STKHevyMetl
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## STKHevyMetl

STKHevyMetl — STKHevyMetl produit des sons de type "heavy metal".

## Description

Opcode du greffon stkopd.

STKHevyMetl produit des sons de type "heavy metal" en utilisant la synthèse FM. Il utilise 3 opérateurs en cascade avec modulation en boucle de retour, aussi connu comme l'algorithme 3 du TX81Z.

## Syntaxe

    asignal STKHevyMetl ifrequency, iamplitude, [kmod, kv1[, kcross, kv2[, klfo, kv3[, klfodepth, kv4[, kadsr, kv5]]]]]

## Initialisation

ifrequency -- Fréquence de la note jouée, en Hz.

iamplitude -- Amplitude de la note jouée (entre 0 et 1).

## Exécution

kmod -- contrôleur 2, index total du modulateur. kv1 compris entre 0 et 127.

kcross -- contrôleur 4, fondu enchaîné du modulateur. kv2 compris entre 0 et 127.

klfo -- contrôleur 11, vitesse de l'oscillateur basse-fréquence. kv3 compris entre 0 et 127.

klfodepth -- contrôleur 1, intensité de l'oscillateur basse-fréquence. kv4 compris entre 0 et 127.

kadsr -- contrôleur 128, cible de l'ADSR 2 et 4. kv5 compris entre 0 et 127.

| Notes
Le code pour cet opcode vient directement de la classe HevyMetl du Synthesis Toolkit en C++ par Perry R. Cook et Gary P. Scavone. On peut en savoir plus sur les classes STK ici : https://ccrma.stanford.edu/software/stk/classes.html kc1, kv1, kc2, kv2, kc3, kv3, kc4, kv4, kc5, kv5, kc6, kv6, kc7, kv7, kc8, kv8 -- Jusqu'à 8 paires de contrôle facultatives au taux-k pour les opcodes STK. Chaque paire de contrôle est constituée d'un numéro de contrôleur (kc) suivi d'une valeur de contrôleur (kv). Le numéro de contrôleur ainsi que la valeur associée sont des variables de taux-k. Cependant, durant l'exécution, les numéros de contrôleur sont habituellement constants tandis que les valeurs correspondantes peuvent changer à tout moment. L'ordre des paires de contrôle est arbitraire mais elles doivent apparaître après iamplitude. Il n'est pas non plus nécessaire d'utiliser toutes les paires.

## Exemples

Voici un exemple de l'opcode STKHevyMetl. Il utilise le fichier STKHevyMetl.csd

Exemple 1008. Exemple de l'opcode STKHevyMetl.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if RT audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o STKHevyMetl.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1

    ifrq	=	p4
    kv1	line	p5, p3, p6				;Total Modulator Index
    kv2	line	p7, p3, 0				;Modulator Crossfade

    asig	STKHevyMetl cpspch(ifrq), 1, 2, kv1, 4, kv2, 11, 0, 1, 100, 128, 40
    	outs asig, asig
    endin

    </CsInstruments>
    <CsScore>
    i 1 0 7  8.05 100 0  100
    i 1 3 7   9.03 20 120  0
    i 1 3 .5  8.05 20 120  0
    i 1 4 .5  9.09 20 120  0
    i 1 5 3   9.00 20 120  0

    e
    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

STKWurley.

## Crédits

Auteur : Michael Gogins (d'après Perry Cook)
Irreducible Productions
New York, NY

Nouveau dans la version 5.11 de Csound.

Précédent | Niveau supérieur | Suivant
STKFMVoices | Sommaire | STKMandolin