taninv2
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## taninv2

taninv2 — Retourne une tangente inverse (arctangente).

## Description

Retourne arctangente de iy/ix, ky/kx, ou ay/ax.

## Syntaxe

    ares taninv2 ay, ax

    ires taninv2 iy, ix

    kres taninv2 ky, kx

    ...taninv2(ky, kx)... (pas de restriction de taux)

Retourne arctangente de iy/ix, ky/kx, ou ay/ax. Si y vaut zéro, taninv2 retourne zéro quelque soit la valeur de x. Si x vaut zéro, la valeur de retour est :

- π/2, si y est positif.

- -π/2, si y est négatif.

- 0, si y vaut 0.

## Initialisation

iy, ix -- valeurs à transformer

## Exécution

ky, kx -- signaux de taux de contrôle à transformer

ay, ax -- signaux de taux audio à transformer

## Exemples

Voici un exemple de l'opcode taninv2. Il utilise le fichier taninv2.csd.

Exemple 1079. Exemple de l'opcode taninv2.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    ; Audio out   Audio in
    -odac           -iadc    ;;;RT audio I/O
    ; For Non-realtime ouput leave only the line below:
    ; -o taninv2.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    ; Initialize the global variables.
    sr = 44100
    kr = 4410
    ksmps = 10
    nchnls = 1

    ; Instrument #1.
    instr 1
      ; Returns the arctangent for 1/2.
      i1 taninv2 1, 2

      print i1
    endin

    </CsInstruments>
    <CsScore>

    ; Play Instrument #1 for one second.
    i 1 0 1
    e

    </CsScore>
    </CsoundSynthesizer>

Sa sortie contiendra cette ligne :

    instr 1:  i1 = 0.464

Voici un autre exemple de l'opcode taninv2. Il utilise le fichier taninv2-advanced.csd.

Exemple 1080. Exemple avancé de l'opcode taninv2.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    -odac -d
    ; By Stefano Cucchi 2020

    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 10
    nchnls = 2
    0dbfs = 1

    instr 1

    a1 oscili 0.1, p4
    a2 oscili 0.1, p5
    ashape taninv2 a1, a2
    kdeclick linseg 0, 0.3, 0.2, p3-0.6, 0.2, 0.3, 0
    outs ashape*kdeclick, ashape*kdeclick
    endin

    instr 2

    a1 diskin  p4, 1
    a2 = a1
    ashape taninv2 a1, a2
    kdeclick linseg 0, 0.3, 0.2, p3-0.6, 0.2, 0.3, 0
    outs ashape*kdeclick*.5, ashape*kdeclick*.5
    endin

    </CsInstruments>
    <CsScore>

    i 1 0 3 440 300
    i 1 3 3 200 210
    i 1 6 3 50 40
    i 1 9 3 50 3000
    i 2 12 3 "fox.wav"

    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

taninv

## Crédits

Auteur : John ffitch
Université de Bath/Codemist Ltd.
Bath, UK
Avril 1998

Exemple écrit par Kevin Conder.

Nouveau dans la version 3.48 de Csound

Corrigé en mai 2002, grâce à Istvan Varga.

Disponible comme fonction dans la version 6.00

Précédent | Niveau supérieur | Suivant
taninv | Sommaire | tbvcf