valpass
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## valpass

valpass — Réverbération variable du signal en entrée avec une réponse en fréquence plate.

## Description

Réverbération variable du signal en entrée avec une réponse en fréquence plate.

## Syntaxe

    ares valpass asig, krvt, xlpt, imaxlpt [, iskip] [, insmps]

## Initialisation

imaxlpt -- durée de boucle maximale pour klpt

iskip (facultatif, 0 par défaut) -- état initial de l'espace de données de la boucle de retard (cf. reson). La valeur par défaut est 0.

insmps (facultatif, 0 par défaut) -- valeur du retard, en nombre d'échantillons.

## Exécution

krvt -- la durée de réverbération (définie comme le temps en secondes pris par un signal pour décroitre à 1/1000 ou 60 dB de son amplitude originale).

xlpt -- durée de boucle variable en secondes, comme ilpt dans comb. La durée de boucle peut aller jusqu'à imaxlpt.

Ce filtre répète l'entrée avec une densité d'écho déterminée par la durée de boucle xlpt. Le taux d'atténuation est indépendant et il est déterminé par krvt, la durée de réverbération (définie comme le temps en secondes pris par un signal pour décroitre à 1/1000 ou 60 dB de son amplitude originale). La sortie apparait sans retard.

## Exemples

Voici un exemple de l'opcode valpass. Il utilise le fichier valpass.csd.

Exemple 1134. Exemple de l'opcode valpass.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac  ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o valpass.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1

    krvt = 1.5
    klpt line p4, p3, p5
    imaxlpt = .1

    a1 diskin2 "fox.wav", 1
    a1 valpass a1, krvt, klpt, imaxlpt
    a2 valpass a1, krvt, klpt*.5, imaxlpt
       outs	a1, a2

    endin
    </CsInstruments>
    <CsScore>

    i 1 0 5 .01 .2
    e
    </CsScore>
    </CsoundSynthesizer>

Voici un autre exemple de l'opcode valpass. Il utilise le fichier valpass-2.csd.

Exemple 1135. Second exemple de l'opcode valpass.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac  ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o valpass-2.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    giSine ftgen 0, 0, 65536, 10, 1			;sine wave

    instr 1

    asig diskin2 "beats.wav", 1, 0, 1
    krvt line 0.01, p3, p3				;reverb time
    adepth = p4					;sine depth
    krate = 0.3					;sine rate (speed)
    adel oscil 0.5, krate, giSine			;delay time oscillator (LFO)
    adel = ((adel+0.5)*adepth)			;scale and offset LFO
    aout valpass asig, krvt, adel*0.01, 0.5
         outs aout, aout

    endin
    </CsInstruments>
    <CsScore>

    i1 0  10 1
    i1 11 10 5
    e
    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

alpass, comb, reverb, vcomb

## Crédits

Auteur : William « Pete » Moss
Université du Texas à Austin
Austin, Texas USA
Janvier 2002

Précédent | Niveau supérieur | Suivant
vaget | Sommaire | vaset