sc_trig
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## sc_trig

sc_trig — Déclencheur mesuré (remplacé par trighold).

## Description

Opcode du greffon scugens.

Déclencheur mesuré. Adapté de Trig de Supercollider. Cet opcode est obsolète et remplacé par trighold.

## Syntaxe

    aout sc_trig ain, kdur

    kout sc_trig kin, kdur

## Exécution

ain -- Déclencheur, pouvant être n'importe quel signal. Un déclenchement a lieu quand le signal passe d'une valeur non-positive à une valeur positive.

kdur -- Durée du déclenchement en secondes.

Quand une transition d'une valeur non-positive à une valeur positive a lieu en entrée, sc_trig restitue le niveau du signal déclencheur pendant la durée spécifiée, sinon la sortie vaut zéro.

## Exemples

Voici un exemple de l'opcode sc_trig. Il utilise le fichier sc_trig.csd.

Exemple 933. Exemple de l'opcode sc_trig.

Voir les sections Audio en temps réel et Options de la ligne de commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 128
    nchnls = 2
    0dbfs = 1.0

    instr 1
      km = metro(1)
      kt timeinsts
      ktrig = sc_trig(km, 0.5)
      printks "t=%f  km=%f    ktrig=%f\n", 0.01, kt, km, ktrig
    endin

    instr 2
      am = upsamp(metro(1))
      aenv = sc_trig(am, 0.5)
      asig pinker
      outch 1, asig*aenv
      outch 2, asig
    endin

    </CsInstruments>
    <CsScore>
    i 1 0 10
    i 2 0 10

    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

sc_lag, metro, mpulse trigger

## Crédits

Par : Eduardo Moguillansky 2017

Précédent | Niveau supérieur | Suivant
trigphasor | Sommaire | trighold