atonex
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## atonex

atonex — Emule une série de filtres utilisant l'opcode atone.

## Description

atonex est équivalent à un filtre constitué de plusieurs couches de filtres atone avec les mêmes arguments, connectés en série. L'utilisation d'une série d'un nombre important de filtres permet une pente de coupure plus raide. Ils sont plus rapides que l'équivalent obtenu à partir du même nombre d'instances d'opcodes classiques dans un orchestre Csound, car il n'y aura qu'un cycle d'initialisation et une seule passe de k cycles de contrôle à la fois et la boucle audio sera entièrement contenue dans la mémoire cache du processeur.

## Syntaxe

    ares atonex asig, khp [, inumlayer] [, iskip]

    ares atonex asig, ahp [, inumlayer] [, iskip]

## Initialisation

inumlayer (facultatif) -- nombre d'éléments dans la série de filtre. La valeur par défaut est 4.

iskip (facultatif, par défaut 0) -- état initial de l'espace de données interne. Comme le filtrage comprend une boucle de rétroaction sur la sortie précédente, l'état initial de l'espace de stockage utilisé est significatif. Une valeur nulle provoquera l'effacement de cet espace ; une valeur non nulle autorisera la persistance de l'information précédente. La valeur par défaut est 0.

## Exécution

asig -- signal d'entrée

khp/ahp -- le point à mi-puissance de la courbe de réponse. La mi-puissance est définie par puissance maximale / racine de 2.

## Exemples

Voici un exemple de l'opcode atonex. Il utilise le fichier atonex.csd.

Exemple 64. Exemple de l'opcode atonex.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;RT audio out
    ;-iadc    ;;;uncomment -iadc if RT audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o atonex.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs = 1

    instr 1	; unfiltered noise

    asig	rand	0.7	; white noise
    	outs	asig, asig

    endin

    instr 2	; filtered noise

    asig	rand	0.7
    khp	line	100, p3, 3000
    afilt	atonex	asig, khp, 32

    ; Clip the filtered signal's amplitude to 85 dB.
    a1	clip afilt, 2, ampdb(85)
    	outs a1, a1
    endin

    </CsInstruments>
    <CsScore>

    i 1 0 2
    i 2 2 2

    e

    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

resonx, tonex

## Crédits

Auteur : Gabriel Maldonado (adapté par John ffitch)
Italie

Nouveau dans la version 3.49 de Csound

Paramètres de taux audio introduits dans la version 6.02

Octobre 2013.

Précédent | Niveau supérieur | Suivant
atonek | Sommaire | ATSadd