cossegb
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## cossegb

cossegb — Trace une suite de segments entre les points absolus spécifiés, avec interpolation cosinusoïdale.

## Description

Trace une suite de segments entre les points absolus spécifiés, avec interpolation cosinusoïdale.

## Syntaxe

    ares cossegb ia, itim1, ib [, itim2] [, ic] [...]

    kres cossegb ia, itim1, ib [, itim2] [, ic] [...]

## Initialisation

ia -- valeur initiale.

ib, ic, etc. -- valeur à tim1 secondes, etc.

itim1 -- date en secondes de la fin du premier segment. Avec une valeur nulle ou négative l'initialisation sera ignorée.

itim2, itim3, etc. -- date en secondes de la fin des segments suivants.

## Exécution

Ces unités génèrent des signaux de contrôle ou audio dont les valeurs passent par 2 ou plus points spécifiés. La dernière valeur tim peut égaler ou non la durée d'exécution de l'instrument : avec une exécution plus courte, la courbe sera tronquée alors qu'avec une exécution plus longue, la dernière valeur sera répétée jusqu'à la fin de la note.

## Exemples

Voici un exemple de l'opcode cossegb. Il utilise le fichier cossegb.csd.

Exemple 161. Exemple de l'opcode cossegb.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac      ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ;-o linseg.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    giSine ftgen 0, 0, 2^10, 10, 1

    instr 1

    kcps = cpspch(p4)
    kenv cossegb 0, 0.25, 1, 1, 0
    asig poscil kenv, kcps, giSine
         outs asig, asig

    endin

    instr 2	; scaling to duration

    kcps = cpspch(p4)
    kenv cossegb 0, p3*0.25, 1, p3, 0
    asig poscil kenv, kcps, giSine
         outs asig, asig

    endin

    </CsInstruments>
    <CsScore>

    i 1 0 1   7.00	; = 1 sec, p3 fits exactly
    i 1 2 2   7.00	; = 2 sec, p3 truncated at 1 sec

    i 2 4 1   7.00	; scales to duration
    i 2 6 2   7.00	; of p3

    e
    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

cosseg, expon, expseg, expsegr, line, linseg linsegb linsegr transeg

## Credits

Auteur : John ffitch
Août 2012

Nouveau dans la version 5.18

Précédent | Niveau supérieur | Suivant
cosseg | Sommaire | cossegr