ceil
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## ceil

ceil — Retourne le plus petit entier supérieur ou égal à x.

## Description

Retourne le plus petit entier supérieur ou égal à x.

## Syntaxe

    ceil(x) (argument au taux d'initialisation, de contrôle ou audio)

    ceil(k/i[]) (k- ou i-tableau)

où l'argument entre parenthèses peut être une expression. Les convertisseurs de valeur effectuent une transformation arithmétique d'unités d'une sorte en unités d'une autre sorte. Le résultat peut devenir ensuite un terme dans une autre expression.

## Exemples

Voici un exemple de l'opcode ceil. Il utilise le fichier ceil.csd.

Exemple 116. Exemple de l'opcode ceil.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    ; Audio out   Audio in    No messages
    -odac     ;;;RT audio out
    ;-iadc    ;;;uncomment -iadc if RT audio input is needed too

    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2

    instr 1

    inum = p4
    iceil = ceil(inum)
    print iceil

    endin

    </CsInstruments>
    <CsScore>

    i 1 0 0 1
    i . . . 0.999999
    i . . . 0.000001
    i . . . 0
    i . . . -0.0000001
    i . . . -0.9999999
    i . . . -1
    e
    </CsScore>
    </CsoundSynthesizer>

Sa sortie contiendra des lignes comme celles-ci :

    instr 1:  iceil = -1.000
    instr 1:  iceil = 1.000
    instr 1:  iceil = 1.000
    instr 1:  iceil = 1.000
    instr 1:  iceil = 0.000
    instr 1:  iceil = 0.000
    instr 1:  iceil = 0.000

Voici un autre exemple de l'opcode ceil. Il utilise le fichier ceil-2.csd.

Exemple 117. Un second exemple de l'opcode ceil.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac      ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o ceil-2.wav -W ;;; for file output any platform

    ; By Stefano Cucchi - 2020

    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1

    kcps = 100
    kcar = 1
    kmod = p4

    kndx oscil 30, .25/p3, 1
    kndx ceil kndx

    asig foscili .5, kcps, kcar, kmod, kndx, 1
         outs asig, asig

    endin
    </CsInstruments>
    <CsScore>

    f 1 0 16384 10 1

    i 1 0 10 1.5
    e
    </CsScore>
    </CsoundSynthesizer>

Voici un exemple de groupe d'arrondis, comparant les différents opcodes d'arrondi. Il utilise le fichier rounding-group.csd.

Exemple 118. Exemple de groupe d'arrondis.

    <CsoundSynthesizer>
    <CsOptions>
    -odac       ;
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32

    ; by tgrey 2020
    instr 1

    iLoopStart = p4
    iLoopEnd   = p5
    iOffset    = p6

    iCount init iLoopStart

    if(iLoopStart<iLoopEnd) then		; loop going up
    	while iCount <= iLoopEnd do
    		iVal = iCount+iOffset
    		iRound = round(iVal)
    		iInt = int(iVal)
    		iFloor = floor(iVal)
    		iCeil = ceil(iVal)
    		print iVal, iRound, iInt, iFloor, iCeil
    		iCount = iCount + 1
    	od

    elseif(iLoopEnd<iLoopStart) then	; loop going down
    	while iCount >= iLoopEnd do
    		iVal = iCount+iOffset
    		iRound = round(iVal)
    		iInt = int(iVal)
    		iFloor = floor(iVal)
    		iCeil = ceil(iVal)
    		print iVal, iRound, iInt, iFloor, iCeil
    		iCount = iCount - 1
    	od
    endif
    endin
    </CsInstruments>
    <CsScore>
    i1 0 .1 0 10 .5
    i1 .2 .1 0 -10 .5
    e
    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

abs, exp, int, log, log10, i, sqrt

## Crédits

Auteur : Istvan Varga
Nouveau dans Csound 5
2005

Précédent | Niveau supérieur | Suivant
cauchyi | Sommaire | cell