table
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## table

table — Accède aux valeurs d'une table par indexation directe.

## Description

Accède aux valeurs d'une table par indexation directe.

## Syntaxe

    ares table andx, ifn [, ixmode] [, ixoff] [, iwrap]

    ires table indx, ifn [, ixmode] [, ixoff] [, iwrap]

    kres table kndx, ifn [, ixmode] [, ixoff] [, iwrap]

## Initialisation

ifn -- numéro de la table de fonction.

ixmode (facultatif) -- type de l'index. La valeur par défaut est 0.

- 0 = index brut

- 1 = normalisé (de 0 à 1)

ixoff (facultatif) -- décalage de l'index. Pour une table dont l'origine est au centre, utiliser taille_table/2 (brut) ou 0.5 (normalisé). La valeur par défaut est 0.

iwrap (facultatif) -- indicateur d'indexation cyclique. La valeur par défaut est 0.

- 0 = indexation normale (index < 0 traité comme index=0 ; index > taille_table ramené à index=taille_table)

- 1 = indexation cyclique.

## Exécution

table effectue une consultation de table avec des index variant au taux d'initialisation, de contrôle ou audio. Ces index peuvent être des nombres bruts (0, 1, 2, ..., taille - 1) ou des valeurs normalisées (0 à 1). Les index sont d'abord modifiés par la valeur de décalage puis leur appartenance à un intervalle valable est testée avant la consultation de la table (voir iwrap). Si l'index peut prendre la valeur maximale ou si l'on utilise l'interpolation, la table doit avoir un point de garde. Une table indéxée par un phaseur périodique (voir phasor) simulera un oscillateur.

## Exemples

Voici un exemple de l'opcode table. Il utilise le fichier table.csd.

Exemple 1053. Exemple de l'opcode table.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    ; Audio out   Audio in    No messages
    -odac           -iadc     -d     ;;;RT audio I/O
    ; For Non-realtime ouput leave only the line below:
    ; -o table.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    ; Initialize the global variables.
    sr = 44100
    kr = 4410
    ksmps = 10
    nchnls = 1

    ; Instrument #1.
    instr 1
      ; Vary our index linearly from 0 to 1.
      kndx line 0, p3, 1

      ; Read Table #1 with our index.
      ifn = 1
      ixmode = 1
      kfreq table kndx, ifn, ixmode

      ; Generate a sine waveform, use our table values
      ; to vary its frequency.
      a1 oscil 20000, kfreq, 2
      out a1
    endin

    </CsInstruments>
    <CsScore>

    ; Table #1, a line from 200 to 2,000.
    f 1 0 1025 -7 200 1024 2000
    ; Table #2, a sine wave.
    f 2 0 16384 10 1

    ; Play Instrument #1 for 2 seconds.
    i 1 0 2
    e

    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

tablei, table3, oscil1, oscil1i, osciln

## Crédits

Exemple écrit par Kevin Conder.

Précédent | Niveau supérieur | Suivant
tabifd | Sommaire | table3