wgpluck
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## wgpluck

wgpluck — Une simulation haute fidélité de corde pincée.

## Description

Une simulation haute fidélité de corde pincée, utilisant des lignes à retard avec interpolation.

## Syntaxe

    ares wgpluck icps, iamp, kpick, iplk, idamp, ifilt, axcite

## Initialisation

icps -- fréquence de la corde pincée

iamp -- amplitude de la corde pincée

iplk -- point d'excitation le long de la corde, dans l'intervalle compris entre 0 et 1. 0 = pas d'excitation.

idamp -- amortissement de la note. Il contrôle l'extinction globale de la corde. Plus la valeur de idamp est importante, plus la décroissance est rapide. Avec une valeur négative, il y aura un accroissement progressif de la sortie.

ifilt -- contrôle l'atténuation du filtre sur le chevalet. Les valeurs élevées provoquent une décroissance plus rapide des harmoniques supérieurs.

## Exécution

kpick -- Fraction de la longueur de la corde où sera lue la sortie.

axcite -- un signal d'excitation de la corde.

Une corde de fréquence icps est pincée avec l'amplitude iamp au point iplk. L'extinction de la corde virtuelle est contrôlée par idamp et ifilt qui simule le chevalet. L'oscillation est lue au point kpick, et excitée par le signal axcite.

## Exemples

L'exemple suivant produit une note moyennement longue avec une décroissance rapide des partiels supérieurs. Il utilise le fichier wgpluck.csd.

Exemple 1205. Un exemple de l'opcode wgpluck.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    ; Audio out   Audio in    No messages
    -odac           -iadc     -d     ;;;RT audio I/O
    ; For Non-realtime ouput leave only the line below:
    ; -o wgpluck.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    ; Initialize the global variables.
    sr = 44100
    kr = 4410
    ksmps = 10
    nchnls = 1

    ; Instrument #1.
    instr 1
      icps = 220
      iamp = 20000
      kpick = 0.5
      iplk = 0
      idamp = 10
      ifilt = 1000

      axcite oscil 1, 1, 1
      apluck wgpluck icps, iamp, kpick, iplk, idamp, ifilt, axcite

      out apluck
    endin

    </CsInstruments>
    <CsScore>

    ; Table #1, a sine wave.
    f 1 0 16384 10 1

    ; Play Instrument #1 for two seconds.
    i 1 0 2
    e

    </CsScore>
    </CsoundSynthesizer>

L'exemple suivant produit une note plus courte et plus brillante. Il utilise le fichier file wgpluck_brighter.csd.

Exemple 1206. Un exemple de l'opcode wgpluck avec une note plus courte et plus brillante.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    ; Audio out   Audio in    No messages
    -odac           -iadc     -d     ;;;RT audio I/O
    ; For Non-realtime ouput leave only the line below:
    ; -o wgpluck_brighter.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    ; Initialize the global variables.
    sr = 44100
    kr = 4410
    ksmps = 10
    nchnls = 1

    ; Instrument #1.
    instr 1
      icps = 220
      iamp = 20000
      kpick = 0.5
      iplk = 0
      idamp = 30
      ifilt = 10

      axcite oscil 1, 1, 1
      apluck wgpluck icps, iamp, kpick, iplk, idamp, ifilt, axcite

      out apluck
    endin

    </CsInstruments>
    <CsScore>

    ; Table #1, a sine wave.
    f 1 0 16384 10 1

    ; Play Instrument #1 for two seconds.
    i 1 0 2
    e

    </CsScore>
    </CsoundSynthesizer>

## Crédits

Auteur : Michael A. Casey
M.I.T.
Cambridge, Mass.
1997

Nouveau dans la Version 3.47

Précédent | Niveau supérieur | Suivant
wgflute | Sommaire | wgpluck2