STKBrass
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## STKBrass

STKBrass — STKBrass est un simple instrument de la famille des cuivres.

## Description

Opcode du greffon stkopd.

STKBrass utilise un modèle simple à guide d'onde d'un instrument de la famille des cuivres, à la Cook.

## Syntaxe

    asignal STKBrass ifrequency, iamplitude, [klip, kv1[, kslide, kv2[, klfo, kv3[, klfodepth, kv4[, kvol, kv5]]]]]

## Initialisation

ifrequency -- Fréquence de la note jouée, en Hz.

iamplitude -- Amplitude de la note jouée (entre 0 et 1).

## Exécution

klip -- contrôleur 2, tension des lèvres. kv1 compris entre 0 et 127.

kslide -- contrôleur 4, longueur de la coulisse. kv2 compris entre 0 et 127.

klfo -- contrôleur 11, vitesse de l'oscillateur basse-fréquence. kv3 compris entre 0 et 127.

klfodepth -- contrôleur 1, intensité de l'oscillateur basse-fréquence. kv4 compris entre 0 et 127.

kvol -- contrôleur 128, volume. kv5 compris entre 0 et 127.

| Notes
Le code pour cet opcode vient directement de la classe Brass du Synthesis Toolkit en C++ par Perry R. Cook et Gary P. Scavone. On peut en savoir plus sur les classes STK ici : https://ccrma.stanford.edu/software/stk/classes.html kc1, kv1, kc2, kv2, kc3, kv3, kc4, kv4, kc5, kv5, kc6, kv6, kc7, kv7, kc8, kv8 -- Jusqu'à 8 paires de contrôle facultatives au taux-k pour les opcodes STK. Chaque paire de contrôle est constituée d'un numéro de contrôleur (kc) suivi d'une valeur de contrôleur (kv). Le numéro de contrôleur ainsi que la valeur associée sont des variables de taux-k. Cependant, durant l'exécution, les numéros de contrôleur sont habituellement constants tandis que les valeurs correspondantes peuvent changer à tout moment. L'ordre des paires de contrôle est arbitraire mais elles doivent apparaître après iamplitude. Il n'est pas non plus nécessaire d'utiliser toutes les paires.

## Exemples

Voici un exemple de l'opcode STKBrass. Il utilise le fichier STKBrass.csd.

Exemple 1003. Exemple de l'opcode STKBrass.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if RT audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o STKBrass.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1

    ifrq	=	p4
    kv1	line	p5, p3, p6					;lip tension
    kv3	line	p7, p3, p8					;speed of low-frequency oscillator

    asig	STKBrass cpspch(ifrq), 1, 2, kv1, 4, 100, 11, kv3, 1, 10, 128, 40
    asig	=	asig *3						;amplify
    	outs asig, asig
    endin

    </CsInstruments>
    <CsScore>

    i 1 0 2 8.05 100 120 50 0
    i 1 + 3 9.00  80 82 10 0
    e
    </CsScore>
    </CsoundSynthesizer>

## Crédits

Auteur : Michael Gogins (d'après Perry Cook)
Irreducible Productions
New York, NY

Nouveau dans la version 5.11 de Csound.

Précédent | Niveau supérieur | Suivant
STKBowed | Sommaire | STKClarinet