cngoto
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## cngoto

cngoto — Transfère le contrôle à chaque passage si la condition n'est pas vraie.

## Description

Transfère le contrôle à chaque passage si la condition n'est pas vraie.

## Syntaxe

    cngoto condition, label

où label se trouve dans le même bloc d'instrument et n'est pas une expression, et où condition utilise un des opérateurs relationnels (<, =, <=, ==, !=) (et = par commodité, voir aussi Valeurs Conditionnelles).

## Exemples

Voici un exemple de l'opcode cngoto. Il utilise le fichier cngoto.csd.

Exemple 147. Exemple de l'opcode cngoto.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Audio out   Audio in
    -odac           -iadc    ;;;RT audio I/O
    ; -o cngoto.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    ; Initialize the global variables.
    sr = 44100
    ksmps = 10
    nchnls = 1

    ; Instrument #1.
    instr 1
      ; Change kval linearly from 0 to 2 over
      ; the period set by the third p-field.
      kval line 0, p3, 2

      ; If kval *is not* greater than or equal to 1 then play
      ; the high note. Otherwise, play the low note.
      cngoto (kval >= 1), highnote
        kgoto lownote

    highnote:
      kfreq = 880
      goto playit

    lownote:
      kfreq = 440
      goto playit

    playit:
      ; Print the values of kval and kfreq.
      printks "kval = %f, kfreq = %f\\n", 1, kval, kfreq

      a1 oscil 10000, kfreq, 1
      out a1
    endin

    </CsInstruments>
    <CsScore>

    ; Table: a simple sine wave.
    f 1 0 32768 10 1

    ; Play Instrument #1 for two seconds.
    i 1 0 2
    e

    </CsScore>
    </CsoundSynthesizer>

Sa sortie contiendra des lignes comme celles-ci :

    kval = 0.000000, kfreq = 880.000000
    kval = 0.999732, kfreq = 880.000000
    kval = 1.999639, kfreq = 440.000000

## Voir aussi

cggoto, cigoto, ckgoto, goto, if, igoto, tigoto, timout

## Crédits

Exemple écrit par Kevin Conder.

Nouveau dans la version 4.21

Précédent | Niveau supérieur | Suivant
cmplxprod | Sommaire | comb