FLtabs
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## FLtabs

FLtabs — Crée une interface FLTK à onglets.

## Description

FLtabs est une interface à onglets qui est utile pour afficher alternativement plusieurs zones contenant des widgets dans la même fenêtre. Il doit être utilisé en même temps qu'un FLgroup, un autre conteneur qui regroupe des widgets enfants.

## Syntaxe

    FLtabs iwidth, iheight, ix, iy

## Initialisation

iwidth -- largeur du widget.

iheight -- hauteur du widget.

ix -- position horizontale du coin supérieur gauche du conteneur, relative au coin supérieur gauche de la fenêtre correspondante (exprimée en pixels).

iy -- position verticale du coin supérieur gauche du conteneur, relative au coin supérieur gauche de la fenêtre correspondante (exprimée en pixels).

## Exécution

Les conteneurs sont utiles pour formater l'apparence graphiques des widgets. Le conteneur le plus important est FLpanel, qui crée une fenêtre. Il peut être rempli avec d'autres conteneurs et/ou des valuateurs ou d'autres sortes de widgets.

Il n'y a pas d'arguments de taux-k dans les conteneurs.

FLtabs est une interface à onglets qui est utile pour afficher alternativement plusieurs zones contenant des widgets dans la même fenêtre.

FLtabs.

Il doit être utilisé en même temps qu'un FLgroup, un autre opcode de conteneur FLTK qui regroupe des widgets enfants.

## Exemples

Le code de l'exemple suivant :

             FLpanel  "Panel1", 450, 550, 100, 100
             FLscroll 450, 550, 0, 0
             FLtabs   400, 550, 5, 5

             FLgroup  "sliders", 380, 500, 10, 40, 1
    gk1, ihs FLslider  "FLslider 1", 500, 1000, 2 ,1, -1, 300,15, 20,50
    gk2, ihs FLslider  "FLslider 2", 300, 5000, 2 ,3, -1, 300,15, 20,100
    gk3, ihs FLslider  "FLslider 3", 350, 1000, 2 ,5, -1, 300,15, 20,150
    gk4, ihs FLslider  "FLslider 4", 250, 5000, 1 ,11, -1, 300,30, 20,200
    gk5, ihs FLslider  "FLslider 5", 220, 8000, 2 ,1, -1, 300,15, 20,250
    gk6, ihs FLslider  "FLslider 6", 1, 5000, 1 ,13, -1, 300,15, 20,300
    gk7, ihs FLslider  "FLslider 7", 870, 5000, 1 ,15, -1, 300,30, 20,350
    gk8, ihs FLslider  "FLslider 8", 20, 20000, 2 ,6, -1, 30,400, 350,50
             FLgroupEnd

             FLgroup  "rollers", 380, 500, 10, 30, 2
    gk1, ihr FLroller  "FLroller 1", 50, 1000,.1,2 ,1 ,-1, 200,22, 20,50
    gk2, ihr FLroller  "FLroller 2", 80, 5000,1,2 ,1 ,-1, 200,22, 20,100
    gk3, ihr FLroller  "FLroller 3", 50, 1000,.1,2 ,1 ,-1, 200,22, 20,150
    gk4, ihr FLroller  "FLroller 4", 80, 5000,1,2 ,1 ,-1, 200,22, 20,200
    gk5, ihr FLroller  "FLroller 5", 50, 1000,.1,2 ,1 ,-1, 200,22, 20,250
    gk6, ihr FLroller  "FLroller 6", 80, 5000,1,2 ,1 ,-1, 200,22, 20,300
    gk7, ihr FLroller  "FLroller 7",50, 5000,1,1 ,2 ,-1, 30,300, 280,50
             FLgroupEnd

             FLgroup "joysticks", 380, 500, 10, 40, 3
    gk1, gk2, ihj1, ihj2 FLjoy "FLjoy", 50, 18000, 50, 18000, 2, 2, -1, -1, 300, 300, 30, 60
             FLgroupEnd

             FLtabsEnd
             FLscrollEnd
             FLpanelEnd

... produira le résultat suivant :

Exemple FLtabs, onglet des réglettes.

Exemple FLtabs, onglet des molettes.

Exemple FLtabs, onglet du joystick.

(Chaque image montre un onglet différent sélectionné dans la même fenêtre.)

## Exemples

Voici un exemple de l'opcode FLtabs. Il utilise le fichier FLtabs.csd.

Exemple 334. Exemple de l'opcode FLtabs.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    ; Audio out   Audio in    No messages
    -odac           -iadc     -d     ;;;RT audio I/O
    ; For Non-realtime ouput leave only the line below:
    ; -o FLtabs.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    ; A single oscillator with frequency, amplitude and
    ; panning controls on separate file tab cards
    sr = 44100
    kr = 441
    ksmps = 100
    nchnls = 2

    FLpanel "Tabs", 300, 350, 100, 100
    itabswidth = 280
    itabsheight = 330
    ix = 5
    iy = 5
    FLtabs itabswidth,itabsheight, ix,iy

        itab1width = 280
        itab1height = 300
        itab1x = 10
        itab1y = 40
        FLgroup "Tab 1", itab1width, itab1height, itab1x, itab1y
            gkfreq, i1 FLknob "Frequency", 200, 5000, -1, 1, -1, 70, 70, 130
            FLsetVal_i 400, i1
        FLgroupEnd

        itab2width = 280
        itab2height = 300
        itab2x = 10
        itab2y = 40
        FLgroup "Tab 2", itab2width, itab2height, itab2x, itab2y
            gkamp, i2 FLknob "Amplitude", 0, 15000, 0, 1, -1, 70, 70, 130
            FLsetVal_i 15000, i2
        FLgroupEnd

        itab3width = 280
        itab3height = 300
        itab3x = 10
        itab3y = 40
        FLgroup "Tab 3", itab3width, itab3height, itab3x, itab3y
            gkpan, i3 FLknob "Pan position", 0, 1, 0, 1, -1, 70, 70, 130
            FLsetVal_i 0.5, i3
        FLgroupEnd
    FLtabsEnd
    FLpanelEnd
    ; Run the widget thread!
    FLrun

    instr 1
        ifn = 1
        asig oscili gkamp, gkfreq, ifn
        outs asig*(1-gkpan), asig*gkpan
    endin

    </CsInstruments>
    <CsScore>

    ; Function table that defines a single cycle
    ; of a sine wave.
    f 1 0 1024 10 1

    ; Instrument 1 will play a note for 1 hour.
    i 1 0 3600
    e

    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

FLgroup, FLgroupEnd, FLpack, FLpackEnd, FLpanel, FLpanelEnd, FLscroll, FLscrollEnd, FLtabsEnd

## Crédits

Auteur : Gabriel Maldonado

Nouveau dans la version 4.22

Exemple écrit par Iain McCurdy, édité par Kevin Conder.

Précédent | Niveau supérieur | Suivant
FLslider | Sommaire | FLtabsEnd