Instruction m (instruction de marquage)
Précédent | Instructions de partition et routines GEN | Suivant

## Instruction m (instruction de marquage)

m — Positionne une marque nommée dans la partition.

## Description

Positionne une marque nommée dans la partition, qui peut être utilisée par une instruction n.

## Syntaxe

    m p1

## Initialisation

p1 -- Nom de la marque.

## Exécution

Peut être utile pour construire une structure couplet refrain dans la partition. Les noms peuvent contenir des lettres et des chiffres.

Par exemple, la partition suivante :

    m foo
    i1 0 1
    i1 1 1.5
    i1 2.5 2
    s
    i1 0 10
    s
    n foo
    e

sera passée au préprocesseur de Csound comme :

    i1 0 1
    i1 1 1.5
    i1 2.5 2
    s
    i1 0 10
    s
    ;; ceci est la section nommée répétée
    i1 0 1
    i1 1 1.5
    i1 2.5 2
    s
    ;; fin de la section nommée
    e

## Exemples

Voici un exemple de l'instruction m. Il utilise le fichier m.csd.

Exemple 1255. Exemple de l'instruction m.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if RT audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o m.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1

    aenv expseg .01, p3*0.25, 1, p3*0.75, 0.01
    asig poscil3 .8*aenv, p4, 1
         outs asig, asig

    endin
    </CsInstruments>
    <CsScore>
    f 1 0 16384 10 1	;sine wave

    m foo			;mark section
    i 1 0   1 110
    i 1 1.5 1 220
    i 1 3   1 440
    i 1 4.5 1 880
    s			;second section
    i 1 0 2 110
    i 1 2 2 220
    s
    n foo			;repeat marked section
    e
    </CsScore>
    </CsoundSynthesizer>

## Crédits

Auteur : John ffitch
Université de Bath/Codemist Ltd.
Bath, UK
Avril 1998

Nouveau dans la version 3.48 de Csound

Précédent | Niveau supérieur | Suivant
Instruction i (instruction d'instrument ou de note) | Sommaire | Instruction n