sc_phasor
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## sc_phasor

sc_phasor — Une rampe linéaire réinitialisable entre deux niveaux (renommé trigphasor.

## Description

Opcode du greffon scugens.

Une rampe linéaire réinitialisable entre deux niveaux. Adapté du Phasor de Supercollider. Obsolète (renommétrigphasor).

## Syntaxe

    aindex sc_phasor xtrig, xrate, kstart, kend [, kresetPos]

    kindex sc_phasor xtrig, xrate, kstart, kend [, kresetPos]

## Exécution

Le phaseur produit une rampe linéaire entre les valeurs de kstart et de kend. Quand son entrée de déclenchement passe de valeurs non positives à des valeurs positives, la sortie de sc_phasor saute à sa position de reset (ou à kstart si aucune valeur de reset n'a été donnée). Lorsqu'il atteint la fin de sa rampe, sc_phasor recommence au début.

Si kresetPos est spécifié, cette valeur sera utilisée après un déclenchement. Sinon, un déclenchement ramènera à la position de kstart.

Si l'on veut que sc_phasor produise un signal de fréquence freq oscillant entre start et end, la valeur de rate doit être :

(end - start) * freq / sr

## Exemples

Voici un exemple de l'opcode sc_phasor. Il utilise le fichier sc_phasor.csd.

Exemple 931. Exemple de l'opcode sc_phasor.

Voir les sections Audio en temps réel et Options de la ligne de commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 128
    nchnls = 2
    0dbfs = 1.0

    instr 1
    	krate linseg 1, p3, 40
    	ktrig metro krate
    	kx sc_phasor ktrig, krate/kr, 0, 1
    	asine oscili 0.2, kx*500+500
    	outch 1, asine
    endin

    instr 2
    	krate linseg 1, p3, 40
    	atrig = mpulse(1, 1/krate)
    	ax sc_phasor atrig, krate/sr, 0, 1
    	asine oscili 0.2, ax*500+500
    	outch 2, asine
    endin

    </CsInstruments>
    <CsScore>
    i1 0 20
    i2 0 20
    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

phasor

## Crédits

Par : Eduardo Moguillansky 2017

Précédent | Niveau supérieur | Suivant
lagud | Sommaire | trigphasor