downsamp
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## downsamp

downsamp — Modifie un signal par sous-échantillonnage.

## Description

Modifie un signal par sous-échantillonnage.

## Syntaxe

    kres downsamp asig [, iwlen]

## Initialisation

iwlen (facultatif) -- longueur en échantillons de la fenêtre sur laquelle est prise la valeur moyenne du signal audio pour déterminer une valeur sous-échantillonnée. La longueur maximale est ksmps ; 0 et 1 impliquent pas de fenêtre de moyenne. La valeur par défaut est 0.

## Exécution

downsamp convertit un signal audio en signal de contrôle par sous-échantillonnage. Il produit une kval pour chaque période audio de contrôle. La fenêtre optionnelle invoque un simple procédé de moyenne pour supprimer le repliement.

## Exemples

Voici un exemple de l'opcode downsamp. Il utilise le fichier downsamp.csd.

Exemple 242. Exemple de l'opcode downsamp.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o downsamp.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr	1

    ifrq	= cpspch(p4)
    ain	diskin2 "beats.wav", 1
    aenv	follow	ain, .001	;take the amplitude every 1/1000th of a second
    alow	tone	aenv, 25	;lowpass-filter (25 Hz) for a clean signal
    kenv	downsamp alow
    asig    pluck   kenv, ifrq, 15, 0, 1
    	outs	asig, asig
    	endin

    </CsInstruments>
    <CsScore>

    i 1 0 2	 9
    i 1 + .	 7
    i 1 + .	 5

    e
    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

diff, integ, interp, samphold, upsamp

Précédent | Niveau supérieur | Suivant
dot | Sommaire | dripwater