pcauchy
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## pcauchy

pcauchy — Générateur de nombres aléatoires de distribution de Cauchy (valeurs positives seulement).

## Description

Générateur de nombres aléatoires de distribution de Cauchy (valeurs positives seulement). C'est un générateur de bruit de classe x.

## Syntaxe

    ares pcauchy kalpha

    ires pcauchy kalpha

    kres pcauchy kalpha

## Exécution

pcauchy kalpha -- contrôle l'étalement à partir de zéro (grand kalpha = grand étalement). Ne produit que des nombres positifs.

Pour des explications plus détaillées sur ces distributions, consulter :

1. C. Dodge - T.A. Jerse 1985. Computer music. Schirmer books. pp.265 - 286

2. D. Lorrain. A panoply of stochastic cannons. In C. Roads, ed. 1989. Music machine . Cambridge, Massachusetts: MIT press, pp. 351 - 379.

## Exemples

Voici un exemple de l'opcode pcauchy. Il utilise le fichier pcauchy.csd.

Exemple 725. Exemple de l'opcode pcauchy.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if real audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o pcauchy.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1  	; every run time same values

    kalpha	pcauchy	1000
    	printk	.2, kalpha		; look
    aout	oscili	0.8, 440+kalpha, 1	; & listen
    	outs	aout, aout
    endin

    instr 2		; every run time different values

    	seed 0
    kalpha	pcauchy	1000
    	printk	.2, kalpha		; look
    aout	oscili	0.8, 440+kalpha, 1	; & listen
    	outs	aout, aout
    endin
    </CsInstruments>
    <CsScore>
    ; sine wave
    f 1 0 16384 10 1

    i 1 0 2
    i 2 3 2
    e

    </CsScore>
    </CsoundSynthesizer>

Sa sortie contiendra des lignes comme celles-ci :

     i   1 time     0.00033:    10.48851
     i   1 time     0.20033:     0.29508
     i   1 time     0.40033:     1.75214
     i   1 time     0.60033:    22.88281
     i   1 time     0.80033:    16.06435
     i   1 time     1.00000:     0.43110
     i   1 time     1.20033:    16.51694
     i   1 time     1.40033:     2.98797
     i   1 time     1.60033:     1.32767
     i   1 time     1.80000:    17.94039
     i   1 time     2.00000:     4.85994
     Seeding from current time 1526147515
     i   2 time     3.00033:     0.89797
     i   2 time     3.20033:     9.19447
     i   2 time     3.40033:     0.73053
     i   2 time     3.60000:     7.43371
     i   2 time     3.80033:     5.87640
     i   2 time     4.00000:     0.80456
     i   2 time     4.20000:     4.50637
     i   2 time     4.40033:     2.08145
     i   2 time     4.60033:    13.47125
     i   2 time     4.80033:     3.16399
     i   2 time     5.00000:    11.05428

## Voir aussi

seed, betarand, bexprnd, cauchy, exprand, gauss, linrand, poisson, trirand, unirand, weibull

## Crédits

Auteur : Paris Smaragdis
MIT, Cambridge
1995

Précédent | Niveau supérieur | Suivant
paulstretch | Sommaire | pchbend