follow2
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## follow2

follow2 — Un autre extracteur d'enveloppe contrôlable.

## Description

Un extracteur d'enveloppe contrôlable utilisant un algorithme attributé à Jean-Marc Jot.

## Syntaxe

    ares follow2 asig, katt, krel

## Exécution

asig -- le signal d'entrée dont l'enveloppe est suivie

katt -- la vitesse d'attaque (temps d'attaque à 60dB en secondes)

krel -- la vitesse de chute (temps de chute à 60dB en secondes)

La sortie suit l'enveloppe d'amplitude du signal d'entrée. La vitesse à laquelle la sortie augmente pour suivre le signal est contrôlée par katt, et la vitesse à laquelle elle diminue en réponse à une amplitude plus faible est contrôlée par krel. Cela donne une enveloppe plus lisse qu'avec follow.

## Exemples

Voici un exemple de l'opcode follow2. Il utilise les fichiers follow2.csd et beats.wav.

Exemple 363. Exemple de l'opcode follow2.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac      ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o follow2.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1

    asig soundin "beats.wav"
         outs asig, asig
    endin

    instr 2 ;using follow2

    as soundin "beats.wav"
    af follow2 as, p4, p5
    ar rand 44100	;noise
    ; "beats.wav" provides amplitude for noise
    asig balance ar, af
         outs asig, asig

    endin
    </CsInstruments>
    <CsScore>

    i 1 0 2
    i 2 2 2 0.001 0.01 ;quick attack & deacy
    i 2 5 2  0.1   0.5  ;slow attack & deacy

    e
    </CsScore>
    </CsoundSynthesizer>

## Crédits

Auteur : John ffitch
L'algorithme de follow2 est attribué à Jean-Marc Jot.
Université de Bath, Codemist Ltd.
Bath, UK
Février 2000

Nouveau dans la version 4.03 de Csound.

Notes ajoutées par Rasmus Ekman en septembre 2002.

Précédent | Niveau supérieur | Suivant
follow | Sommaire | foscil