schedule
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## schedule

schedule — Ajoute un nouvel évènement de partition.

## Description

Ajoute un nouvel évènement de partition.

## Syntaxe

    schedule insnum, iwhen, idur [, ip4] [, ip5] [...]

    schedule "insname", iwhen, idur [, ip4] [, ip5] [...]

    schedule iPar[]

## Initialisation

insnum -- numéro d'un instrument. Equivalent à p1 dans une instruction i de partition. insnum doit être un numéro supérieur au numéro de l'instrument appelant.

« insname » -- une chaîne de caractères (entre guillemets) représentant un instrument nommé.

iwhen -- date de début du nouvel évènement. Equivalent à p2 dans une instruction i de partition. iwhen ne doit pas être négatif. Si iwhen vaut zéro, insnum doit être supérieur ou égal au p1 de l'instrument courant.

idur -- durée de l'évènement. Equivalent à p3 dans une instruction i de partition.

iPar[] -- paramètres de l'évènement dans un tableau de taux-i.

ip4, ip5, ... -- Equivalent à p4, p5, etc., dans une instruction i de partition. L'opcode accepte aussi des chaînes de caractères en p4-pN

## Exécution

schedule ajoute un nouvel évènement de partition. Les arguments, options incluses, sont les mêmes que dans une partition. Le temps iwhen (p2) est mesuré à partir de l'instant de cet évènement.

Si la durée est nulle ou négative, le nouvel évènement est de type MIDI, et il hérite le sous-évènement de relachement (release) de l'instruction schedule.

## Exemples

Voici un exemple de l'opcode schedule. Il utilise le fichier schedule.csd.

Exemple 923. Exemple de l'opcode schedule.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    ; Audio out   Audio in
    -odac           -iadc    ;;;RT audio I/O
    ; For Non-realtime ouput leave only the line below:
    ; -o schedule.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    ; Initialize the global variables.
    sr = 44100
    kr = 4410
    ksmps = 10
    nchnls = 1

    ; Instrument #1 - oscillator with a high note.
    instr 1
      ; Play Instrument #2 at the same time.
      schedule 2, 0, p3

      ; Play a high note.
      a1 oscils 10000, 880, 1
      out a1
    endin

    ; Instrument #2 - oscillator with a low note.
    instr 2
      ; Play a low note.
      a1 oscils 10000, 220, 1
      out a1
    endin

    </CsInstruments>
    <CsScore>

    ; Table #1, a sine wave.
    f 1 0 16384 10 1

    ; Play Instrument #1 for half a second.
    i 1 0 0.5
    ; Play Instrument #1 for half a second.
    i 1 1 0.5
    e

    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

event, event_i, schedulek, schedwhen, schedkwhen, schedkwhennamed, scoreline, scoreline_i

Pour plus d'information sur cet opcode : http://www.csoundjournal.com/issue15/phrase_loops.html , écrit par Jim Aikin.

## Crédits

Auteur : John ffitch
Université de Bath/Codemist Ltd.
Bath, UK
Novembre 1998

Exemple écrit par Kevin Conder.

Nouveau dans la version 3.491 de Csound

Basé sur un travail de Gabriel Maldonado

Merci à David Gladstein, pour avoir clarifié le paramètre iwhen.

Précédent | Niveau supérieur | Suivant
schedkwhennamed | Sommaire | schedulek