<
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## <

< — Détermine si une valeur est inférieure à l'autre.

## Description

Détermine si une valeur est inférieure à l'autre.

## Syntaxe

    (a <  b ? v1 : v2)

où a, b, v1 et v2 peuvent être des expressions, mais a, b pas de taux audio.

## Exécution

Dans l'expression conditionnelle ci-dessus, a et b sont d'abord comparés. Si la relation indiquée est vraie (a inférieur à b), alors l'expression conditionnelle prend la valeur de v1 ; si la relation est fausse, l'expression prend la valeur de v2.

Nota Bene : Si v1 ou v2 sont des expressions, elles seront évaluées avant que l'expression conditionnelle ne soit déterminée.

En terme de précédence, tous les opérateurs conditionnels (c-à-d. les opérateurs relationnels (<, etc.), et ?, et : ) sont plus faibles que les opérateurs arithmétiques et logiques (+, -, *, /, && et ||).

Ce sont des opérateurs pas des opcodes. C'est pourquoi on peut les utiliser dans les instructions de l'orchestre, mais ils ne forment pas des instructions complètes par eux-mêmes.

## Exemples

Voici un exemple de l'opérateur <. Il utilise le fichier lessthan.csd.

Exemple 21. Exemple de l'opérateur <.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac  ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o <.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1

    ipch = p4
    ipitch	= (ipch < 15 ? cpspch(ipch) : ipch)	;if p4 is lower then 15, it assumes p4 to be pitch-class
    print ipitch					;and not meant to be a frequency in Hertz
    asig  poscil .5,  ipitch , 1
          outs asig, asig

    endin
    </CsInstruments>
    <CsScore>
    f1 0 8192 10 1	;sine wave

    i1 0  3 8.00	;pitch class
    i1 4  3 800	;frequency

    e
    </CsScore>
    </CsoundSynthesizer>

Sa sortie contiendra des lignes comme :

    ipitch = 261.626
    ipitch = 800.00

## Voir aussi

==, >=, >, <=, !=

Précédent | Niveau supérieur | Suivant
>= | Sommaire | <=