vlowres
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## vlowres

vlowres — Un banc de filtres dans lequelle la fréquence de coupure peut être séparée sous le contrôle de l'utilisateur.

## Description

Un banc de filtres dans lequelle la fréquence de coupure peut être séparée sous le contrôle de l'utilisateur.

## Syntaxe

    ares vlowres asig, kfco, kres, iord, ksep

## Initialisation

iord -- nombre total de filtres (1 à 10)

## Exécution

asig -- signal d'entrée

kfco -- fréquence de coupure (pas en Hz)

kres -- quantité de résonance

ksep -- séparation de la fréquence de coupure pour chaque filtre : le premier filtre a pour fréquence de coupure kfreq, le second kfreq + ksep et le troisième kfreq + 2*ksep, et ainsi de suite, en fonction du nombre de filtres.

vlowres (variable resonant lowpass filter) permet d'avoir une courbe de réponse variable dans les filtres à résonance. On peut l'imaginer comme un banc de filtres passe-bas à résonance, chacun avec la même résonance, connectés en série. La fréquence de coupure de chaque filtre peut varier avec les paramètres kcfo et ksep.

## Exemples

Voici un exemple de l'opcode vlowres. Il utilise le fichier vlowres.csd.

Exemple 1174. Exemple de l'opcode vlowres.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if RT audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o vlowres.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1

    kamp init p4
    asig vco2  kamp, 110			;saw wave
    kfco line 30, p3, 300			;vary the cutoff frequency from 30 to 300 Hz.
    kres = 20
    ksep = p5				;different resonance values
    iord = p6				;and different number of filters
    aout vlowres asig, kfco, kres, iord, ksep
    aclp clip aout, 1, 1			;avoid distortion
         outs aclp, aclp

    endin
    </CsInstruments>
    <CsScore>
    f 1 0 16384 10 1	;sine

    s
    i 1 0 10 .1 5  2	;compensate volume and
    i 1 + 10 .1 25 2	;number of filters = 2
    s
    i 1 0 10 .01 5  6	;compensate volume and
    i 1 + 10 .04 15 6	;number of filters = 6

    e
    </CsScore>
    </CsoundSynthesizer>

## Crédits

Auteur : Gabriel Maldonado
Italie

Nouveau dans la version 3.49 de Csound.

Précédent | Niveau supérieur | Suivant
vlinseg | Sommaire | vmap