pvsdiskin
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## pvsdiskin

pvsdiskin — Lit un canal sélectionné d'un fichier d'analyse PVOC-EX.

## Description

Crée un flot fsig en lisant un canal sélectionné d'un fichier d'ananlyse PVOC-EX, avec interpolation de trame.

## Syntaxe

    fsig pvsdiskin SFname, ktscal, kgain[, ioffset, ichan]

## Initialisation

Sfname -- Nom du fichier d'analyse. Il doit avoir l'extension de fichier .pvx.

On peut générer un fichier PVOC-EX multi-canaux avec l'utilité pvanal étendue.

ichan -- (facultatif) Le canal à lire (en comptant à partir de 1). Vaut 1 par défaut.

ioffset -- (facultatif) Décalage à partir du début du fichier (secondes). Vaut 0 par défaut.

## Exécution

ktscal -- échelle temporelle, c'est-à-dire la vitesse du pointeur de lecture (1 pour la vitesse normale, valeurs négatives pour une lecture à l'envers, 0 < ktscal < 1 pour une lecture plus lente et ktscal > 1 pour une lecture plus rapide).

kgain -- valeur du gain.

## Exemples

Voici un exemple de l'opcode pvsdiskin. Il utilise le fichier pvsdiskin.csd.

Exemple 811. Exemple de l'opcode pvsdiskin.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac  ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o pvsdiskin.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    0dbfs  = 1
    nchnls = 2

    instr 1
    ; create a PVOC-EX (*.pvx) file with PVANAL first
    ktscale	line 1, p3, .05			;change speed
    fsigr	pvsdiskin "fox.pvx", ktscale, 1	;read PVOCEX file
    aout	pvsynth	fsigr			;resynthesise it
    	outs	aout, aout

    endin
    </CsInstruments>
    <CsScore>

    i 1 0 10
    e
    </CsScore>
    </CsoundSynthesizer>

## Crédits

Auteur : Victor Lazzarini
Mai 2007

Nouveau dans Csound 5.06

Précédent | Niveau supérieur | Suivant
pvsdemix | Sommaire | pvsdisp