voice
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## voice

voice — Simulation d'une voix humaine.

## Description

Simulation d'une voix humaine.

## Syntaxe

    ares voice kamp, kfreq, kphoneme, kform, kvibf, kvamp, ifn, ivfn

## Initialisation

ifn, ivfn -- numéros des deux tables contenant la forme d'onde de la porteuse et la forme d'onde du vibrato. Les fichiers impuls20.aiff, ahh.aiff, eee.aiff ou ooo.aiff conviennent pour la première, et la deuxième peut contenir une sinusoïde. Ces fichiers sont disponibles à ftp://ftp.cs.bath.ac.uk/pub/dream/documentation/sounds/modelling/.

## Exécution

kamp -- Amplitude de la note.

kfreq -- Frequency de la note. Elle peut varier pendant l'exécution.

kphoneme -- un entier compris entre 0 et 16, pour choisir les formants des sons :

- « eee », « ihh », « ehh », « aaa »,

- « ahh », « aww », « ohh », « uhh »,

- « uuu », « ooo », « rrr », « lll »,

- « mmm », « nnn », « nng », « ngg ».

Actuellement les phonèmes

- « fff », « sss », « thh », « shh »,

- « xxx », « hee », « hoo », « hah »,

- « bbb », « ddd », « jjj », « ggg »,

- « vvv », « zzz », « thz », « zhh »

ne sont pas disponibles (!)

kform -- gain pour le phonème. Des valeurs entre 0,0 et 1,2 sont recommandées.

kvibf -- fréquence du vibrato en Hertz. On suggère des valeurs entre 0 et 12

kvamp -- amplitude du vibrato

## Exemples

Voici un exemple de l'opcode voice. Il utilise les fichiers voice.csd et impuls20.aiff.

Exemple 1180. Exemple de l'opcode voice.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac  ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o voice.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1

    kamp  = p4
    kphon = p5
    asig  voice kamp, 200, kphon, 0.488, 0, 1, 1, 2
          outs asig, asig

    endin
    </CsInstruments>
    <CsScore>
    f 1 0 256 1 "impuls20.aiff" 0 0 0	;audio file for the carrier waveform
    f 2 0 256 10 1				;sine wave for the vibrato waveform

    ;       ampl phoneme
    i 1 0 2 0.8    1
    i 1 + . 0.6    2
    i 1 + . 1.8    3
    i 1 + . 15.0   4
    i 1 + . 0.05   5
    i 1 + . 0.06   6
    i 1 + . 0.03   7
    i 1 + . 0.0002 8
    i 1 + . 0.1    9
    i 1 + . 0.5   10
    i 1 + . 100   11
    i 1 + . 0.03  12
    i 1 + . 0.04  13
    i 1 + . 0.04  14
    i 1 + . 0.04  15
    i 1 + . 0.05  16

    e
    </CsScore>
    </CsoundSynthesizer>

## Crédits

Auteur : John ffitch (d'après Perry Cook)
Université de Bath, Codemist Ltd.
Bath, UK

Nouveau dans la version 3.47 de Csound

Précédent | Niveau supérieur | Suivant
vmultv_i | Sommaire | vosim