event_i
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## event_i

event_i — Génère un évènement de partition à partir d'un instrument.

## Description

Génère un évènement de partition à partir d'un instrument.

## Syntaxe

    event_i "scorechar", iinsnum, idelay, idur, [, ip4] [, ip5] [, ...]

    event_i "scorechar", "insname", idelay, idur, [, ip4] [, ip5] [, ...]

## Initialisation

« scorechar » -- Une chaîne de caractères (entre guillemets) représentant le p-champ initial d'une instruction de partition. C'est habituellement « e », « f », ou « i ».

« insname » -- Une chaîne de caractères (entre guillemets) représentant un instrument nommé.

iinsnum -- L'instrument à utiliser pour cet évènement. Cela correspond au premier p-champ, p1, dans une instruction de partition.

idelay -- Quand (en secondes) l'évènement aura lieu à partir de l'instant courant de l'exécution. Cela correspond au second p-champ, p2, dans une instruction de partition.

idur -- Durée (en secondes) de l'évènement. Cela correspond au troisième p-champ, p3, dans une instruction de partition.

ip4, ip5, ... (facultatif) -- Paramètres représentant des p-champs supplémentaires dans une instruction de partition. Ils commencent par le quatrième p-champ, p4.

## Exécution

L'évènement est ajouté à la file d'attente pendant la phase d'initialisation.

| Note
Noter que l'opcode event_i ne peut pas accepter de p-champs chaîne de caractère. Si vous devez passer des chaînes de caractère à l'instanciation d'un instrument, utilisez l'opcode scoreline ou scoreline_i.

## Exemples

Voici un exemple de l'opcode event_i. Il utilise le fichier event_i.csd.

Exemple 269. Exemple de l'opcode event_i.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;RT audio out
    ;-iadc    ;;;uncomment -iadc if RT audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o event_i.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    seed 0
    gisine ftgen 0, 0, 2^10, 10, 1

    instr 1 ;master instrument

    ininstr = 10 ;number of called instances
    indx = 0
    loop:
    ipan  random 0, 1
    ifreq random 100, 1000
    iamp  = 1/ininstr
    event_i "i", 10, 0, p3, iamp, ifreq, ipan
    loop_lt indx, 1, ininstr, loop

    endin

    instr 10

          print p4, p5, p6
    ipeak random 0, 1 ;where is the envelope peak
    asig  poscil3 p4, p5, gisine
    aenv  transeg 0, p3*ipeak, 6, 1, p3-p3*ipeak, -6, 0
    aL,aR pan2 asig*aenv, p6
          outs aL, aR

    endin

    </CsInstruments>
    <CsScore>
    i1 0 10
    i1 8 10
    i1 16 15
    e
    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

event, schedule, schedwhen, schedkwhen, schedkwhennamed, scoreline, scoreline_i

## Crédits

Ecrit par Istvan Varga.

Nouveau dans Csound5

Précédent | Niveau supérieur | Suivant
event | Sommaire | exciter