wguide1
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## wguide1

wguide1 — Un modèle simple de guide d'onde constitué d'une ligne à retard et d'un filtre passe-bas du premier ordre.

## Description

Un modèle simple de guide d'onde constitué d'une ligne à retard et d'un filtre passe-bas du premier ordre.

## Syntaxe

    ares wguide1 asig, xfreq, kcutoff, kfeedback

## Exécution

asig -- l'entrée du bruit d'excitation.

xfreq -- la fréquence (c-à-d l'inverse de la durée du retard). A été changé au taux-x dans la version 3.59 de Csound.

kcutoff -- la fréquence de coupure du filtre en Hz.

kfeedback -- le facteur de rétroaction.

wguide1 est le modèle de guide d'onde le plus élémentaire, consistant en une ligne à retard et un filtre passe-bas du premier ordre.

L'implémentation des algorithmes de guide d'onde comme opcodes au lieu d'instruments d'un orchestre de Csound permet de fixer une valeur de kr différente de celle de sr, ce qui donne de meilleures performances particulièrement en .

wguide1.

## Exemples

Voici un exemple de l'opcode wguide1. Il utilise le fichier wguide1.csd.

Exemple 1208. Exemple de l'opcode wguide1.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    ; Audio out   Audio in    No messages
    -odac           -iadc     -d     ;;;RT audio I/O
    ; For Non-realtime ouput leave only the line below:
    ; -o wguide1.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    ; Initialize the global variables.
    sr = 44100
    kr = 4410
    ksmps = 10
    nchnls = 1

    ; Instrument #1 - a simple noise waveform.
    instr 1
      ; Generate some noise.
      asig noise 20000, 0.5

      out asig
    endin

    ; Instrument #2 - a waveguide example.
    instr 2
      ; Generate some noise.
      asig noise 20000, 0.5

      ; Run it through a wave-guide model.
      kfreq init 200
      kcutoff init 3000
      kfeedback init 0.8
      awg1 wguide1 asig, kfreq, kcutoff, kfeedback

      out awg1
    endin

    </CsInstruments>
    <CsScore>

    ; Play Instrument #1 for 2 seconds.
    i 1 0 2
    ; Play Instrument #2 for 2 seconds.
    i 2 2 2
    e

    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

wguide2

## Crédits

Auteur : Gabriel Maldonado
Italie
Octobre 1998

Exemple écrit par Kevin Conder.

Nouveau dans la version 3.49 de Csound.

Précédent | Niveau supérieur | Suivant
wgpluck2 | Sommaire | wguide2