plltrack
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## plltrack

plltrack — Traque la hauteur d'un signal.

## Description

plltrack est un détecteur de hauteur basé sur un algorithme de boucle à verrouillage de phase, décrit par Zolzer, U, Sankarababu, S.V. et Moller, S, "PLL-based Pitch Detection and Tracking for Audio Signals. Proc. of IIH-MSP 2012".

## Syntaxe

    acps, alock plltrackasig, kd [, kloopf, kloopq, klf, khf, kthresh]

## Exécution

acps -- hauteur estimée en Hz.

alock -- indicateur du verrouillage de phase, une erreur de phase indiquant la qualité de la détection, avec des valeurs comprises entre 0 et 1. Les plus grandes valeurs dénotent une bonne détection.

kd -- Gain de rétroaction de la PLL. Contrôle l'intervalle de fréquence de la PLL (entre 0 et 1). Les plus grandes valeurs augmentent l'intervalle de détection.

kloopf -- Fréquence de coupure du filtre passe-bas de la PLL. Contrôle l'intervalle de fréquence de la PLL (facultatif, vaut 20 Hz par défaut).

kloopq -- Q du filtre passe-bas de la PLL. Contrôle le temps de montée vers la fréquence centrale (facultatif, vaut 1/3 par défaut).

klf -- fréquence de détection la plus basse (facultatif, vaut 20 Hz par défaut)

khf -- fréquence de détection la plus haute (facultatif, vaut 1500 Hz par défaut)

kthresh -- seuil de niveau du signal de détection (facultatif, vaut 0.001 par défaut, ce qui équivaut à -60 dBfs)

plltrack analyse le signal d'entrée asig, estimant la fondamentale d'un signal monophonique. Sa sortie est actualisée à chaque échantillon.

## Exemples

Voici un exemple de l'opcode plltrack. Il utilise le fichier plltrack.csd.

Exemple 754. Exemple de l'opcode plltrack.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac    ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o plltrack.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1

    kd = p4
    a1 diskin2 "fox.wav", 1,0,1
    apitch, aloc plltrack a1, kd
    krms rms a1
    krms port krms, 0.01
    asig buzz krms, apitch, 10, 1
         outs asig, asig		;mix in some dry signal as well

    endin
    </CsInstruments>
    <CsScore>
    f1 0 65536 10 1	;sine wave

    i 1 0 6 0.1
    i 1 7 6 0.3	;more feedback

    e
    </CsScore>
    </CsoundSynthesizer>

## Crédits

Auteur : Victor Lazzarini
NUI, Maynooth.
Maynooth, Ireland
Septembre, 2012

Nouveau dans la version 5.18.031 de Csound.

Précédent | Niveau supérieur | Suivant
platerev | Sommaire | pluck