else
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## else

else — Exécute un bloc de code lorsqu'une condition "if...then" est fausse.

## Description

Exécute un bloc de code lorsqu'une condition "if...then" est fausse.

## Syntaxe

                else

## Exécution

else est utilisé dans un bloc de code entre les opcodes "if...then" et endif. Il définit les instructions à exécuter lorsqu'une condition "if...then" est fausse. Il ne peut y avoir qu'une seule instruction else et celle-ci doit être la dernière instruction conditionnelle avant l'opcode endif.

## Exemples

Voici un exemple de l'opcode else. Il utilise le fichier else.csd.

Exemple 257. Exemple de l'opcode else.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o else.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs = 1

    instr 1

    ipch = cpspch(p4)
    ienv = p5

    if (ienv == 0) then
    	kenv adsr 0.01, 0.95, .7, .5
    else
    	kenv linseg 0, p3 * .5, 1, p3 * .5, 0
    endif

    aout vco2    .8, ipch, 10
    aout moogvcf aout, ipch + (kenv * 6 * ipch) , .5

    aout = aout * kenv
        outs aout, aout

    endin
    </CsInstruments>
    <CsScore>

    i 1 0 2 8.00 0
    i 1 3 2 8.00 1

    e
    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

elseif, endif, goto, if, igoto, kgoto, tigoto, timout

Plus d'information sur cet opcode : http://www.csoundjournal.com/2006spring/controlFlow.html, écrit par Steven Yi.

## Crédits

Nouveau dans la version 4.21

Précédent | Niveau supérieur | Suivant
dust2 | Sommaire | elseif