inch
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## inch

inch — Lit depuis des canaux numérotés d'un signal audio externe ou d'un flot.

## Description

Lit depuis des canaux numérotés d'un signal audio externe ou d'un flot.

## Syntaxe

    ain1[, ...] inch kchan1[,...]

## Exécution

ain, ... - signaux audio en entrée

kchan1, ... - numéro des canaux

inch lit depuis des canaux numérotés déterminés par les kchan correspondants vers les ain associés. Si l'option de ligne de commande -i est positionnée, le son est lu en continu depuis le flot audio en entrée (par exemple stdin ou un fichier son). On peut aussi utiliser inch pour recevoir des données audio en temps réel depuis l'interface audio au moyen de -iadc.

| Note
La plus grande valeur de kchan utilisable avec inch dépend de nchnls_i. Si kchan est supérieur à nchnls_i, ain restera silencieux. Noter que dans ce cas inch donnera un avertissement et non une erreur.

## Exemples

Voici un exemple de l'opcode inch. Il utilise le fichier inch.csd.

Exemple 460. Exemple de l'opcode inch.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac   -iadc   ;;;realtime audio I/O
    ; For Non-realtime ouput leave only the line below:
    ; inch.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1 ;nchnls channels in, two channels out

    ain1, ainr inch 1, 2			;grab your mic and sing
    adel  linseg 0, p3*.5, 0.02, p3*.5, 0	;max delay time = 20ms
    aoutl flanger ain1, adel, .7
    aoutr flanger ain1, adel*2, .8
          fout "in_ch.wav", 14, aoutl, aoutr ;write to stereo file,
          outs aoutl, aoutr			;16 bits with header

    endin
    </CsInstruments>
    <CsScore>

    i 1 0 10
    e
    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

in32, inx, inz

## Crédits

Auteur : John ffitch
Université de Bath/Codemist Ltd.
Bath, UK
Mai 2000

Nouveau dans la version 4.07 de Csound

Arguments multiples depuis la version 5.13

Précédent | Niveau supérieur | Suivant
in32 | Sommaire | inh