display
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## display

display — Affiche un signal audio ou de contrôle sur un graphique amplitude/temps.

## Description

Ces unités affichent les valeurs d'initialisation de l'orchestre ou produisent un affichage graphique de signaux de contrôle ou audio de l'orchestre. Des fenêtres X11 sont utilisées s'il est activé, sinon (ou si l'option -g est positionnée) on a un affichage approximatif en caractères ASCII.

## Syntaxe

    display xsig, iprd [, inprds] [, iwtflg]

## Initialisation

iprd -- la période d'affichage en secondes.

inprds (facultatif, 1 par défaut) -- Nombre de périodes d'affichage retenues dans chaque graphique. Les valeurs supérieures ou égales à 2 donneront une perspective plus étendue du mouvement du signal. La valeur par défaut est 1 (chaque graphique est entièrement renouvelé). inprds est un facteur d'échelle pour la forme d'onde affichée, qui contrôle combien de trames d'échantillon de longueur iprd sont dessinées dans la fenêtre (la valeur par défaut qui est aussi la valeur minimale est 1.0). Des valeurs supérieures de inprds provoquent un dessin plus lent (plus de points à dessiner) mais feront défiler la forme d'onde à travers la fenêtre, ce qui est utile avec de faibles valeurs de iprd.

iwtflg (facultatif, 0 par défaut) -- indicateur de maintien. S'il est différent de zéro, chaque affichage est maintenu jusqu'à ce que l'utilisateur le libère. La valeur par défaut est 0 (pas de maintien).

## Exécution

display -- affiche le signal audio ou de contrôle xsig chaque iprd secondes, sur un graphique amplitude/temps.

## Exemples

Voici un exemple de l'opcode display. Il utilise le fichier display.csd.

Exemple 236. Exemple de l'opcode display.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o display.wav -W ;;; for file output any platform
    </CsOptions>;be sure to NOT have -d in the CsOptions...
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs = 1

    instr 1

    kcps = 110
    ifn  = 1

    knh	line p4, p3, p5
    asig	buzz 1, kcps, knh, ifn
    	outs asig, asig

    display	asig, .1, 3

    endin
    </CsInstruments>
    <CsScore>
    ;sine wave.
    f 1 0 16384 10 1

    i 1 0 3 20 20
    i 1 + 3 3 3
    i 1 + 3 150 1
    e

    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

dispfft, print

## Crédits

Commentaires sur le paramètre inprds par Rasmus Ekman.

Précédent | Niveau supérieur | Suivant
dispfft | Sommaire | distort