zawm
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## zawm

zawm — Ecrit dans une variable za au taux-a avec mixage.

## Description

Ecrit dans une variable za au taux-a avec mixage.

## Syntaxe

    zawm asig, kndx [, imix]

## Initialisation

imix (facultatif, par defaut=1) -- indique si le mixage sera fait.

## Exécution

asig -- valeur à écrire dans l'espace za.

kndx -- Pointe sur la position za vers laquelle écrire.

Ces opcodes sont rapides, et vérifient toujours que l'indexation est à l'intérieur des limites des espaces zk ou za. Sinon, une erreur est rapportée, la valeur 0 est retournée et il n'y a aucune écriture.

zawm est un opcode de mixage, il ajoute le signal à la valeur actuelle de la variable. Si aucun imix n'est specifié, le mixage aura toujours lieu. imix = 0 provoquera l'écrasement des données comme dans ziw, zkw, et zaw. Toute autre valeur entraînera un mixage.

Avertissement : lors de l'utilisation des opcodes de mixage ziwm, zkwm, et zawm, il faut faire attention à ce que les variables qui reçoivent le mixage soient remises à zéro à la fin (ou au début) de chaque cycle-k ou -a. Leur ajouter indéfiniment des signaux peut engendrer des valeurs astronomiques.

Une approche possible serait d'établir certains intervalles de variables zk ou za à utiliser pour le mixage, puis d'utiliser ensuite zkcl ou zacl pour effacer ces variables.

## Exemples

Voici un exemple de l'opcode zawm. Il utilise le fichier zawm.csd.

Exemple 1234. Exemple de l'opcode zawm.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    ; Audio out   Audio in    No messages
    -odac           -iadc     -d     ;;;RT audio I/O
    ; For Non-realtime ouput leave only the line below:
    ; -o zawm.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    ; Initialize the global variables.
    sr = 44100
    kr = 4410
    ksmps = 10
    nchnls = 1

    ; Initialize the ZAK space.
    ; Create 1 a-rate variable and 1 k-rate variable.
    zakinit 1, 1

    ; Instrument #1 -- a basic instrument.
    instr 1
      ; Generate a simple sine waveform.
      asin oscil 15000, 440, 1

      ; Mix the sine waveform with za variable #1.
      zawm asin, 1
    endin

    ; Instrument #2 -- another basic instrument.
    instr 2
      ; Generate another waveform with a different frequency.
      asin oscil 15000, 880, 1

      ; Mix this sine waveform with za variable #1.
      zawm asin, 1
    endin

    ; Instrument #3 -- generates audio output.
    instr 3
      ; Read za variable #1, containing both waveforms.
      a1 zar 1

      ; Generate the audio output.
      out a1

      ; Clear the za variables, get them ready for
      ; another pass.
      zacl 0, 1
    endin

    </CsInstruments>
    <CsScore>

    ; Table #1, a sine wave.
    f 1 0 16384 10 1

    ; Play Instrument #1 for one second.
    i 1 0 1
    ; Play Instrument #2 for one second.
    i 2 0 1
    ; Play Instrument #3 for one second.
    i 3 0 1
    e

    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

zaw, ziw, ziwm, zkw, zkwm

## Crédits

Auteur : Robin Whittle
Australie
Mai 1997

Nouveau dans la version 3.45

Exemple écrit par Kevin Conder.

Précédent | Niveau supérieur | Suivant
zaw | Sommaire | zdf_1pole