expsegba
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## expsegba

expsegba — Un générateur de segments d'exponentielle opérant au taux-a avec des temps absolus.

## Description

Un générateur de segments d'exponentielle opérant au taux-a. Cette unité est presque identique à expsegb, mais plus précises lorsque sont définis des segments de très courte durée (par exemple dans une phase d'attaque percussive) au taux audio.

## Syntaxe

    ares expsegba ia, itim1, ib [, itim2] [, ic] [...]

## Initialisation

ia -- valeur initiale. Zéro est interdit.

ib, ic, etc. -- valeurs après itim1 secondes, etc. Doivent être différentes de zéro et de même signe que ia.

itim1 -- date en secondes de la fin du premier segment.

itim2, itim3, etc. -- date en secondes de la fin des segments suivants.

## Exécution

Cet unité génère des signaux audio dont les valeurs peuvent passer par deux ou plus points spécifiés. La dernière valeur tim peut égaler ou non la durée d'exécution de l'instrument : avec une exécution plus courte, la courbe sera tronquée alors qu'avec une exécution plus longue, la dernière valeur sera répétée jusqu'à la fin de la note.

## Exemples

Voici un exemple de l'opcode expsegba. Il utilise le fichier expsegba.csd.

Exemple 281. Exemple de l'opcode expsegba.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    ; Audio out   Audio in    No messages
    -odac           -iadc     -d     ;;;RT audio I/O
    ; For Non-realtime ouput leave only the line below:
    ; -o expsega.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    ; Initialize the global variables.
    sr = 44100
    kr = 4410
    ksmps = 10
    nchnls = 1

    ; Instrument #1.
    instr 1
      ; Define a short percussive amplitude envelope that
      ; goes from 0.01 to 20,000 and back.
      aenv expsegba 0.01, 0.1, 20000, 0.2, 0.01

      a1 oscil aenv, 440, 1
      out a1
    endin

    </CsInstruments>
    <CsScore>

    ; Table #1, a sine wave.
    f 1 0 16384 10 1

    ; Play Instrument #1 for one second.
    i 1 0 1
    ; Play Instrument #1 for one second.
    i 1 1 1
    ; Play Instrument #1 for one second.
    i 1 2 1
    ; Play Instrument #1 for one second.
    i 1 3 1
    e

    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

expsegb, expsegr

## Crédits

Auteur : John ffitch

Juin 2011

Nouveau dans Csound 5.14

Précédent | Niveau supérieur | Suivant
expsegb | Sommaire | expsegr