fluidNote
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## fluidNote

fluidNote — Joue une note sur un canal dans un moteur fluidsynth.

## Syntaxe

    fluidNote ienginenum, ichannelnum, imidikey, imidivel

## Description

Opcode du greffon fluidOpcodes.

Joue une note de hauteur imidikey et de vélocité imidivel sur le canal ichannelnum du fluidEngine numéro ienginenum.

## Initialisation

ienginenum -- numéro du moteur affecté par fluidEngine

ichannelnum -- numéro de canal sur lequel jouer la note dans le fluidEngine donné

imidikey -- touche MIDI de la note (0-127)

imidivel -- vélocité MIDI de la note (0-127)

## Exemples

Voici un exemple de l'opcode fluidNote. Il utilise les fichiers fluidNote.csd et 19Trumpet.sf2.

Exemple 338. Exemple de l'opcode fluidNote.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac   -+rtmidi=virtual  -M0    ;;;realtime audio out and realtime midi in
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ;-o fluidNote.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs = 1

    giengine fluidEngine
    ; soundfont path to manual/examples
    isfnum	 fluidLoad "19Trumpet.sf2", giengine, 1
    	 fluidProgramSelect giengine, 1, isfnum, 0, 56

    instr 1

    	mididefault   60, p3
    	midinoteonkey p4, p5
    ikey	init p4
    ivel	init p5
    	fluidNote giengine, 1, ikey, ivel

    endin

    instr 99

    imvol  init 7
    asigl, asigr fluidOut giengine
           outs asigl*imvol, asigr*imvol

    endin
    </CsInstruments>
    <CsScore>

    i 1 0 2 60 100 ;play one note from score and...
    i 99 0 60      ;play virtual keyboard for 60 sec.
    e

    </CsScore>
    </CsoundSynthesizer>

Sa sortie contiendra une ligne comme celle-ci :

    SoundFont:   1  Bank:   0  Preset:  56  Trumpet metallic

## Voir aussi

fluidEngine, fluidLoad

Plus d'information sur soundfonts dans les Floss Manuals : https://flossmanual.csound.com/midi/reading-midi-files

D'autres informations au sujet de soundfonts sur Wikipedia : http://en.wikipedia.org/wiki/Soundfont

## Crédits

Michael Gogins (gogins@pipeline.com), Steven Yi. Merci à Peter Hanappe pour Fluidsynth.

Précédent | Niveau supérieur | Suivant
fluidLoad | Sommaire | fluidOut