reson
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## reson

reson — Un filtre à résonance du second ordre.

## Description

Un filtre à résonance du second ordre.

## Syntaxe

    ares reson asig, xcf, xbw [, iscl] [, iskip]

## Initialisation

iscl (facultatif, 0 par défaut) -- facteur de pondération codé pour les résonateurs. Une valeur de 1 signifie que la crête du facteur de réponse est 1, c-à-d. toutes les fréquences autres que kcf sont atténuées selon la courbe de réponse (normalisée). Une valeur de 2 élève le facteur de réponse de façon à ce que sa valeur efficace globale soit égale à 1. Cette égalisation intentionnelle des puissances d'entrée et de sortie suppose que toutes les fréquences sont présentes ; elle est ainsi plus appropriée au bruit blanc. Une valeur de 0 signifie aucune pondération du signal, laissant cette tâche à un ajustement ultérieur (voir balance). La valeur par défaut est 0.

iskip (facultatif, 0 par défaut) -- état initial de l'espace de données interne. Comme le filtrage comprend une boucle de rétroaction sur la sortie précédente, l'état initial de l'espace de stockage utilisé est significatif. Une valeur nulle provoquera l'effacement de cet espace ; une valeur non nulle autorisera la persistance de l'information précédente. La valeur par défaut est 0.

## Exécution

ares -- le signal de sortie au taux audio.

asig -- le signal d'entrée au taux audio.

xcf -- la fréquence centrale du filtre, ou position fréquentielle de la crête de la réponse.

xbw -- largeur de bande du filtre (la différence en Hz entre les points haut et bas à mi-puissance).

reson est un filtre de second ordre dans lequel kcf contrôle la fréquence centrale, ou position fréquentielle de la crête de la réponse, et kbw contrôle sa largeur de bande (la différence en fréquence entre les points haut et bas à mi-puissance).

## Exemples

Voici un exemple de l'opcode reson. Il utilise le fichier reson.csd.

Exemple 882. Exemple de l'opcode reson.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac   ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o reson.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    0dbfs  = 1
    nchnls = 2

    instr 1

    asaw vco2 .2, 220	;sawtooth
    kcf  line 220, p3, 1760	;vary cut-off frequency from 220 to 1280 Hz
    kbw  = p4		;vary bandwidth of filter too
    ares reson asaw, kcf, kbw
    asig balance ares, asaw
         outs asig, asig

    endin
    </CsInstruments>
    <CsScore>

    i 1 0 4 10	;bandwidth of filter = 10 Hz
    i 1 + 4 50	;50 Hz and
    i 1 + 4 200	;200 Hz
    e
    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

areson, aresonk, atone, atonek, port, portk, resonk, tone, tonek

## Crédits

Paramètres de taux audio introduits dans la version 6.02

Octobre 2013.

Précédent | Niveau supérieur | Suivant
reshapearray | Sommaire | resonbnk