STKBowed
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## STKBowed

STKBowed — STKBowed est un instrument à corde frottée.

## Description

Opcode du greffon stkopd.

STKBowed est un instrument à corde frottée, utilisant un modèle à guide d'onde.

## Syntaxe

    asignal STKBowed ifrequency, iamplitude, [kpress, kv1[, kpos, kv2[, klfo, kv3[, klfodepth, kv4[, kvol, kv5]]]]]

## Initialisation

ifrequency -- Fréquence de la note jouée, en Hz.

iamplitude -- Amplitude de la note jouée (entre 0 et 1).

## Exécution

kpress -- contrôleur 2, pression de l'archet. kv1 compris entre 0 et 127.

kpos -- contrôleur 4, position de l'archet. kv2 compris entre 0 et 127.

klfo -- contrôleur 11, vitesse de l'oscillateur basse-fréquence. kv3 compris entre 0 et 127.

klfodepth -- contrôleur 1, intensité de l'oscillateur basse-fréquence. kv4 compris entre 0 et 127.

kvol -- contrôleur 128, volume. kv5 compris entre 0 et 127.

| Notes
Le code pour cet opcode vient directement de la classe Bowed du Synthesis Toolkit en C++ par Perry R. Cook et Gary P. Scavone. On peut en savoir plus sur les classes STK ici : https://ccrma.stanford.edu/software/stk/classes.html kc1, kv1, kc2, kv2, kc3, kv3, kc4, kv4, kc5, kv5, kc6, kv6, kc7, kv7, kc8, kv8 -- Jusqu'à 8 paires de contrôle facultatives au taux-k pour les opcodes STK. Chaque paire de contrôle est constituée d'un numéro de contrôleur (kc) suivi d'une valeur de contrôleur (kv). Le numéro de contrôleur ainsi que la valeur associée sont des variables de taux-k. Cependant, durant l'exécution, les numéros de contrôleur sont habituellement constants tandis que les valeurs correspondantes peuvent changer à tout moment. L'ordre des paires de contrôle est arbitraire mais elles doivent apparaître après iamplitude. Il n'est pas non plus nécessaire d'utiliser toutes les paires.

## Exemples

Voici un exemple de l'opcode STKBowed. Il utilise le fichier STKBowed.csd.

Exemple 1002. Exemple de l'opcode STKBowed.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if RT audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o STKBowed.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1

    ipch	= p4
    kv2	= p7							;position on bow
    kv1	line	p5, p3, p6					;bow pressure
    kv4	line	0, p3, 7					;depth of low-frequency oscillator

    asig	STKBowed cpspch(ipch), 1, 2, kv1, 4, kv2, 11, 40, 1, kv4, 128, 100
    asig	=	asig*2						;amplify
    	outs	asig, asig
    endin

    </CsInstruments>
    <CsScore>

    i 1 0 15 6.00 20 100 115
    i 1 17 3 7.00 120 0  0
    i 1 21 3 7.09 120 0  30
    i 1 21 4 7.03 50  0  0
    e
    </CsScore>
    </CsoundSynthesizer>

## Crédits

Auteur : Michael Gogins (d'après Perry Cook)
Irreducible Productions
New York, NY

Nouveau dans la version 5.11 de Csound.

Précédent | Niveau supérieur | Suivant
STKBlowHole | Sommaire | STKBrass