aresonk
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## aresonk

aresonk — Un filtre réjecteur de bande réglable (notch filter) dont les fonctions de transfert sont les complémentaires de celles de l'opcode reson.

## Description

Un filtre réjecteur de bande réglable dont les fonctions de transfert sont les complémentaires de celles de l'opcode reson.

## Syntaxe

    kres aresonk ksig, kcf, kbw [, iscl] [, iskip]

## Initialisation

iscl (facultatif, par défaut 0) -- facteur de pondération codé pour les résonateurs. Une valeur de 1 signifie que la crête du facteur de réponse est 1, c-à-d. toutes les fréquences autres que kcf sont atténuées selon la courbe de réponse (normalisée). Une valeur de 2 élève le facteur de réponse de façon à ce que sa valeur efficace globale soit égale à 1. (Cette égalisation intentionnelle des puissances d'entrée et de sortie suppose que toutes les fréquences sont présentes ; elle est ainsi plus appropriée au bruit blanc.) Une valeur de 0 signifie aucune pondération du signal, laissant cette tâche à un ajustement ultérieur (voir balance). La valeur par défaut est 0.

iskip (facultatif, par défaut 0) -- état initial de l'espace de données interne. Comme le filtrage comprend une boucle de rétroaction sur la sortie précédente, l'état initial de l'espace de stockage utilisé est significatif. Une valeur nulle provoquera l'effacement de cet espace ; une valeur non nulle autorisera la persistance de l'information précédente. La valeur par défaut est 0.

## Exécution

kres -- le signal de sortie au taux de contrôle.

ksig -- le signal d'entrée au taux de contrôle.

kcf -- la fréquence centrale du filtre, ou position fréquentielle de la crête de la réponse.

kbw -- largeur de bande du filtre (la différence en Hz entre les points haut et bas à mi-puissance).

aresonk est un filtre dont les fonctions de transfert sont complémentaires de celles de resonk. Ainsi aresonk est un filtre réjecteur de bande variable (notch filter) dont les fonctions de transfert représentent les aspects « filtrés » de leurs compléments. Cependant, l'échelle de puissance n'est pas normalisée dans aresonk mais reste le complément réel de l'unité correspondante.

## Exemples

Voici un exemple de l'opcode aresonk. Il utilise le fichier aresonk.csd.

Exemple 61. Exemple de l'opcode aresonk.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;RT audio out
    ;-iadc    ;;;uncomment -iadc if RT audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o aresonk.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>
    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs = 1

    gisin ftgen 0, 0, 2^10, 10, 1

    instr 1

    ksig	randomh	400, 1800, 150
    aout	poscil	.2, 1000+ksig, gisin
    	outs	aout, aout
    endin

    instr 2

    ksig	randomh	400, 1800, 150
    kbw	line	1, p3, 600	; vary bandwith
    ksig	aresonk	ksig, 800, kbw
    aout	poscil	.2, 1000+ksig, gisin
    	outs	aout, aout
    endin

    </CsInstruments>
    <CsScore>
    i 1 0 5
    i 2 5.5 5
    e
    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

areson, atone, atonek, port, portk, reson, resonk, tone, tonek

Précédent | Niveau supérieur | Suivant
areson | Sommaire | atone