scoreline
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## scoreline

scoreline — Délivre un ou plusieurs évènements de ligne de partition depuis un instrument.

## Description

scoreline délivre un ou plusieurs évènements de partition, si ktrig vaut 1, à chaque période k. Il peut gérer les chaînes de caractères dans les mêmes conditions que dans la partition standard. Les chaînes de caractères sur plusieurs lignes sont acceptées, en utilisant {{ }} pour encadrer la chaîne de caractères.

## Syntaxe

    scoreline Sin, ktrig

## Initialisation

« Sin » -- une chaîne de caractères (entre guillemets ou encadrée par {{ }}), contenant un ou plusieurs évènements de partition.

## Exécution

« ktrig » -- déclencheur d'évènement, 1 délivre l'évènement de partition, 0 l'ignore.

## Exemples

Voici un exemple de l'opcode scoreline. Il utilise le fichier scoreline.csd.

Exemple 925. Exemple de l'opcode scoreline.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac    ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o scoreline.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1

    ktrig metro 3				;trigger 3 times a second
    scoreline {{				;so it sounds like an echo
                i 2  0  3  "flute.aiff"
                i 2  1  3  "beats.wav"
                }}, ktrig
    ktrig = 0

    endin

    instr 2

    asig soundin p4
         outs asig*.3, asig*.3

    endin
    </CsInstruments>
    <CsScore>

    i1 0 2	;play for 2 seconds, so the samples are played 6 times
    e
    </CsScore>
    </CsoundSynthesizer>

On peut utiliser des opcodes de chaîne de caractères comme sprintfk pour produire les chaînes de caractères à passer à scoreline comme ceci :

    Sfil = "/Volumes/Bla/file.aif"
    String  sprintfk {{i 2 0 %f "%s" %f %f %f %f}}, idur, Sfil, p5, p6, knorm, iskip
    scoreline String, ktrig

## Voir aussi

event, event_i, schedule, schedwhen, schedkwhen, schedkwhennamed, scoreline_i

Pour plus d'information sur cet opcode : http://www.csoundjournal.com/issue15/phrase_loops.html , écrit par Jim Aikin.

Egalement dans les Floss Manuals : https://flossmanual.csound.com/csound-language/live-events/ .

## Crédits

Auteur : Victor Lazzarini, 2007

Précédent | Niveau supérieur | Suivant
schedwhen | Sommaire | scoreline_i