jitter2
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## jitter2

jitter2 — Génère aléatoirement une suite de segments de droite contrôlables par l'utilisateur.

## Description

Génère aléatoirement une suite de segments de droite contrôlables par l'utilisateur.

## Syntaxe

    kout jitter2 ktotamp, kamp1, kcps1, kamp2, kcps2, kamp3, kcps3[ ,iopt]

## Initialisation

iopt -- Facultatif, contrôle la date de début des effets. S'il est nul (valeur par défaut) la sortie est nulle jusqu'à la fin de la valeur de kcps la plus courte. S'il est différent de zéro l'effet démarre immédiatement.

## Exécution

ktotamp -- Amplitude résultante de jitter2

kamp1 -- Amplitude du premier composant de jitter

kcps1 -- Vitesse de la variation aléatoire du premier composant de jitter (exprimée en cps)

kamp2 -- Amplitude du second composant de jitter

kcps2 -- Vitesse de la variation aléatoire du second composant de jitter (exprimée en cps)

kamp3 -- Amplitude du troisième composant de jitter

kcps3 -- Vitesse de la variation aléatoire du troisième composant de jitter (exprimée en cps)

jitter2 génère une ligne segmentée comme jitter, mais ici le résultat est semblable à la somme de trois opcodes randi, chacun avec ses propres valeurs d'amplitude et de fréquence (voir randi pour plus de détails), qui sont modifiables au taux-k. On peut obtenir différents effets en variant les arguments en entrée.

On peut utiliser jitter2 pour donner plus de naturel et une « touche analogique » à des sons statiques et monotones. Pour de meilleurs résultats il est conseillé de garder une amplitude modérée.

## Exemples

Voici un exemple de l'opcode jitter2. Il utilise le fichier jitter2.csd.

Exemple 482. Exemple de l'opcode jitter2.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o jitter2.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1

    ktotamp init p4
    kamp1   init .5
    kcps1   init 10
    kamp2   init .5
    kcps2   init 2
    kamp3   init .5
    kcps3   init 3

    kj2  jitter2 ktotamp, kamp1, kcps1, kamp2, kcps2, kamp3, kcps3
    aout pluck 1, 200+kj2, 1000, 0, 1
    aout dcblock aout
         outs aout, aout

    endin
    </CsInstruments>
    <CsScore>

    i 1 0 15 2	;a bit jitter
    i 1 8 15 10	;some more
    i 1 16 15 20	;lots more
    e
    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

jitter, vibr, vibrato

## Crédits

Auteur : Gabriel Maldonado, John ffitch

Nouveau dans la version 4.15

iopt ajouté dans la version 6.08

Précédent | Niveau supérieur | Suivant
jitter | Sommaire | joystick