round
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## round

round — Retourne la valeur entière la plus proche de x ; si la partie décimale de x vaut exactement 0.5, la direction de l'arrondi est indéfinie et peut dépendre du système d'exploitation hôte et de la version de Csound.

## Description

La valeur entière la plus proche de x ; si la partie décimale de x vaut exactement 0.5, la direction de l'arrondi est indéfinie.

## Syntaxe

    round(x) (des arguments de taux-i, -k ou -a sont permis)

    round(k/i[]) (k- ou i-tableau)

où l'argument entre parenthèses peut être une expression. Les convertisseurs de valeur réalisent une transformation arithmétique d'unités d'une sorte en unités d'une autre sorte. Le résultat peut devenir ensuite un terme dans une autre expression.

## Exemples

Voici un exemple de l'opcode round. Il utilise le fichier round.csd.

Exemple 908. Exemple de l'opcode round.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ;-o round.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1

    idiv init 1

    loop:
    inumber = 9
    i1  = inumber / idiv
    iro =  round(i1)
    print inumber, idiv, iro ;print number / idiv = result using round
    idiv = idiv + 1
    if (idiv <= 10) igoto loop

    endin
    </CsInstruments>
    <CsScore>

    i 1 0 0
    e

    </CsScore>
    </CsoundSynthesizer>

Sa sortie contiendra des lignes comme celles-ci :

    instr 1:  inumber = 9.000  idiv = 1.000  ifl = 9.000
    instr 1:  inumber = 9.000  idiv = 2.000  ifl = 5.000
    instr 1:  inumber = 9.000  idiv = 3.000  ifl = 3.000
    instr 1:  inumber = 9.000  idiv = 4.000  ifl = 2.000
    instr 1:  inumber = 9.000  idiv = 5.000  ifl = 2.000
    instr 1:  inumber = 9.000  idiv = 6.000  ifl = 2.000
    instr 1:  inumber = 9.000  idiv = 7.000  ifl = 1.000
    instr 1:  inumber = 9.000  idiv = 8.000  ifl = 1.000
    instr 1:  inumber = 9.000  idiv = 9.000  ifl = 1.000
    instr 1:  inumber = 9.000  idiv = 10.000  ifl = 1.000

Voici un exemple de groupe d'arrondis, comparant les différents opcodes d'arrondis. Il utilise le fichier rounding-group.csd.

Exemple 909. Exemple de groupe d'arrondis.

    <CsoundSynthesizer>
    <CsOptions>
    -odac       ;
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32

    ; by tgrey 2020
    instr 1

    iLoopStart = p4
    iLoopEnd   = p5
    iOffset    = p6

    iCount init iLoopStart

    if(iLoopStart<iLoopEnd) then		; loop going up
    	while iCount <= iLoopEnd do
    		iVal = iCount+iOffset
    		iRound = round(iVal)
    		iInt = int(iVal)
    		iFloor = floor(iVal)
    		iCeil = ceil(iVal)
    		print iVal, iRound, iInt, iFloor, iCeil
    		iCount = iCount + 1
    	od

    elseif(iLoopEnd<iLoopStart) then	; loop going down
    	while iCount >= iLoopEnd do
    		iVal = iCount+iOffset
    		iRound = round(iVal)
    		iInt = int(iVal)
    		iFloor = floor(iVal)
    		iCeil = ceil(iVal)
    		print iVal, iRound, iInt, iFloor, iCeil
    		iCount = iCount - 1
    	od
    endif
    endin
    </CsInstruments>
    <CsScore>
    i1 0 .1 0 10 .5
    i1 .2 .1 0 -10 .5
    e
    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

abs, exp, int, log, log10, i, sqrt

## Crédits

Auteur : Istvan Varga
Nouveau dans Csound 5
2005

Précédent | Niveau supérieur | Suivant
rnd31 | Sommaire | rspline