sleighbells
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## sleighbells

sleighbells — Modèle semi-physique d'un son de cloche de traineau.

## Description

sleighbells est un modèle semi-physique d'un son de cloche de traineau. Il fait partie des opcodes de percussion de PhISEM. PhISEM (Physically Informed Stochastic Event Modeling) est une approche algorithmique pour simuler les collisions de multiples objets indépendants produisant des sons.

## Syntaxe

    ares sleighbells kamp, idettack [, inum] [, idamp] [, imaxshake] [, ifreq] \
          [, ifreq1] [, ifreq2]

## Initialisation

idettack -- période de temps durant laquelle tous les sons sont stoppés.

inum (facultatif) -- le nombre de perles, de dents, de cloches, de tambourins, etc. S'il vaut zéro, il prend la valeur par défaut de 32.

idamp (facultatif) -- le facteur d'amortissement, intervenant dans l'équation :

damping_amount = 0,9994 + (idamp * 0,002)

La valeur par défaut de damping_amount est 0,9994 ce qui signifie que la valeur par défaut de idamp est 0. Le maximum de damping_amount est 1,0 (pas d'amortissement). La valeur maximale de idamp est donc 0,03.

L'intervalle recommandé pour idamp se situe d'habitude sous les 75% de la valeur maximale.

imaxshake (facultatif, 0 par défaut) -- quantité d'énergie à réinjecter dans le système. La valeur doit être comprise entre 0 et 1.

ifreq (facultatif) -- la fréquence de résonance principale. La valeur par défaut est 2500.

ifreq1 (facultatif) -- la première fréquence de résonance. La valeur par défaut est 5300.

ifreq2 (facultatif) -- la deuxième fréquence de résonance. La valeur par défaut est 6500.

## Exécution

kamp -- Amplitude de la sortie. Note : comme ces instruments sont stochastiques, ce n'est qu'une approximation.

## Exemples

Voici un exemple de l'opcode sleighbells. Il utilise le fichier sleighbells.csd.

Exemple 970. Exemple de l'opcode sleighbells.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac      ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o sleighbells.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1

    idamp = p4
    asig  sleighbells .7, 0.01, 32, idamp, 0.55
          outs asig, asig

    endin
    </CsInstruments>
    <CsScore>

    i 1 0.00 0.25 0	;short sound
    i 1 0.30 0.25
    i 1 0.60 0.25
    i 1 0.90 0.25
    i 1 1.20 0.25
    i 1 1.50 1   .3	;longer sound
    i 1 1.80 0.25 0	;short sound again
    i 1 2.10 0.25
    i 1 2.40 0.25
    i 1 2.70 0.25
    i 1 3.00 0.25
    e

    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

bamboo, dripwater, guiro, tambourine

## Crédits

Auteur : Perry Cook, fait partie de PhISEM (Physically Informed Stochastic Event Modeling)
Adapté par John ffitch
Université de Bath, Codemist Ltd.
Bath, UK

Nouveau dans la version 4.07 de Csound

Notes ajoutées par Rasmus Ekman en mai 2002.

Précédent | Niveau supérieur | Suivant
skf | Sommaire | slicearray