compilestr
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## compilestr

compilestr — Compile un nouvel orchestre passé dans une chaîne ASCII.

## Description

compilestr compile un ou plusieurs instruments pendant l'initialisation, qui seront ajoutés au moteur courant. Si des numéros ou des noms d'instrument existent déjà, ceux-ci seront remplacés, mais toute instance de l'ancienne définition des instruments encore active continuera son exécution jusqu'à son terme. Seules les nouvelles instances utiliseront la nouvelle définition. Les chaînes de caractères sur plusieurs lignes sont acceptées ; elles sont délimitées par {{ }}.

## Syntaxe

    ires compilestr Sorch

## Initialisation

« Sorch » -- une chaîne de caractères entre guillemets ou délimitée par {{ }} et contenant un ou plusieurs intruments.

« ires » -- 0 si la compilation se fait sans erreur, -1 sinon.

## Exemples

Voici un exemple de l'opcode compilestr. Il utilise le fichier compilestr.csd.

Exemple 152. Exemple de l'opcode compilestr.

Voir les sections Audio en temps réel et Options de la ligne de commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    -o dac -d
    </CsOptions>
    <CsInstruments>
    sr = 44100
    nchnls = 1
    ksmps = 32
    0dbfs = 1

    instr 1

     ;will fail because of wrong code
    ires compilestr {{
    instr 2
    a1 oscilb p4, p5, 0
    out a1
    endin
    }}
    print ires ; returns -1 because not successfull

     ;will compile ...
    ires compilestr {{
    instr 2
    a1 oscils p4, p5, 0
    out a1
    endin
    }}
    print ires ; ... and returns 0

     ;call the new instrument
     ;(note that the overall performance is extended)
    scoreline_i "i 2 0 3 .2 415"

    endin

    </CsInstruments>
    <CsScore>
    i1 0 1
    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

event, event_i, schedule, schedwhen, schedkwhen, schedkwhennamed

## Crédits

Auteur : Victor Lazzarini, 2013

Précédent | Niveau supérieur | Suivant
compileorc | Sommaire | compress2