gausstrig
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## gausstrig

gausstrig — Impulsions aléatoires autour d'une fréquence donnée.

## Description

Génère des impulsions aléatoires autour d'une fréquence donnée.

## Syntaxe

    ares gausstrig kamp, kcps, kdev [, imode] [, ifrst1]

    kres gausstrig kamp, kcps, kdev [, imode] [, ifrst1]

## Initialisation

imode (facultatif, 0 par défaut) -- imode > 0 signifie une meilleure modulation de fréquence. Si la fréquence change, le délai avant l'impulsion suivante est recalculé. Avec le mode par défaut, nous avons le comportement classique du générateur unitaire GaussTrig dans SuperCollider, où la modulation de fréquence est ignorée durant le délai précédant l'impulsion suivante.

ifrst1 (facultatif, 0 par défaut) -- ifrst1 > 0 change le comportement original du générateur unitaire GaussTrig. Par défaut, celui-ci génère toujours une impulsion au tout début. Ici, l'apparition de la première impulsion est aléatoire et dépend des paramètres kcps et kdev parameters.

## Exécution

kamp -- amplitude.

kcps -- la fréquence moyenne autour de laquelle sont distribuées les impulsions aléatoires.

kdev -- déviation aléatoire autour de la moyenne (0 <= dev < 1).

## Exemples

Voici un exemple de l'opcode gausstrig. Il utilise le fichier gausstrig.csd.

Exemple 405. Exemple de l'opcode gausstrig.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o oscil.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1

    kdev line 0, p3, 0.9
    seed 20120125
    aimp gausstrig 0.5, 10, kdev
    aenv filter2 aimp, 1, 1, 0.993, 0.993
    anoi fractalnoise 0.2, 1.7
    al   = anoi*aenv
    ar   delay al, 0.02
    outs al, ar

    endin
    </CsInstruments>
    <CsScore>
    i1 0 10
    e
    </CsScore>
    </CsoundSynthesizer>

Voici un exemple de l'opcode gausstrig avec imode = 1. Il utilise le fichier gausstrig-2.csd.

Exemple 406. Exemple de l'opcode gausstrig avec imode = 1.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o oscil.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1

    kfrq0 oscil 8, 0.25, 1
    ktrig metro 1
    kfrq  samphold kfrq0+8, ktrig
    seed  20120125
    aimp  gausstrig 0.5, kfrq, 0.5, 1
    aenv  filter2 aimp, 1, 1, 0.993, 0.993
    anoi  fractalnoise 0.2, 1.7
    al    = anoi*aenv
    ar    delay al, 0.02
    outs  al, ar

    endin
    </CsInstruments>
    <CsScore>
    f1 0 8192 10 1
    i1 0 16
    e
    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

dust dust2 mpulse

## Crédits

Basé sur le générateur unitaire GaussTrig de Bhob Rainey (SuperCollider)
Auteur : Tito Latini
Janvier 2012
Modification : Gleb Rogozinsky
Mars 2015

Nouveau dans la version 5.16 de Csound.

Précédent | Niveau supérieur | Suivant
gaussi | Sommaire | gbuzz