mvclpf4
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## mvclpf4

mvclpf4 — Emulation d'un filtre passe-bas de Moog contrôlé en tension.

## Description

mvclpf4 est une implémentation numérique du filtre en échelle de Moog du 4ème ordre (24 dB/oct) écrite à l'origine par Fons Andriaensen. C'est une version de l'opcode mvclpf3 avec quatre sorties pour les réponses en fréquence à 6dB, 12 dB, 18 dB et 24 dB/octave.

## Syntaxe

    asig1, asig2, asig3, asig4 mvclpf4 ain, xcf, xres[, istor]

## Initialisation

istor -- état initial de l'espace de données interne. Comme le filtrage comprend une boucle de rétroaction sur la sortie précédente, l'état initial de l'espace de stockage utilisé est significatif. Une valeur nulle provoquera l'effacement de cet espace ; une valeur non nulle autorisera la persistance de l'information précédente. La valeur par défaut est 0.

## Exécution

asig1 -- sortie de la réponse passe-bas à 6 dB/oct.

asig2 -- sortie de la réponse passe-bas à 12 dB/oct.

asig3 -- sortie de la réponse passe-bas à 18 dB/oct.

asig4 -- sortie de la réponse passe-bas à 24 dB/oct.

ain -- signal d'entrée.

xcf -- fréquence de coupure du filtre. L'intervalle utile est d'environ six octaves autour du do médian (pch 8.00).

xres -- résonance, limitée à l'intervalle [0, 1].

## Exemples

Voici un exemple de l'opcode mvclpf4. Il utilise le ficheir mvclpf4.csd.

Exemple 637. Exemple de l'opcode mvclpf4.

Voir les sections Audio en temps réel et Options de la ligne de commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    -odac
    </CsOptions>
    <CsInstruments>
    0dbfs = 1

    instr 1
     asig[] init 4
     kenv linen p4,0.1,p3,0.1
     ain rand kenv
     kfr expon 220, p3, 1760
     asig[0],asig[1],asig[2],asig[3] mvclpf4 ain,kfr,0.9
      out asig[p5]
    endin

    </CsInstruments>
    <CsScore>
    i1 0 5 0.9 0
    i1 + 5 0.9 1
    i1 + 5 0.9 2
    i1 + 5 0.9 3
    </CsScore>
    </CsoundSynthesizer>

## Crédits

Auteur : Fons Andriaensen,
Porté dans Csound par Victor Lazzarini
Janvier 2016

Nouveau dans la version 6.07

Janvier 2016.

Précédent | Niveau supérieur | Suivant
mvclpf3 | Sommaire | mvmfilter