poscil3
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## poscil3

poscil3 — Oscillateur haute précision avec interpolation cubique.

## Description

Oscillateur haute précision avec interpolation cubique.

## Syntaxe

    ares poscil3 aamp, acps [, ifn, iphs]

    ares poscil3 aamp, kcps [, ifn, iphs]

    ares poscil3 kamp, acps [, ifn, iphs]

    ares poscil3 kamp, kcps [, ifn, iphs]

    ires poscil3 kamp, kcps [, ifn, iphs]

    kres poscil3 kamp, kcps [, ifn, iphs]

## Initialisation

ifn (facultatif) -- numéro de la table de fonction. Vaut -1 par défaut ce qui indique une onde sinus.

iphs (facultatif, par défaut 0) -- phase initiale (table normalisée, index 0-1). Si une valeur négative est donnée, l'initialisation de la phase est ignorée.

## Exécution

ares -- signal de sortie

kamp, aamp -- amplitude du signal de sortie.

kcps, acps -- fréquence du signal de sortie en Hertz.

poscil3 fonctionne comme poscil, mais il utilise l'interpolation cubique.

Noter que poscil3 peut utiliser des tables de longueur différée (non puissance de deux).

## Exemples

Voici un exemple de l'opcode poscil3. Il utilise le fichier poscil3.csd.

Exemple 762. Exemple de l'opcode poscil3.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if real audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o poscil3.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    giSine ftgen 0, 0, 2^10, 10, 1

    instr 1

    krnd  randomh 40, 440, 1	; produce random values
    ain   poscil3 .6, krnd, giSine
    kline line    1, p3, 0    	; straight line
    aL,aR pan2    ain, kline	; sent across image
          outs    aL, aR

    endin
    </CsInstruments>
    <CsScore>
    i1 0 10
    e
    </CsScore>
    </CsoundSynthesizer>

Voici un autre exemple de l'opcode poscil3, qui utilise une table remplie à partir d'un fichier son. Il utilise le fichier poscil3-file.csd.

Exemple 763. Un autre exemple de l'opcode poscil3.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    ; Audio out   Audio in    No messages
    -odac           -iadc     -d     ;;;RT audio I/O
    ; For Non-realtime ouput leave only the line below:
    ; -o poscil3-file.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    ; Example written by Joachim Heintz 07/2008

    sr = 44100
    kr = 4410
    ksmps = 10
    nchnls = 1

    ; non-normalized function table with a sample 1
    giFile	ftgen 1, 0, 0, -1, "fox.wav", 0, 0, 0

    ; Instrument #1 - uses poscil3 for playing samples from a function table
    instr 1
    kamp = p4
    kspeed	= p5
    ifn = 1
    iskip = p6
    kcps	= kspeed / (ftlen(ifn) / ftsr(ifn)); frequency of the oscillator
    iphs	= iskip / (ftlen(ifn) / ftsr(ifn)); calculates skiptime to phase values (0-1)

      a1 poscil3 kamp, kcps, ifn, iphs
      out a1
    endin
    </CsInstruments>
    <CsScore>
    i1 0 2.756 1 1 0
    i1 3 2.756 1 -1 0
    i1 6 1.378 1 .5 2.067
    e
    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

poscil

## Crédits

Auteurs : John ffitch, Gabriel Maldonado
Italie

Nouveau dans la version 3.52 de Csound

Les variantes avec fréquence ou amplitude de taux-a sont nouvelles dans la version 5.16

La table de fonction est facultative depuis la version 6.0 de Csound.

La possibilité d'ignorer l'initialisation a été ajoutée dans la version 6.06.

Précédent | Niveau supérieur | Suivant
portk | Sommaire | poscil