expseg
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## expseg

expseg — Trace une suite de segments d'exponentielle entre les points spécifiés.

## Description

Trace une suite de segments d'exponentielle entre les points spécifiés.

## Syntaxe

    ares expseg ia, idur1, ib [, idur2] [, ic] [...]

    kres expseg ia, idur1, ib [, idur2] [, ic] [...]

## Initialisation

ia -- valeur initiale. Zéro est interdit pour les exponentielles.

ib, ic, etc. -- valeur après dur1 secondes, etc. Pour les exponentielles, doivent être différentes de zéro et du même signe que ia.

idur1 -- durée en secondes du premier segment. Avec une valeur nulle ou négative l'initialisation sera ignorée.

idur2, idur3, etc. -- durée en secondes des segments suivants. Une valeur nulle ou négative terminera la phase d'initialisation avec le point précédent, permettant au dernier segment défini de continuer durant toute l'exécution. La valeur par défaut est zéro.

## Exécution

Ces unités génèrent des signaux de contrôle ou audio dont les valeurs passent par 2 ou plus points spécifiés. La somme des valeurs dur peut égaler ou non la durée d'exécution de l'instrument : avec une exécution plus courte, la courbe sera tronquée alors qu'avec une exécution plus longue, le dernier segment défini continuera dans la même direction.

Noter que l'opcode expseg n'opère pas correctement au taux audio lorsque les segments sont plus courts qu'une k-période. Dans ce cas, il vaut mieux utiliser l'opcode expsega.

## Exemples

Voici un exemple de l'opcode expseg. Il utilise le fichier expseg.csd.

Exemple 278. Exemple de l'opcode expseg.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    ; Audio out   Audio in
    -odac           -iadc    ;;;RT audio I/O
    ; For Non-realtime ouput leave only the line below:
    ; -o expseg.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    ; Initialize the global variables.
    sr = 44100
    kr = 4410
    ksmps = 10
    nchnls = 1

    ; Instrument #1.
    instr 1
      ; p4 = frequency in pitch-class notation.
      kcps = cpspch(p4)

      ; Create an amplitude envelope.
      kenv expseg 0.01, p3*0.25, 1, p3*0.75, 0.01
      kamp = kenv * 30000

      a1 oscil kamp, kcps, 1
      out a1
    endin

    </CsInstruments>
    <CsScore>

    ; Table #1, a sine wave.
    f 1 0 16384 10 1

    ; Play Instrument #1 for a half-second, p4=8.00
    i 1 0 0.5 8.00
    ; Play Instrument #1 for a half-second, p4=8.01
    i 1 1 0.5 8.01
    ; Play Instrument #1 for a half-second, p4=8.02
    i 1 2 0.5 8.02
    ; Play Instrument #1 for a half-second, p4=8.03
    i 1 3 0.5 8.03
    e

    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

expon, expsega, expsegr, line, linseg, triglinseg, trigexpseg, linsegr, transeg

## Crédits

Auteur : Gabriel Maldonado

Exemple écrit par Kevin Conder.

Nouveau dans Csound 3.57

Précédent | Niveau supérieur | Suivant
exprandi | Sommaire | expsega