butterlp
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## butterlp

butterlp — Un filtre de Butterworth passe-bas.

## Description

Implémentation d'un filtre de Butterworth passe-bas du second ordre. Cet opcode peut aussi être écrit comme butlp.

## Syntaxe

    ares butterlp asig, kfreq [, iskip]

    ares butterlp asig, afreq [, iskip]

## Initialisation

iskip (facultatif, 0 par défaut) -- L'initialisation est ignorée s'il est présent et non nul.

## Exécution

Ces filtres sont des filtres RII de Butterworth du second ordre. Ils sont légèrement plus lents que les filtres originaux de Csound, mais ils offrent une bande passante presque plate et une précision et une atténuation de la bande bloquée très bonnes.

asig -- Signal d'entrée à filtrer.

kfreq/afreq -- Fréquence de coupure ou centrale pour chacun des filtres.

## Exemples

Voici un exemple de l'opcode butterlp. Il utilise le fichier butterlp.csd.

Exemple 109. Exemple de l'opcode butterlp.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;RT audio out
    ;-iadc    ;;;uncomment -iadc if RT audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o butterlp.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs = 1

    instr 1	; White noise signal

    asig rand 0.5
         outs asig, asig

    endin

    instr 2	; filtered noise

    asig rand 0.7
    alp  butterlp asig, 1000	  ;cutting frequencies above 1 KHz
         outs alp, alp

    endin

    </CsInstruments>
    <CsScore>

    i 1 0 2
    i 2 2.5 2
    e

    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

butterbp, butterbr, butterhp

## Crédits

Auteur : Paris Smaragdis
MIT, Cambridge
1995

Existait dans la version 3.30

Paramètres de taux audio introduits dans la version 6.02

Octobre 2013.

Précédent | Niveau supérieur | Suivant
butterhp | Sommaire | button