pchtom
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## pchtom

pchtom — Conversion d'un pch en numéro de note MIDI.

## Description

Opcode du greffon emugens.

Convertit un pch en numéro de note MIDI. La représentation pch est de la forme octave.classe_de_hauteur où classe_de_hauteur est un nombre entre 00 et 12.

            pch        midi    nom de note
            ------------------------------
            8.09       69      4A
            8.00       60      4C

## Syntaxe

    imidi pchtom ipch

    kmidi pchtom kpch

## Exécution

kpch / ipch -- Hauteur représentée en octave.classe_de_hauteur.

kmidi / imidi -- Numéro de note MIDI.

| Note
Utiliser pchmidinn pour faire l'opération inverse.

## Exemples

Voici un exemple de l'opcode pchtom. Il utilise le fichier pchtom.csd.

Exemple 731. Exemple de l'opcode pchtom.

    <CsoundSynthesizer>
    <CsOptions>
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 128
    nchnls = 2
    0dbfs = 1.0

    ; Show some conversions, both at i- and at k-time

    instr 1
      imidi = pchtom(8.09)
      print imidi

      kidx init 0

      kpch = 8 + kidx / 100
      kmidi = pchtom(kpch)
      kidx += 1
      printf "kpch: %f    kmidi: %f\n", kidx+1, kpch, kmidi

      if kidx >= 12 then
        turnoff
      endif

    endin

    </CsInstruments>
    <CsScore>
    i 1 0 1

    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

pchoct, pchmidinn, cpsmidinn, ftom, mton

## Crédits

Par : Eduardo Moguillansky 2017

Précédent | Niveau supérieur | Suivant
pchoct | Sommaire | pconvolve