printk2
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## printk2

printk2 — Affiche une nouvelle valeur chaque fois qu'une variable de contrôle change.

## Description

Affiche une nouvelle valeur chaque fois qu'une variable de contrôle change.

## Syntaxe

    printk2 kvar [, inumspaces] [, inamed]

## Initialisation

inumspaces (facultatif, 0 par défaut) -- nombre d'espaces imprimés avant la valeur de kvar

inamed (facultatif, 0 par défaut) -- s'il est non nul, affiche le nom de la kvar ainsi que sa valeur.

## Exécution

kvar -- signal à imprimer

Dérivé du printk de Robin Whittle, il affiche une nouvelle valeur de kvar chaque fois que kvar change. Utile pour surveiller les changements des contrôles MIDI lorsque l'on utilise des réglettes.

| Avertissement
Ne pas utiliser cet opcode avec des signaux de taux-k normaux variant continuellement, car cela pourrait bloquer l'ordinateur, le taux d'impression devenant trop rapide.

## Exemples

Voici un exemple de l'opcode printk2. Il utilise le fichier printk2.csd.

Exemple 772. Exemple de l'opcode printk2.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac    ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o printk2.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1

    kval    randomh 0, 1.2, 20		;choose between 0 and 1.2
    if kval >0 && kval<=.5 then		;3 possible outcomes
    	kval = 1
    elseif kval >.5 && kval<=1 then
    	kval =2
    elseif kval >1 then
    	kval =3
    endif

    printk2 kval				;print value when it changes
    asig    poscil .7, 440*kval, 1
            outs asig, asig

    endin
    </CsInstruments>
    <CsScore>
    f1 0 16384 10 1

    i 1 0 5
    e
    </CsScore>
    </CsoundSynthesizer>

Sa sortie contiendra des lignes comme celles-ci :

     i1     0.00000
     i1     3.00000
     i1     1.00000
     i1     3.00000
     i1     1.00000
     i1     2.00000
     i1     3.00000

## Voir aussi

printk and printks

## Crédits

Auteur : Gabriel Maldonado
Italie
1998

Nouveau dans la version 3.48 de Csound

Option du nom ajoutée dans la 6.11

Précédent | Niveau supérieur | Suivant
printf | Sommaire | printk