OSCbundle
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## OSCbundle

OSCbundle — Envoie des données à d'autres processus en utilisant le protocole OSC en assemblant les messages dans un paquet.

## Description

Utilise le protocole OSC pour envoyer un ou plusieurs messages à d'autres processus OSC à l'écoute, dans un paquet unique. Contrairement à OSCsend il peut être utilisé pour envoyer plusieurs messages en même temps, mais seuls les types numériques standard d'OSC sont permis.

## Syntaxe

    OSCbundle kwhen, ihost, iport, \
           Sdest[], Stype[],kArgs[][][, isize]

## Initialisation

ihost -- a string that is the intended host computer domain name. An empty string is interpreted as the current computer.

iport -- le numéro du port utilisé pour la communication.

isize -- taille maximale de paquet en octets, 65536 par défaut.

## Exécution

kwhen -- un paquet de messages est envoyé chaque fois que cette valeur change. Un message sera toujours envoyé lors du premier appel.

Sdest[] -- un tableau de chaînes de caractères contenant l'adresse de destination pour chaque message. Sa longueur doit être conforme à celle de Stype[].

Stype[] -- un tableau de chaînes de caractères contenant les types de chaque message. Seuls les types numériques ('i' pour entiers et 'f' pour flottants) sont supportés. Sa longueur doit être conforme à celle de Sdest[].

kArg[][] -- un tableau bidimensionnel contenant les arguments pour chaque message. Sa dimension 1 (nombre de lignes) doit correspondre à celles de Sdest[] et de Stype[]. sa dimension 2 (nombre de colonnes) doit être suffisamment grande pour s'adapter au message avec le plus grand nombre d'arguments. Chaque ligne doit contenir les arguments pour les types de chaque message. Si une ligne contient moins d'arguments, les places des données restantes sont remplies avec des zéros. Les arguments en sus de ceux que chaque chaîne de caractères de type demande sont ignorés.

## Exemple

Voici un exemple de l'opcode OSCBundle. Il utilise le fichier oscbundle.csd.

Exemple 680. Exemple de l'opcode OSCBundle.

Voir les sections Audio en temps réel et Options de la ligne de commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    -odac
    </CsOptions>
    <CsInstruments>

    instr 1
    Sdest[] init 2
    Stype[] init 2
    kdata[][] init 2, 2

    Sdest[0] = "/test/floats"
    Sdest[1] = "/test/ints"
    Stype[0] = "ff"
    Stype[1] = "ii"

    kdata fillarray 1,2,3,4

    OSCbundle  1, "localhost", 7000, Sdest, Stype, kdata
    endin

    </CsInstruments>
    <CsScore>
    i1 0 1
    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

OSClisten, OSCinit

## Crédits

Auteur : Victor Lazzarini
2018

Précédent | Niveau supérieur | Suivant
oscilx | Sommaire | OSCcount