delayr
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## delayr

delayr — Lit depuis une ligne à retard numérique établie automatiquement.

## Description

Lit depuis une ligne à retard numérique établie automatiquement.

## Syntaxe

    ares delayr idlt [, iskip]

## Initialisation

idlt -- délai demandé en secondes. Il peut être aussi grand que la mémoire disponible le permet. L'espace requis pour n secondes de délai est de 4n * sr octets. Il est alloué lorsque l'instrument est initialisé pour la première fois, et retourne dans le pool à la fin d'une section de partition.

iskip (facultatif, 0 par défaut) -- disposition initiale de l'espace des données de la boucle de retard (voir reson). La valeur par défaut est 0.

## Exécution

delayr lit depuis une ligne à retard numérique établie automatiquement, dans laquelle le signal restitué est resté pendant idlt secondes. Cette unité doit être appariée avec une unité delayw qu'elle précède. Il peut y avoir d'autres opcodes de Csound entre les deux.

## Exemples

Voici un exemple de l'opcode delayr. Il utilise le fichier delayr.csd.

Exemple 214. Exemple de l'opcode delayr.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;RT audio out
    ;-iadc    ;;;uncomment -iadc if RT audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o delayr.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs = 1

    gasig  init 0
    gidel  = 1		;delay time in seconds

    instr 1

    ain  pluck .7, 440, 1000, 0, 1
         outs ain, ain

    vincr gasig, ain	;send to global delay
    endin

    instr 2

    ifeedback = p4

    abuf2	delayr	gidel
    adelL 	deltap	.4		;first tap (on left channel)
    adelM 	deltap	1		;second tap (on middle channel)
    	delayw	gasig + (adelL * ifeedback)

    abuf3	delayr	gidel
    kdel	line    1, p3, .01	;vary delay time
    adelR 	deltap  .65 * kdel	;one pitch changing tap (on the right chn.)
    	delayw	gasig + (adelR * ifeedback)
    ;make a mix of all deayed signals
    	outs	adelL + adelM, adelR + adelM

    clear	gasig
    endin

    </CsInstruments>
    <CsScore>

    i 1 0 1
    i 1 3 1
    i 2 0 3  0	;no feedback
    i 2 3 8 .8	;lots of feedback
    e
    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

delay, delay1, delayw

Précédent | Niveau supérieur | Suivant
delayk | Sommaire | delayw