lowres
Prev | Orchestra Opcodes and Operators | Next

## lowres

lowres — Another resonant lowpass filter.

## Description

lowres is a resonant lowpass filter.

## Syntax

    ares lowres asig, xcutoff, xresonance [, iskip]

## Initialization

iskip -- initial disposition of internal data space. A zero value will clear the space; a non-zero value will allow previous information to remain. The default value is 0.

## Performance

asig -- input signal

xcutoff -- filter cutoff frequency point

xresonance -- resonance amount

lowres is a resonant lowpass filter derived from a Hans Mikelson orchestra. This implementation is much faster than implementing it in Csound language, and it allows kr lower than sr. xcutoff is not in Hz and xresonance is not in dB, so experiment for the finding best results.

## Examples

Here is an example of the lowres opcode. It uses the file lowres.csd.

Example 531. Example of the lowres opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o lowres.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1

    kres = p4
    asig vco .2, 220, 1		;sawtooth

    kcut line 1000, p3, 10		;note: kcut is not in Hz
    as   lowres asig, kcut, kres	;note: kres is not in dB
    aout balance as, asig		;avoid very loud sounds
         outs aout, aout

    endin
    </CsInstruments>
    <CsScore>
    ; a sine
    f 1 0 16384 10 1

    i 1 0 4 3
    i 1 + 4 30
    i 1 + 4 60
    e
    </CsScore>
    </CsoundSynthesizer>

## See Also

lowresx

## Credits

Author: Gabriel Maldonado (adapted by John ffitch)
Italy

New in Csound version 3.49

Prev | Up | Next
lowpass2 | Home | lowresx