bformenc
Précédent | Opcodes de l'orchestre et routines GEN obsolètes | Suivant

## bformenc

bformenc — Obsolète. Encode un signal dans le format ambisonic B.

## Description

Encode un signal dans le format ambisonic B. Noter que cet opcode est obsolète et imprécis et qu'il est remplacé par l'opcode bformenc1 bien meilleur qui reprend toutes les caractéristiques importantes ; noter que les arguments de gain ne sont pas disponibles dans bformenc1.

## Syntaxe

    aw, ax, ay, az bformenc asig, kalpha, kbeta, kord0, kord1

    aw, ax, ay, az, ar, as, at, au, av bformenc asig, kalpha, kbeta, \
          kord0, kord1 , kord2

    aw, ax, ay, az, ar, as, at, au, av, ak, al, am, an, ao, ap, aq bformenc \
          asig, kalpha, kbeta, kord0, kord1, kord2, kord3

## Exécution

aw, ax, ay, ... -- cellules de sortie au format B.

asig -- signal d'entrée.

kalpha –- angle d'azimut en degrés (dans le sens des aiguilles d'une montre).

kbeta -- angle d'altitude en degrés.

kord0 -- gain linéaire du format B d'ordre zéro.

kord1 -- gain linéaire du format B du premier ordre.

kord2 -- gain linéaire du format B du deuxième ordre.

kord3 -- gain linéaire du format B du troisième ordre.

## Exemples

Voici un exemple de l'opcode bformenc. Il utilise le fichier bformenc.csd.

Exemple 1320. Exemple de l'opcode bformenc.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    ; Audio out   Audio in    No messages
    ;-odac           -iadc     -d     ;;;RT audio I/O
    ; For Non-realtime ouput leave only the line below:
     -o bformenc.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>
    sr = 44100
    kr = 4410
    ksmps = 10
    nchnls = 8

    ;bformenc is deprecated, please use bformenc1

    instr 1
            ; generate pink noise
            anoise pinkish 1000

            ; two full turns
            kalpha line 0, p3, 720
            kbeta = 0

            ; fade ambisonic order from 2nd to 0th during second turn
            kord0 = 1
            kord1 linseg 1, p3 / 2, 1, p3 / 2, 0
            kord2 linseg 1, p3 / 2, 1, p3 / 2, 0

            ; generate B format
            aw, ax, ay, az, ar, as, at, au, av bformenc anoise, kalpha, kbeta, kord0, kord1, kord2

            ; decode B format for 8 channel circle loudspeaker setup
            a1, a2, a3, a4, a5, a6, a7, a8 bformdec 4, aw, ax, ay, az, ar, as, at, au, av

            ; write audio out
            outo a1, a2, a3, a4, a5, a6, a7, a8
    endin

    </CsInstruments>
    <CsScore>

    ; Play Instrument #1 for 20 seconds.
    i 1 0 20
    e

    </CsScore>
    </CsoundSynthesizer>

## Crédits

Auteur : Samuel Groner
2005

Nouveau dans la version 5.07. Obsolète dans la 5.09.

Précédent | Niveau supérieur | Suivant
bformdec | Sommaire | clock