dssiactivate
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## dssiactivate

dssiactivate — Active ou désactive un greffon DSSI ou LADSPA.

| Note
Greffon : nécessite le greffon dssi4cs

## Syntaxe

    dssiactivate ihandle, ktoggle

## Description

Opcode du greffon dssi4cs.

dssiactivate est utilisé pour activer ou désactiver un greffon DSSI ou LADSPA. Il appelle les fonctions activate() et deactivate() du greffon si elles sont disponibles.

## Initialisation

ihandle - le numéro qui identifie le greffon, généré par dssiinit.

## Exécution

ktoggle - Choix entre l'activation (ktoggle = 1) et la désactivation (ktoggle = 0).

dssiactivate est utilisé pour activer ou désactiver des greffons si ceux-ci proposent cette option. Cela peut aider à maintenir le traitement CPU dans certains cas. Pour être consistant, tous les greffons doivent être activés pour produire du son. Un greffon inactif reste silencieux.

En fonction de l'implémentation du greffon, cela peut causer des interruptions dans le processus audio en temps réel. Il faut donc l'utiliser avec précaution.

dssiactivate pouvant provoquer des interruptions du flux audio en temps réel, il est recommandé de charger tous les greffons que l'on veut utiliser avant l'exécution.

| Avertissement
Noter que même si un greffon ne possède pas les fonctions activate() et deactivate(), dssiactivate doit être appelé pour que le greffon produise du son.

## Exemples

Voici un exemple de l'opcode dssiactivate. Il utilise le fichier dssiactivate.csd.

Exemple 244. Exemple de l'opcode dssiactivate.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;RT audio out
    ;-iadc    ;;;uncomment -iadc if RT audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o dssiactivate.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2

    gihandle dssiinit "caps.so", 19, 1	; = mono phaser and
    gaout init  0				; verbose about all ports

    instr 1	; activate DSSI

    ktoggle	=  p4
    dssiactivate gihandle, ktoggle
    endin

    instr 2

    ain1	diskin2 "beats.wav", 1,0,1	; loop
    ain1	=	ain1*.5
    	outs	ain1, ain1
    gaout = gaout+ain1
    endin

    instr 3

    dssictls gihandle, 0, 1, 1			; range -1 to 1
    dssictls gihandle, 1, 2, 1			; rate 0 to 10
    dssictls gihandle, 2, .8, 1			; depth 0 to 1
    dssictls gihandle, 3, 3, 1			; spread 0 to 3.14
    dssictls gihandle, 4, .9, 1			; feedback 0 to 0.999

    endin

    instr 4

    aout1 dssiaudio gihandle, gaout	;get beats.wav, mono out
    	outs aout1,aout1

    gaout = 0
    endin

    </CsInstruments>
    <CsScore>
    i 1 0 4 1
    i 1 + . 0
    i 1 + . 1
    i 1 + . 0
    i 1 + . 1
    i 2 1 20
    i 3 1 20
    i 4 0 20

    e
    </CsScore>
    </CsoundSynthesizer>

## Crédits

2005

Par Andrés Cabrera

Utilise du code provenant du sdk de LADSPA par Richard Furse.

Précédent | Niveau supérieur | Suivant
dripwater | Sommaire | dssiaudio