Instruction e
Précédent | Instructions de partition et routines GEN | Suivant

## Instruction e

e — On peut utiliser cette instruction pour marquer la fin de la dernière section de la partition.

## Description

On peut utiliser cette instruction pour marquer la fin de la dernière section de la partition.

## Syntaxe

    e [0 temps]

## Exécution

Le second p-champ temps est facultatif et s'il est présent, il détermine la date de fin (en pulsations) de la dernière section de la partition. Cette date doit être après le dernier évènement sinon elle n'aura pas d'effet. Les instruments "actifs en permanence" se termineront à cette date. Cette manière d'allonger la section est utile pour éviter les coupures prématurées de chute de réverbération ou d'autres effets.

### Considérations Spéciales

L'instruction e est contextuellement identique à une instruction s. De plus, l'instruction e termine toute génération de signal (y compris une exécution indéfinie) et ferme tous les fichiers d'entrée et de sortie.

Si une instruction e intervient avant la fin de la partition, toutes les lignes suivantes de la partition seront ignorées.

Dans un fichier de partition pas encore trié, l'instruction e est facultative. Si un fichier de partition n'a pas d'instruction e, alors la fonction Sort en fournira une.

## Exemples

Voici un exemple de l'instruction e. Il utilise le fichier e.csd.

Exemple 1253. Exemple de l'instruction e.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if RT audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o e.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    ga1 init 0

    instr 1

    aenv expseg .01, p3*0.1, 1, p3*0.9, 0.01
    ga1  poscil3 .5*aenv, cpspch(p4), 1
         outs ga1,ga1
    endin

    instr 99

    aL, aR  reverbsc ga1, ga1, 0.85, 12000, sr, 0.5, 1
    outs aL,aR

    ga1 = 0

    endin
    </CsInstruments>
    <CsScore>
    f 1 0 128 10 1		;sine wave

    i 1 1 0.1 8.00
    i 1 2 0.1 8.02
    i 1 3 0.1 8.04
    i 1 4 0.1 9.06

    i 99 0 6		;remains active for 6 seconds

    e10
    </CsScore>
    </CsoundSynthesizer>

Précédent | Niveau supérieur | Suivant
Instruction d (instruction de note) | Sommaire | Instruction f (ou instruction de table de fonction)