marimba
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## marimba

marimba — Modèle physique de la frappe d'un bloc de bois.

## Description

La sortie audio est un son tel que celui produit lorque l'on frappe un bloc de bois comme dans un marimba. Il s'agit d'un modèle physique développé d'après Perry Cook mais recodé pour Csound.

## Syntaxe

    ares marimba kamp, kfreq, ihrd, ipos, imp, kvibf, kvamp, ivibfn, idec \
          [, idoubles] [, itriples]

## Initialisation

ihrd -- la dureté de la baguette utilisée pour la frappe. On utilise un intervalle allant de 0 à 1. 0,5 est une valeur adéquate.

ipos -- le point d'impact sur le bloc, compris entre 0 et 1.

imp -- une table des impulsions de la frappe. Le fichier marmstk1.wav contient une fonction adéquate créée à partir de mesures et l'on peut le charger dans une table GEN01. Il est aussi disponible à ftp://ftp.cs.bath.ac.uk/pub/dream/documentation/sounds/modelling/.

ivfn -- forme du vibrato, habituellement une table sinus, créée par une fonction

idec -- durée avant la fin de la note lorqu'il y a une atténuation

idoubles (facultatif) -- pourcentage de frappes doubles. La valeur par défaut est de 40%.

itriples (facultatif) -- pourcentage de frappes triples. La valeur par défaut est de 20%.

## Exécution

kamp -- Amplitude de la note.

kfreq -- Fréquence de la note.

kvibf -- Fréquence du vibrato en Hertz. L'intervalle conseillé va de de 0 à 12.

kvamp -- Amplitude du vibrato.

## Exemples

Voici un exemple de l'opcode marimba. Il utilise les fichiers marimba.csd et marmstk1.wav.

Exemple 560. Exemple de l'opcode marimba.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    ; Audio out   Audio in    No messages
    -odac           -iadc     -d     ;;;RT audio I/O
    ; For Non-realtime ouput leave only the line below:
    ; -o marimba.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    ; Initialize the global variables.
    sr = 44100
    ksmps = 128
    nchnls = 2

    ; Instrument #1.
    instr 1
      ifreq = cpspch(p4)
      ihrd = 0.1
      ipos = 0.561
      imp = 1
      kvibf = 6.0
      kvamp = 0.05
      ivibfn = 2
      idec = 0.6

      a1 marimba 20000, ifreq, ihrd, ipos, imp, kvibf, kvamp, ivibfn, idec, 20, 10

      outs a1, a1
    endin

    </CsInstruments>
    <CsScore>

    ; Table #1, the "marmstk1.wav" audio file.
    f 1 0 256 1 "marmstk1.wav" 0 0 0
    ; Table #2, a sine wave for the vibrato.
    f 2 0 128 10 1

    ; Play Instrument #1 for one second.
    i 1 0 1 8.09
    i 1 + 0.5 8.00
    i 1 + 0.5 7.00
    i 1 + 0.25 8.02
    i 1 + 0.25 8.01
    i 1 + 0.25 7.09
    i 1 + 0.25 8.02
    i 1 + 0.25 8.01
    i 1 + 0.25 7.09
    i 1 + 0.3333 8.09
    i 1 + 0.3333 8.02
    i 1 + 0.3334 8.01
    i 1 + 0.25 8.00
    i 1 + 0.3333 8.09
    i 1 + 0.3333 8.02
    i 1 + 0.25 8.01
    i 1 + 0.3333 7.00
    i 1 + 0.3334 6.00

    e

    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

vibes

## Crédits

Auteur : John ffitch (d'après Perry Cook)
Université de Bath, Codemist Ltd.
Bath, UK

Nouveau dans la version 3.47 de Csound

Précédent | Niveau supérieur | Suivant
maparray | Sommaire | massign