pvsynth
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## pvsynth

pvsynth — Resynthèse par recouvrement-addition de TFR.

## Description

Resynthèse de données de vocodeur de phase (signal-f) par recouvrement-addition de TFR.

## Syntaxe

    ares pvsynth fsrc, [iinit]

## Exécution

ares -- signal audio en sortie

fsrc -- signal d'entrée

iinit -- pas encore implémenté.

## Exemples

Exemple 842. Exemple (utilisant une table-f provenant de la partition, en supposant un fsig avec fftsize = 1024)

    ; score ftable using cubic spline to define shaped peaks
    f1 0 513 8 0 2 1 3 0 4 1 6 0 10 1 12 0 16 1 32 0 1 0 436 0

    asig    buzz     20000, 199, 50, 1         ; pulsewave source
    fsig    pvsanal  asig, 1024, 256, 1024, 0  ; create fsig
    kmod    linseg   0, p3/2, 1, p3/2, 0       ; simple control sig

    fsigout pvsmaska fsig, 2, kmod             ; apply weird eq to fsig
    aout    pvsynth  fsigout                   ; resynthesize,
            dispfft  aout, 0.1, 1024           ; and view the effect

Voici un exemple de l'opcode pvsynth. Il utilise le fichier pvsynth.csd.

Exemple 843. Exemple de l'opcode pvsynth.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    ; Audio out   Audio in
    -odac    ;;;RT audio I/O
    ; For Non-realtime ouput leave only the line below:
    ; -o pvsynth.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 16
    nchnls = 1
    0dbfs = 1

    ;; example written by joachim heintz 2009

    instr 1
    ifftsize	=		1024
    ioverlap	=		ifftsize / 4
    iwinsize	=		ifftsize
    iwinshape	=		1  ; von-Hann window
    Sfile		=		"fox.wav"
    ain		soundin	Sfile
    fftin		pvsanal	ain, ifftsize, ioverlap, iwinsize, iwinshape; fft-analysis of the audio-signal
    aout		pvsynth	fftin; resynthesis
    		out		aout
    endin

    </CsInstruments>
    <CsScore>
    i 1 0 3
    e
    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

pvsanal, pvsadsyn

## Crédits

Auteur : Richard Dobson
Août 2001

Nouveau dans la version 4.13

Février 2004. Grâce à une note de Francisco Vila, l'exemple a été mis à jour.

Précédent | Niveau supérieur | Suivant
pvsvoc | Sommaire | pvswarp