fmbell
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## fmbell

fmbell — Utilise la synthèse FM pour créer un son de cloche tube.

## Description

Utilise la synthèse FM pour créer un son de cloche tube. Il provient d'une famille de sons FM qui utilisent tous 4 oscillateurs élémentaires et diverses architectures, comme dans le synthétiseur TX81Z.

## Syntaxe

    ares fmbell kamp, kfreq, kc1, kc2, kvdepth, kvrate[, ifn1, ifn2, ifn3, \
          ifn4, ivfn, isus]

## Initialisation

Tous ces opcodes prennent 5 tables pour l'initialisation. Les 4 premières sont les entrées de base et la dernière est l'oscillateur basse fréquence (LFO) utilisé pour le vibrato. La dernière table contiendra habitullement une onde sinus.

Les formes d'onde initiales seront :

- ifn1 -- onde sinus

- ifn2 -- onde sinus

- ifn3 -- onde sinus

- ifn4 -- onde sinus

L'argument facultatif isus contrôle la durée du son, ou sa vitesse de décroissance. Il vaut 4 par défaut.

## Exécution

kamp -- Amplitude de la note.

kfreq -- Fréquence de la note jouée.

kc1, kc2 -- Contrôles pour le synthétiseur :

- kc1 -- Indice de modulation 1

- kc2 -- Fondu des deux sorties

- Algorithme -- 5

kvdepth -- Largeur du vibrato

kvrate -- Vitesse du vibrato

## Exemples

Voici un exemple de l'opcode fmbell. Il utilise le fichier fmbell.csd.

Exemple 348. Exemple de l'opcode fmbell.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o fmbell.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1

    kamp = p4
    kfreq = 880
    kc1 = p5
    kc2 = p6
    kvdepth = 0.005
    kvrate = 6

    asig fmbell kamp, kfreq, kc1, kc2, kvdepth, kvrate, 1, 1, 1, 1, 1
         outs asig, asig
    endin

    instr 2

    kamp = p4
    kfreq = 880
    kc1 = p5
    kc2 = p6
    kvdepth = 0.005
    kvrate = 6

    asig fmbell kamp, kfreq, kc1, kc2, kvdepth, kvrate, 1, 1, 1, 1, 1, p7
         outs asig, asig
    endin

    </CsInstruments>
    <CsScore>
    ; sine wave.
    f 1 0 32768 10 1

    i 1 0 3 .2  5 5
    i 1 + 4 .3 .5 1
    s
    i 2 0 12 .2  5 5 16
    i 2 + 12 .3 .5 1 12

    e
    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

fmb3, fmmetal, fmpercfl, fmrhode, fmwurlie

## Crédits

Auteur : John ffitch (d'après Perry Cook)
University of Bath, Codemist Ltd.
Bath, UK

Nouveau dans la version 3.47 de Csound.

Argument facultatif ajouté dans la version 5.16.

Plus d'arguments sont facultatifs depuis la version 6.0

Précédent | Niveau supérieur | Suivant
fmb3 | Sommaire | fmin