vps
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## vps

vps — Met en forme un signal de phase selon un vecteur à deux dimensions.

## Description

La mise en forme de phase par vecteur modifie une entrée de phase dans l'intervalle [0, 1) selon une fonction non linéaire constituée de deux segements linéaires joints par un point d'inflexion. Celui-ci est défini par le vecteur [kd, kv], où kd est dans l'intervalle [0, 1) et où kv peut prendre n'importe quelle valeur.

## Syntaxe

    avp vps aph,kd,kv

## Exécution

avp -- phase en sortie.

aph -- phase en entrée (telle que produite par phasor).

kd -- composante horizontale du vecteur.

aph -- composante verticale du vecteur.

## Exemples

Voici un exemple de l'utilisation de l'opcode vps. Il utilise le fichier vps.csd.

Exemple 1187. Exemple de l'opcode vps.

Voir les sections Audio en temps réel et Options de la ligne de commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    -o dac -d
    </CsOptions>
    <CsInstruments>
    0dbfs = 1
    nchnls=1
    ksmps = 1

    instr 1
     kd = oscili:k(0.5,2) + 0.5
     kv = oscili:k(0.5,1.5) + 0.5
     aph = vps(phasor(p5),kd,kv)
     asig = p4*tablei:a(aph,-1,1,0.25,1)
     out(linenr(asig,0.1,0.1,0.01))
    endin

    </CsInstruments>
    <CsScore>

    i 1 0 10 0.5 110

    </CsScore>
    </CsoundSynthesizer>

## Crédits

Auteur : Victor Lazzarini
Juillet 2020

Précédent | Niveau supérieur | Suivant
vpowv_i | Sommaire | vpvoc