loopxseg
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## loopxseg

loopxseg — Génère un signal de contrôle constitué de segments exponentiels délimités par deux ou plus points spécifiés.

## Description

Génère un signal de contrôle constitué de segments exponentiels délimités par deux ou plus points spécifiés. L'enveloppe entière est parcourue en boucle au taux kfreq. Chaque paramètre peut varier au taux-k.

## Syntaxe

    ksig loopxseg kfreq, ktrig, iphase, kvalue0, ktime0 [, ktvalue1] [, ktime1] \
          [, ktvalue2] [, ktime2] [...]

## Exécution

ksig -- Signal de sortie.

kfreq -- Taux de répétition en Hz ou en fraction de Hz.

ktrig -- S'il est non nul, redéclanche l'enveloppe depuis le début (voir l'opcode trigger), avant que le cycle de l'enveloppe ne soit complet.

iphase -- Une valeur comprise entre 0 et 1 pour indiquer où commence la boucle. Zéro, la valeur la plus usuelle, indique le début du signal.

ktime0...ktimeN -- Dates des points ; exprimées en fraction d'une période.

kvalue0...kvalueN -- Valeurs des points.

L'opcode loopxseg est semblable à expseg, mais l'enveloppe entière est parcourue en boucle au taux kfreq. Noter que les valeurs temporelles ne sont pas exprimées en secondes mais en fractions d'une période. Concrètement chaque durée est proportionnelle aux autres, et la durée du cycle complet est proportionnelle à la somme de toutes les valeurs de durée.

La somme de toutes les durées est ensuite pondérée en fonction de l'argument kfreq. Par exemple, considérant une enveloppe faite de 3 segments, chaque segment ayant une valeur de durée de 100, leur somme sera 300. Cette valeur représente la durée totale de l'enveloppe, et elle est divisée en 3 parties égales, une partie pour chaque segment.

Concrètement, la durée réelle de l'enveloppe en secondes est déterminée par kfreq. Si l'enveloppe est à nouveau constituée de 3 segments, mais cette fois-ci le premier et le dernier segments ayant une durée de 50, tandis que le segment central a une durée de 100, leur somme sera 200. Ici 200 représente la durée totale des 3 segments, et ainsi le segment central sera deux fois plus long que les autres segments.

Tous les paramètres peuvent varier au taux-k. Si les valeurs de fréquence sont négatives, l'enveloppe est lue à l'envers. ktime0 doit toujours valoir 0, sauf si l'on désire un effet spécial.

## Exemples

Voici un exemple de l'opcode loopxseg. Il utilise le fichier loopxseg.csd.

Exemple 525. Exemple de l'opcode loopxseg.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac      ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o loopxseg.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1
    kfreq  rspline  0.01,20,0.2,1   ; freq. of loop repetition created by random spline
    ktrig  init     0   ; loop restart trigger (not used)
    iphase =        0   ; initial phase
    ; loop of filter cutoff values (oct format). Rescaled further down.
    kcfoct loopxseg  kfreq, ktrig, iphase, 1,1,0,0
    kenv  linseg   0,0.01,1,p3-5.01,1,5,0
    asig  vco2     0.2*kenv,cpsmidinn(48),0
    kdep  rspline  5,8,0.2,1  ; filter depth created by a random spline
    kcf   port     cpsoct((kcfoct*kdep)+4), 0.001  ; smooth filter changes
    asig  moogladder  asig,kcf,rnd(0.6)
    aL,aR pan2     asig,rnd(1)
          outs     aL, aR
    endin

    </CsInstruments>
    <CsScore>
    i 1  0 60
    e
    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

lpshold loopseg

## Crédits

Auteur : John ffitch

Nouveau dans la version 5.12

Précédent | Niveau supérieur | Suivant
looptseg | Sommaire | lorenz