trlowest
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## trlowest

trlowest — Extrait le canal de fréquence le plus bas d'un flot de suivi de partiels.

## Description

L'opcode trlowest prend en entrée un flot de signal TRACKS pv (tel que généré, par exemple, par partials) et ne restitue que le canal le plus bas. De plus, il fournit en sortie deux signaux de taux-k, correspondant à la fréquence et à l'amplitude du signal de canal le plus bas.

## Syntaxe

    fsig, kfr, kamp trlowest fin1, kscal

## Exécution

fsig -- flot pv de sortie au format TRACKS.

kfr -- fréquence (en Hz) du canal de fréquence le plus bas.

kamp -- amplitude du canal de fréquence le plus bas.

fin -- flot pv d'entrée au format TRACKS.

kscal -- pondération d'amplitude de la sortie.

## Exemples

Voici un exemple de l'opcode trlowest. Il utilise le fichier trlowest.csd.

Exemple 1112. Exemple de l'opcode trlowest.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o trlowest.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1

    ain     diskin2 "beats.wav", 1
    fs1,fsi2 pvsifd ain, 2048, 512, 1	; ifd analysis
    fst partials fs1, fsi2, .003, 1, 3, 500 ; partial tracking
    flow,kfr,kamp trlowest fst, 1		; lowest freq-track
    aout	tradsyn	flow, 1, 1, 1, 1	; resynthesis of lowest frequency
    	outs	aout*2, aout*2

    endin
    </CsInstruments>
    <CsScore>
    f1 0 8192 10 1	;sine wave

    i 1 0 3
    e
    </CsScore>
    </CsoundSynthesizer>

L'exemple ci-dessus montre le suivi de partiels d'un signal d'analyse par distribution de fréquence instantanée, l'extraction de la fréquence la plus basse et la resynthèse.

## Crédits

Auteur : Victor Lazzarini
Février 2006

Nouveau dans Csound 5.01

Précédent | Niveau supérieur | Suivant
trirand | Sommaire | trmix