fmvoice
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## fmvoice

fmvoice — Synthèse FM d'une Voix de Chanteur

## Description

Synthèse FM d'une Voix de Chanteur

## Syntaxe

    ares fmvoice kamp, kfreq, kvowel, ktilt, kvibamt, kvibrate[, ifn1, \
          ifn2, ifn3, ifn4, ivibfn]

## Initialisation

ifn1, ifn2, ifn3,ifn3 -- Tables, normalement des formes d'onde sinus.

## Exécution

kamp -- Amplitude de la note.

kfreq -- Fréquence de la note jouée.

kvowel -- La voyelle chantée, dans l'intervalle 0-64

ktilt -- La pente spectrale du son dans l'intervalle 0 à 99

kvibamt -- Largeur du vibrato

kvibrate -- Vitesse du vibrato

## Exemples

Voici un exemple de l'opcode fmvoice. Il utilise le fichier fmvoice.csd.

Exemple 354. Exemple de l'opcode fmvoice.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o fmvoice.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1

    kfreq = 110
    kvowel = p4	; p4 = vowel (0 - 64)
    ktilt  = p5
    kvibamt = 0.005
    kvibrate = 6

    asig fmvoice .5, kfreq, kvowel, ktilt, kvibamt, kvibrate, 1, 1, 1, 1, 1
    outs asig, asig

    endin
    </CsInstruments>
    <CsScore>
    ;  sine wave.
    f 1 0 16384 10 1

    i 1 0 1 1  0	; tilt=0
    i 1 1 1 >  .
    i 1 2 1 >  .
    i 1 3 1 >  .
    i 1 4 1 >  .
    i 1 5 1 >  .
    i 1 6 1 >  .
    i 1 7 1 12 .

    i 1 10 1 1  90	; tilt=90
    i 1 11 1 >  .
    i 1 12 1 >  .
    i 1 13 1 >  .
    i 1 14 1 >  .
    i 1 15 1 >  .
    i 1 16 1 >  .
    i 1 17 1 12 .

    e
    </CsScore>
    </CsoundSynthesizer>

## Crédits

Auteur : John ffitch (d'après Perry Cook)
University of Bath, Codemist Ltd.
Bath, UK

Nouveau dans la version 3.47 de Csound

Précédent | Niveau supérieur | Suivant
fmrhode | Sommaire | fmwurlie