GEN40
Précédent | Instructions de partition et routines GEN | Suivant

## GEN40

GEN40 — Génère une distribution aléatoire à partir d'un histogramme.

## Description

Génère une distribution aléatoire continue en partant de la forme d'un histogramme défini par l'utilisateur.

## Syntaxe

    f # date taille 40 tblforme

## Exécution

La forme de l'histogramme doit être stockée dans une table préalablement définie, en fait, tblforme doit contenir le numéro de cette table.

La forme de l'histogramme peut être générée avec n'importe quelle GEN routine. Comme il n'y a pas d'interpolation lorque GEN40 opère la traduction, il est suggéré de donner à la table contenant la forme de l'histogramme une taille raisonnablement grande, afin d'obtenir une meilleure précision (cependant, cette dernière table peut être détruite après le traitement pour récupérer de la mémoire).

Ce sous-programme est prévu pour être utilisé avec l'opcode cuserrnd (voir cuserrnd pour plus d'information).

## Exemples

Voici un exemple de l'opcode GEN40. Il utilise le fichier gen40.csd.

Exemple 1298. Exemple de l'opcode GEN40.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o GEN40.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1	; every run time same values

    kuser cuserrnd 0, 100, 1
          printk .2, kuser
    asig  poscil .5, 220+kuser, 3
          outs asig, asig
    endin

    instr 2	; every run time different values

          seed 0
    kuser cuserrnd 0, 100, 1
          printk .2, kuser
    asig  poscil .5, 220+kuser, 3
          outs asig, asig
    endin
    </CsInstruments>
    <CsScore>
    f 1 0 16 -7 1 4 0 8 0 4 1	;distrubution using GEN07
    f 2 0 16384 40 1		;GEN40 is to be used with cuserrnd
    f 3 0 8192 10 1			;sine

    i 1 0 2
    i 2 3 2
    e
    </CsScore>
    </CsoundSynthesizer>

Sa sortie contiendra des lignes comme celles-ci :

     i   1 time     0.00067:    53.14918
     i   1 time     0.20067:     0.00000
     i   1 time     0.40067:     0.00000
     i   1 time     0.60067:    96.80406
     i   1 time     0.80067:    94.20729
     i   1 time     1.00000:     0.00000
     i   1 time     1.20067:    86.13032
     i   1 time     1.40067:    31.37096
     i   1 time     1.60067:    70.35889
     i   1 time     1.80000:     0.00000
     i   1 time     2.00000:    49.18914

    WARNING: Seeding from current time 2006647442

     i   2 time     3.00067:    21.45002
     i   2 time     3.20067:    44.32333
     i   2 time     3.40067:    46.05420
     i   2 time     3.60000:     0.00000
     i   2 time     3.80067:    41.32175
     i   2 time     4.00000:     0.00000
     i   2 time     4.20000:    63.72019
     i   2 time     4.40067:     0.00000
     i   2 time     4.60067:     0.00000
     i   2 time     4.80067:     0.00000
     i   2 time     5.00000:    74.49330

Voici le diagramme de la forme d'onde de la routine GEN40 utilisée dans l'exemple :

f 2 0 16384 40 1

## Crédits

Auteur : Gabriel Maldonado

Précédent | Niveau supérieur | Suivant
GEN34 | Sommaire | GEN41