FLsetText
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## FLsetText

FLsetText — Fixe l'étiquette d'un widget FLTK.

## Description

FLsetText met la chaîne de caractères entre guillemets de l'argument itext dans l'étiquette du widget cible.

## Syntaxe

    FLsetText "itext", ihandle

    FLsetText istr, ihandle

## Initialisation

« itext » -- une chaîne de caractères entre guillemets contenant le texte de l'étiquette du widget.

istr -- une valeur de taux-i qui dénote une chaîne de caractères via strset désignant le texte de l'étiquette du widget.

ihandle -- un nombre entier (utilisé comme identifiant unique) pris de la sortie d'un opcode de widget déjà en place (qui correspond au widget cible). Il est utilisé pour identifier de manière univoque le widget lors de la modification de son apparence par cette classe d'opcodes. Il ne faut pas fixer la valeur de ihandle directement sous peine de provoquer un plantage de Csound.

## Exemples

Voici un exemple de l'opcode FLsetText. Il utilise le fichier FLsetText.csd.

Exemple 328. Exemple de l'opcode FLsetText.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    ; Audio out   Audio in    No messages
    -odac           -iadc     -d     ;;;RT audio I/O
    ; For Non-realtime ouput leave only the line below:
    ; -o FLsetText.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 128
    nchnls = 2

    ; Example by Giorgio Zucco and Andres Cabrera 2007

    FLpanel "FLsetText",250,100,50,50

    gk1,giha FLcount "", 1, 20, 1, 20, 1, 200, 40, 20, 20, 0, 1, 0, 1

    FLpanelEnd
    FLrun

        instr 1
    ; This instrument is triggered by FLcount above each time
    ; its value changes
    iname = i(gk1)
    print iname
    ; Must use FLsetText on the init pass!
    if (iname == 1) igoto text1
    if (iname == 2) igoto text2
    if (iname == 3) igoto text3

    igoto end

    text1:
    FLsetText "FM",giha
    igoto end

    text2:
    FLsetText "GRANUL",giha
    igoto end

    text3:
    FLsetText "PLUCK",giha
    igoto end

    end:
        endin

    </CsInstruments>
    <CsScore>

    f 0 3600

    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

FLcolor2, FLhide, FLlabel, FLsetAlign, FLsetBox, FLsetColor, FLsetColor2, FLsetFont, FLsetPosition, FLsetSize, FLsetText, FLsetTextColor, FLsetTextSize, FLsetTextType, FLsetVal_i, FLsetVal, FLshow

## Crédits

Auteur : Gabriel Maldonado

Nouveau dans la version 4.22

Précédent | Niveau supérieur | Suivant
FLsetSnapGroup | Sommaire | FLsetTextColor