FLbox
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## FLbox

FLbox — Un widget FLTK qui affiche du texte dans une boîte.

## Description

Un widget FLTK qui affiche du texte dans une boîte.

## Syntaxe

    ihandle FLbox "label", itype, ifont, isize, iwidth, iheight, ix, iy [, image]

    ihandle FLbox istr, itype, ifont, isize, iwidth, iheight, ix, iy [, image]

## Initialisation

ihandle -- un identifiant (un nombre entier) qui référence de manière univoque le widget correspondant. Il est utilisé par d'autres opcodes qui modifient les propriété du widget (voir Modifier l'Apparence des Widgets FLTK). Il est automatiquement retourné par FLbox et ne doit pas être fixé par l'étiquette de l'utilisateur. (L'étiquette de l'utilisateur est une chaîne entre guillemets contenant un texte fourni par l'utilisateur placé à côté du widget.)

« label » -- une chaîne entre guillemets contenant un texte fourni par l'utilisateur placé à côté du widget.

istr -- une valeur de taux-i utilisée pour obtenir une chaîne de caractères via strset, placée près du widget correspondant.

Noter qu'avec FLbox il n'est pas nécessaire d'appeler l'opcode FLsetTextType pour utiliser un symbole. Dans ce cas, il suffit d'utiliser une étiquette commençant par « @ » suivi de la chaîne de formatage correcte.

Les symboles suivants sont supportés :

Symboles d'étiquette FLTK supportés.

Le signe @ peut être suivi par les caractères de « formatage » facultatifs suivants, dans cet ordre :

1. « # » force une image carrée sans distortion de la forme du widget.

2. +[1-9] ou -[1-9] grossit ou diminue l'image.

3. [1-9] effectue une rotation d'un multiple de 45 degrés. « 6 » ne fait rien, les autres valeurs pointent dans la direction de cette touche sur un pavé numérique.

itype -- un nombre entier dénotant l'apparence du widget. Les valeurs suivantes sont acceptées :

- 1 - boîte sans relief

- 2 - boîte saillante

- 3 - boîte en creux

- 4 - boîte légèrement saillante

- 5 - boîte légèrement en creux

- 6 - boîte gravée

- 7 - boîte en relief

- 8 - boîte avec cadre

- 9 - boîte ombrée

- 10 - boîte arrondie

- 11 - boîte arrondie ombrée

- 12 - boîte arrondie sans relief

- 13 - boîte arrondie saillante

- 14 - boîte arrondie creuse

- 15 - boîte en losange saillante

- 16 - boîte en losange en creux

- 17 - boîte ovale

- 18 - boîte ovale ombrée

- 19 - boîte ovale sans relief

ifont -- un nombre entier dénotant le type de la police de FLbox. Les valeurs suivantes sont acceptées :

- 1 - helvetica (commes "Arial" sous Windows)

- 2 - helvetica gras

- 3 - helvetica italique

- 4 - helvetica gras italique

- 5 - courrier

- 6 - courrier gras

- 7 - courrier italique

- 8 - courrier gras italique

- 9 - times

- 10 - times gras

- 11 - times italique

- 12 - times gras italique

- 13 - symbol

- 14 - screen

- 15 - screen gras

- 16 - dingbats

isize -- taille de la police.

iwidth -- largeur du widget.

iheight -- hauteur du widget.

ix -- position horizontale du coin supérieur gauche du widget, relative au coin supérieur gauche de la fenêtre correspondante (exprimée en pixels).

iy -- position verticale du coin supérieur gauche du widget, relative au coin supérieur gauche de la fenêtre correspondante (exprimée en pixels).

image -- un identifiant faisant référence à une image éventuellement ouverte avec l'opcode bmopen. S'il est utilisé, cela permet un skin pour ce widget.

| Note sur l'opcode bmopen
Bien qu'il soit mentionné, l'opcode bmopen n'a pas été implémenté dans Csound 4.22.

## Exécution

FLbox est utile pour montrer du texte dans une fenêtre. Le texte est à l'intérieur d'une boîte dont l'aspect dépent de l'argument itype.

Noter que FLbox n'est pas un valuateur et que sa valeur est constante. Elle ne peut pas être modifiée.

## Exemples

Voici un exemple de l'opcode FLbox. Il utilise le fichier FLbox.csd.

Exemple 306. Exemple de l'opcode FLbox.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    ; Audio out   Audio in    No messages
    -odac           -iadc     -d     ;;;RT audio I/O
    ; For Non-realtime ouput leave only the line below:
    ; -o FLbox.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    kr = 441
    ksmps = 100
    nchnls = 1

    FLpanel "Text Box", 700, 400, 50, 50
        ; Box border type (7=embossed box)
        itype = 7
        ; Font type (10='Times Bold')
        ifont = 10
        ; Font size
        isize = 20
        ; Width of the flbox
        iwidth = 400
        ; Height of the flbox
        iheight = 30
        ; Distance of the left edge of the flbox
        ; from the left edge of the panel
        ix = 150
        ; Distance of the upper edge of the flbox
        ; from the upper edge of the panel
        iy = 100

        ih3 FLbox "Use Text Boxes For Labelling", itype, ifont, isize, iwidth, iheight, ix, iy
    ; End of panel contents
    FLpanelEnd
    ; Run the widget thread!
    FLrun

    instr 1
    endin

    </CsInstruments>
    <CsScore>

    ; Real-time performance for 1 hour.
    f 0 3600
    e

    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

FLbutBank, FLbutton, FLprintk, FLprintk2, FLvalue

## Crédits

Auteur : Gabriel Maldonado

Nouveau dans la version 4.22

Exemple écrit par Iain McCurdy, édité par Kevin Conder.

Précédent | Niveau supérieur | Suivant
flashtxt | Sommaire | FLbutBank