gainslider
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## gainslider

gainslider — Une implémentation de courbe de gain logarithmique qui est semblable à l'objet gainslider~ de Cycling 74 Max / MSP.

## Description

Cet opcode sert à être multiplié par un signal audio pour donner la même impression qu'avec une console de mixage. Il n'y a pas de limites dans le code source si bien que l'on peut par exemple donner des valeurs supérieures à 127 pour obtenir un signal audio plus fort mais avec un risque d'écrêtage.

## Syntaxe

    kout gainslider kindex

## Exécution

kindex -- Valeur d'indice. Intervalle nominal de 0 à 127. Par exemple un intervalle de 0 à 152 donnera un intervalle de -∞ à +18,0 dB.

kout -- Sortie pondérée.

## Exemples

Voici un exemple de l'opcode gainslider. Il utilise le fichier gainslider.csd.

Exemple 401. Exemple de l'opcode gainslider.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    ; Audio out   Audio in    Silent
    -odac           -iadc     -d    ;;;realtime output
    </CsOptions>
    <CsInstruments>

    sr	=	48000
    ksmps	=	100
    nchnls	=	2

    		instr	1	; gainslider test

    ; uncomment for realtime midi
    ;kmod	ctrl7	1, 1, 0, 127

    ; uncomment for non realtime
    km0d phasor 1/10
    kmod scale km0d, 127, 0

    kout	gainslider	kmod

    	printks	"kmod = %f  kout = %f\\n", 0.1, kmod, kout

    aout	diskin2	"fox.wav", 1, 0, 1

    aout	=	aout*kout

    	outs	aout, aout

    		endin

    </CsInstruments>
    <CsScore>
    i1	0	30
    e
    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

scale, logcurve, expcurve

## Crédits

Auteur : David Akbari
Octobre
2006

Précédent | Niveau supérieur | Suivant
gain | Sommaire | gtf