random
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## random

random — Génère une suite contrôlée de nombres pseudo-aléatoires entre des valeurs minimale et maximale.

## Description

Génère une suite contrôlée de nombres pseudo-aléatoires entre des valeurs minimale et maximale.

## Syntaxe

    ares random kmin, kmax

    ires random imin, imax

    kres random kmin, kmax

## Initialisation

imin -- limite inférieure de l'intervalle

imax -- limite supérieure de l'intervalle

## Exécution

kmin -- limite inférieure de l'intervalle

kmax -- limite supérieure de l'intervalle

L'opcode random est semblable à linrand et à trirand mais parfois je [Gabriel Maldonado] le trouve plus pratique car il permet de fixer arbitrairement les valeurs du minimum et du maximum.

## Exemples

Voici un exemple de l'opcode random. Il utilise le fichier random.csd.

Exemple 863. Exemple de l'opcode random.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if RT audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o random.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1	;same values every time

    krnd random 100, 1000
         printk .5, krnd			; look
    aout oscili 0.8, 440+krnd, 1		; & listen
         outs aout, aout

    endin

    instr 2	;different values every time

    seed 0
    krnd random 100, 1000			; seed from system clock
         printk .5, krnd			; look
    aout oscili 0.8, 440+krnd, 1		; & listen
         outs aout, aout

    endin
    </CsInstruments>
    <CsScore>
    f 1 0 16384 10 1	;sine wave.

    i 1 0 1
    i 2 2 1
    e
    </CsScore>
    </CsoundSynthesizer>

Sa sortie contiendra des lignes comme celles-ci :

     i   1 time     0.00067:   894.58566
     i   1 time     0.50000:   748.44281
     i   1 time     1.00000:   328.29916

    WARNING: Seeding from current time 1656666052

     i   2 time     2.00067:   690.71466
     i   2 time     2.50000:   459.42445
     i   2 time     3.00000:   100.85594

## Voir aussi

linrand, randomh, randomi, trirand

## Crédits

Auteur : Gabriel Maldonado

Précédent | Niveau supérieur | Suivant
randi | Sommaire | randomh