triglinseg
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## triglinseg

triglinseg — Déclenche une suite de segments linéaires entre des points spécifiés.

## Description

Déclenche une suite de segments linéaires entre des points spécifiés.

## Syntaxe

    ares triglinseg kTrig, ia, idur1, ib [, idur2] [, ic] [...]

    kres triglinseg kTrig, ia, idur1, ib [, idur2] [, ic] [...]

## Initialisation

ia -- valeur initiale.

ib, ic, etc. -- valeur après dur1 secondes, etc.

idur1 -- durée en secondes du premier segment.

idur2, idur3, etc. -- durée en secondes des segments suivants.

## Exécution

kTrig -- valeur de déclenchement. L'exécution de l'enveloppe est déclenchée lorsque kTrig vaut 1.

Cette unité génère des signaux de contrôle ou audio dont les valeurs passent par deux ou plus de points spécifiés. La somme des valeurs dur peut égaler ou non la durée d'exécution de l'instrument : une exécution plus courte va tronquer l'enveloppe spécifiée. Déclencher l'enveloppe alors qu'elle est déjà en train d'être exécutée va provoquer un saut au début pour la recommencer. Cela peut provoquer un pop ou un clic. Il est préférable d'attendre la fin de l'enveloppe avant de la réenclencher.

## Exemples

Voici un exemple de l'opcode triglinseg. Il utilise le fichier triglinseg.csd.

Exemple 1108. Exemple de l'opcode triglinseg.

Voir les sections Audio en temps réel et Options de la ligne de commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    ; Audio out   Audio in    No messages
    -odac 	-d    -m0d     -M0  -+rtmidi=virtual ;;;RT audio I/O with MIDI in
    ; For Non-realtime ouput leave only the line below:
    ; -o midiin.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>
    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs = 1

    instr 1
    aEnv linseg 0, .2, 1, .2, .5, .2, .7, .2, 0
    a1 oscili aEnv, 400
    outs a1, a1
    endin

    instr 2
    kTrig metro 1
    aEnv trigLinseg kTrig, 0, .2, 1, .2, .5, .2, .7, .2, 0
    a1 oscili aEnv, 400
    outs a1, a1
    endin

    </CsInstruments>
    <CsScore>
    i1 0 1
    i2 1 10
    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

expon, expseg, expseg, expsegb, expsegr, cosseg, line, linsegr, transeg, transegb

## Crédits

Auteur : Rory Walsh
2021

Précédent | Niveau supérieur | Suivant
trigger | Sommaire | trigseq