sfpreset
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## sfpreset

sfpreset — Associe un preset d'un fichier d'échantillons SoundFont2 (SF2) à un indice numérique.

## Description

Associe un preset d'un fichier d'échantillons SoundFont2 (SF2) préalablement chargé en mémoire à un indice numérique. Ces opcodes permettent la gestion de la structure d'échantillon des fichiers SF2. Afin de comprendre l'utilisation de ces opcodes, il faut connaître le format SF2 dont on peut trouver une brève description dans la section format de fichier SoundFont2.

sfpreset doit être placé dans la section d'en-tête d'un orchestre de Csound.

## Syntaxe

    ir sfpreset iprog, ibank, ifilhandle, ipreindex

## Initialisation

ir -- valeur de retour à utiliser par les autres opcodes SF2. Pour sfpreset, ir est le ipreindex.

iprog -- numéro de programme d'une banque de presets dans un fichier SF2.

ibank -- numéro d'une banque spécifique d'un fichier SF2.

ifilhandle -- nombre unique généré par l'opcode sfload à utiliser comme identificateur pour un fichier SF2. On peut charger et activer plusieurs fichiers SF2 en même temps.

ipreindex -- indice du preset.

## Exécution

sfpreset associe un preset d'un fichier SF2 préalablement chargé en mémoire à un indice numérique, à utiliser ensuite avec les opcodes sfplay et sfplaym. L'utilisateur doit connaître à l'avance les numéros de banque du preset afin de remplir les arguments correspondants. On peut placer plusieurs instances de sfpreset dans la section d'en-tête d'un orchestre, chacune associant un preset différent appartenant au même (ou à différents) fichiers SF2 à différents indices numériques.

Ces opcodes ne supportent que la structure d'échantillon des fichiers SF2. La structure de modulateur du format SoundFormat2 n'est pas supportée dans Csound. Tout traitement ou modulation des données échantillonnées est à la charge de l'utilisateur de Csound, ce qui permet de s'affranchir de toutes les restrictions imposées par le standard SF2.

## Exemples

Voici un exemple de l'opcode sfpreset. Il utilise le fichier sfpreset.csd.

Exemple 960. Exemple de l'opcode sfpreset.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac  ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if RT audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o sfpreset.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    ; By  Menno Knevel - 2020

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    gisf1	sfload	 "sf_GMbank.sf2"
    	sfplist	 gisf1						;list presets of first soundfont
    gisf2	sfload	 "07AcousticGuitar.sf2"
    	sfplist	 gisf2						;list presets of second soundfont
    gir	sfpreset 51, 0, gisf1, 0 				;assign Synth Strings2 (#51)to index 0
    giv	sfpreset 0, 0, gisf2, 1					;assign AcousticGuitar (#0) to index 1
    print gir
    print giv

    instr 1

    inum	=	p4
    ivel	=	p5
    kamp	linsegr	1, 1, 1, .1, 0
    kamp	= kamp/600000						;scale amplitude, small value due to 0dbfs = 1
    kfreq	=	1						;do not change freq
    a1,a2	sfplay3	ivel, inum, kamp*ivel, kfreq, p6
    	outs	a1, a2
    endin

    </CsInstruments>
    <CsScore>

    i1 0 1 60 127 0	;= Synth Strings I from first soundfont
    i1 + 1 62 <   .
    i1 + 1 65 <   .
    i1 + 1 69 10  .

    i1 5 1 60 127 1	;= AcousticGuitar from second soundfont
    i1 + 1 62 <   .
    i1 + 1 65 <   .
    i1 + 1 69 10  .
    e
    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

sfilist, sfinstr, sfinstrm, sfload, sfpassign, sfplay, sfplaym, sfplist

## Crédits

Auteur : Gabriel Maldonado
Italie
Mai 2000

Nouveau dans la version 4.07 de Csound

Précédent | Niveau supérieur | Suivant
sfplist | Sommaire | shaker