ATSinterpread
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## ATSinterpread

ATSinterpread — permet de déterminer l'enveloppe de fréquence de n'importe quel ATSbufread.

## Description

ATSinterpread permet de déterminer l'enveloppe de fréquence de n'importe quel ATSbufread.

## Syntaxe

    kamp ATSinterpread kfreq

## Exécution

kfreq - une valeur de fréquence (en Hz) utilisée par ATSinterpread comme indice dans la table produite par un ATSbufread.

ATSinterpread prend une valeur de fréquence (kfreq en Hz). Cette fréquence sert à indexer les données d'un ATSbufread. La valeur retournée est une amplitude obtenue de l'ATSbufread après interpolation. ATSinterpread permet de déterminer l'enveloppe de fréquence de n'importe quel ATSbufread. Ces données peuvent être utiles pour plusieurs raisons, dont l'une est la réalisation de la synthèse croisée entre des données provenant d'un fichier ATS et des données non ATS.

## Exemples

Voici un exemple de l'opcode ATSinterpread. Il utilise le fichier ATSinterpread.csd.

Exemple 73. Exemple de l'opcode ATSinterpread.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;RT audio out
    ;-iadc    ;;;uncomment -iadc for RT audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o ATSinterpread.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs = 1

    instr 1	; "beats.ats" is created by atsa

    ktime	line	0, p3, 1.8
    	ATSbufread ktime, 1, "beats.ats", 42
    kamp	ATSinterpread 	p4
    aosc	oscili	kamp, p4, 1
    	outs	aosc * 25, aosc *25

    endin

    </CsInstruments>
    <CsScore>
    ; sine wave.
    f 1 0 16384 10 1

    i 1 0 2 100
    e

    </CsScore>
    </CsoundSynthesizer>

Cet exemple montre comment utiliser ATSinterpread. Ici une fréquence est fournie par la partition (p4) et cette fréquence est passée à un ATSinterpread (avec un ATSbufread) correspondant. L'ATSinterpread utilise cette fréquence pour retourner l'amplitude correspondante basée sur le fichier ATS donné par le ATSbufread (beats.ats dans ce cas). Nous utilisons ensuite cette amplitude pour pondérer une onde sinus qui est synthétisée avec la même fréquence (p4). On peut étendre ceci pour inclure plusieurs ondes sinus. De cette manière il est possible de synthétiser n'importe quelle fréquence raisonnable (comprise entre la fréquence basse et la fréquence haute du fichier ATS indiqué), et de conserver la forme (en fréquence) du fichier ATS (donné par l'ATSbufread).

## Voir aussi

ATSread, ATSreadnz, ATSinfo, ATSsinnoi, ATSbufread, ATScross, ATSpartialtap, ATSadd, ATSaddnz

## Crédits

Auteur : Alex Norman
Seattle, Washington
2004

Précédent | Niveau supérieur | Suivant
ATSinfo | Sommaire | ATSread