fluidCCk
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## fluidCCk

fluidCCk — Envoie un message de données de contrôleur MIDI à fluid.

## Syntaxe

    fluidCCk iEngineNumber, iChannelNumber, iControllerNumber, kValue

## Description

Opcode du greffon fluidOpcodes.

Envoie un message de données de contrôleur MIDI (numéro du contrôleur MIDI et valeur à utiliser) à un moteur fluid spécifié par son numéro, sur le numéro de canal MIDI indiqué.

## Initialisation

iEngineNumber -- numéro du moteur affecté par fluidEngine

iChannelNumber -- numéro du canal MIDI auquel le programme Fluidsynth est affecté : de 0 à 255. Les canaux MIDI dont le numéro est supérieur ou égal à 16 sont des canaux virtuels.

iControllerNumber -- numéro du contrôleur MIDI à utiliser pour ce message

## Exécution

kValue -- valeur à affecter au contrôleur (habituellement 0-127)

## Exemples

Voici un exemple de l'opcode fluidCCk. Il utilise le fichier fluidCCk.csd.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac      ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ;-o fluidCCk.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs = 1

    giengine fluidEngine
    ; soundfont path to manual/examples
    isfnum	 fluidLoad "22Bassoon.sf2", giengine, 1
    	 fluidProgramSelect giengine, 1, isfnum, 0, 70

    instr 1

    	mididefault   60, p3
    	midinoteonkey p4, p5
    ikey	init p4
    ivel	init p5
    kpan	line 0, p3, 127 ;panning from left to right
    	fluidCCk giengine, 1, 10, kpan ;CC 10 = pan
    	fluidNote giengine, 1, ikey, ivel

    endin

    instr 99

    imvol  init 7
    asigl, asigr fluidOut giengine
           outs asigl*imvol, asigr*imvol

    endin
    </CsInstruments>
    <CsScore>

    i 1 0 4 48 100
    i 1 4 2 50 120
    i 1 6 1 53 80
    i 1 7 1 45 70
    i 1 8 1.5 48 80

    i 99 0 10      ;keep instr 99 active
    e
    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

fluidEngine, fluidNote, fluidLoad, fluidCCi

Plus d'information sur soundfonts dans les Floss Manuals : https://flossmanual.csound.com/midi/reading-midi-files

D'autres informations sur soundfonts dans Wikipedia : http://en.wikipedia.org/wiki/Soundfont

## Crédits

Michael Gogins (gogins@pipeline.com), Steven Yi. Merci à Peter Hanappe pour Fluidsynth.

Précédent | Niveau supérieur | Suivant
fluidCCi | Sommaire | fluidControl