resonbnk
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## resonbnk

resonbnk — Un banc de filtre à résonance.

## Description

Cet opcode prend un tableau de paramètres de filtre sous forme de paires fréquence-largeur de bande et construit une banque de résonateurs du second ordre, en connexions parallèle ou série.

## Syntaxe

    asigresonbnk ain, kPar[], kmin, kmax, iper[,imode, iscal, iskip]

## Initialisation

iper -- période d'interpolation des paramètres du filtre (en échantillons).

imode -- mode de connexion du filtre (0 = série, 1 = parallèle, vaut 1 par défaut).

iscal -- mode de pondération du filtre (0 = pas de pondération, modes 1 et 2 comme dans reson, vaut 0 par défaut).

iskip -- ignore l'initialisation si différent de zéro (vaut 0 par défaut).

## Exécution

asig -- signal de sortie.

asig -- signal d'entrée.

kPar[] -- paramètres du filtre sous forme de paires fréquence-largeur de bande.

kmin -- fréquence minimale de filtre.

kmax -- fréquence maximale de filtre.

Cet opcode fait partie d'une suite d'opcodes de prédiction linéaire sur un flux. Il prend un tableau de paramètres de filtre sous forme de paires fréquence/largeur de bande et crée un banc de filtres. Les fréquence minimales et maximales de filtre utilisées dans le banc de filtre sont fixées par kmin et kmax, et tous les filtres dont les fréquences sont en-dehors de cet intervalle sont exclus du banc de filtre. Les coefficients de filtre sont calculés chaque iper échantillons et interpolés linéairement entre chaque calcul.

## Exemples

Voici un exemple de l'opcode resonbnk utilisant un signal audio en entrée comme source lpc. Il utilise le fichier resonbnk.csd.

Exemple 883. Exemple de l'opcode resonbnk.

Voir les sections Audio en temps réel et Options de la ligne de commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    -odac -d
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 64
    nchnls = 1
    0dbfs = 1

    gifw ftgen 0,0,1024,20,2,1
    instr 1
    a1 diskin "fox.wav",1,0,1
    kcfs[],krms,kerr,kcps lpcanal a1,1,512,1024,50,gifw
    a2 rand 0dbfs
    kpar[] apoleparams kcfs
    kmin expseg 8000,p3/4,200,3*p3/4,600
    a3 resonbnk a2*krms*kerr/4,kpar,kmin,16000-kmin,512,1
      out a3
    endin

    </CsInstruments>
    <CsScore>

    i1 0 32
    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

lpcanal, resonbnk

Précédent | Niveau supérieur | Suivant
reson | Sommaire | resonk