GEN24
Précédent | Instructions de partition et routines GEN | Suivant

## GEN24

GEN24 — Lit les valeurs numériques d'une table de fonction déjà allouée en les reproportionnant.

## Description

Ce sous-programme lit les valeurs numériques d'une table de fonction déjà allouée et les reproportionne selon les valeurs min et max données par l'utilisateur.

## Syntaxe

    f # date taille -24 ftable min max

## Initialisation

#, date, taille -- les paramètres GEN habituels. Voir l'instruction f.

ftable -- ftable doit être une table déjà allouée avec la même taille que cette fonction.

min, max -- l'intervalle de recadrage.

| Note
Ce GEN est utile, par exemple, pour éliminer le décalage du début dans les morceaux d'exponentielle permettant d'avoir une vrai origine à zéro.

## Exemples

Voici un exemple de la routine GEN24. Il utilise le fichier gen24.csd.

Exemple 1289. Exemple de la routine GEN24.

Voir les sections Audio en Temps Réel et Options de Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac  ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o gen24.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1

    ifn  = p4				;choose between tables
    kcps init 1/p3				;create index over duration of note.
    kndx phasor kcps
    ixmode = 1				;normalize to 0-1
    kval table kndx, ifn, ixmode
    asig poscil .7, 440 + kval, 1		;add to frequency
         outs asig, asig

    endin
    </CsInstruments>
    <CsScore>
    f 1 0 16384 10 1	;sine wave
    f 10 0 16384 -24 1 0 400;scale sine wave from table 1 from 0 to 400
    f 11 0 16384 -24 1 0 50	;and from 0 to 50

    i 1 0 3 10
    i 1 4 3 11
    e
    </CsScore>
    </CsoundSynthesizer>

## Crédits

Auteur : Gabriel Maldonado

Nouveau dans la version 4.16 de Csound

Précédent | Niveau supérieur | Suivant
GEN23 | Sommaire | GEN25