ftmorf
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## ftmorf

ftmorf — Fondu enchaîné entre plusieurs ftables données dans une liste.

## Description

Utilise un index dans une table de numéros de ftable pour faire un fondu enchaîné entre les tables voisines dans la liste. La fonction résultante est écrite dans la table référencée par iresfn à chaque cycle-k.

## Syntaxe

    ftmorf kftndx, iftfn, iresfn

## Initialisation

iftfn -- la table contenant les numéros des tables existantes qui sont utilisées pour le fondu enchaîné.

iresfn -- numéro de table de la fonction résultante.

Toutes les tables référencées dans iftfn doivent avoir la même longueur que iresfn.

## Exécution

kftndx -- l'index dans la table iftfn.

Si iftfn contient (6, 4, 6, 8, 7, 4):

- kftndx=4 écrira le contenu de f7 dans iresfn.

- kftndx=4.5 écrira la moyenne des contenus de f7 et de f4 dans iresfn.

| Note
iresfn n'est mise à jour que si l'indice du fondu enchaîné change de valeur. Si kftindx est statique, il n'y a pas d'écriture dans iresfn.

## Exemples

Voici un exemple de l'opcode ftmorf. Il utilise le fichier ftmorf.csd.

Exemple 391. Exemple de l'opcode ftmorf.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o ftmorf.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs   =1

    instr 1

    kndx  line   0, p3, 7
          ftmorf kndx, 1, 2
    asig  oscili .8, 440, 2
          outs   asig, asig

    endin
    </CsInstruments>
    <CsScore>

    f1 0 8 -2 3 4 5 6 7 8 9 10
    f2 0 1024 10 1 /*contents of f2 dont matter */
    f3 0 1024 10 1
    f4 0 1024 10 0 1
    f5 0 1024 10 0 0 1
    f6 0 1024 10 0 0 0 1
    f7 0 1024 10 0 0 0 0 1
    f8 0 1024 10 0 0 0 0 0 1
    f9 0 1024 10 0 0 0 0 0 0 1
    f10 0 1024 10 1 1 1 1 1 1 1

    i1 0 15
    e
    </CsScore>
    </CsoundSynthesizer>

## Crédits

Author : William « Pete » Moss
Université du Texas à Austin
Austin, Texas USA
Janvier 2002

Nouveau dans la version 4.18

Précédent | Niveau supérieur | Suivant
ftlptim | Sommaire | ftom