vbap8move
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## vbap8move

vbap8move — Distribue un signal audio sur 8 canaux avec des sources virtuelles en mouvement.

## Description

Distribue un signal audio sur 8 canaux avec des sources virtuelles en mouvement.

## Syntaxe

    ar1, ..., ar8 vbap8move asig, idur, ispread, ifldnum, ifld1 \
          [, ifld2] [...]

## Initialisation

idur -- durée pendant laquelle le mouvement a lieu.

ispread -- diffusion de la source virtuelle (de 0 à 100). S'il vaut 0, on a un panoramique d'amplitude conventionnel. Plus ispread augmente et plus le nombre de haut-parleurs utilisés dans le panoramique augmente. S'il vaut 100, le son est appliqué à tous les haut-parleurs.

ifldnum -- nombre de champs (sa valeur absolue doit être supérieure ou égale à 2). Si ifldnum est positif, le mouvement de la source virtuelle est une ligne brisée spécifiée par les directions données. Chaque transition est exécutée durant un intervalle de même durée. Si ifldnum est négatif, les vélocités angulaires spécifiées sont appliquées à la source virtuelle durant les intervalles de temps spécifiés correspondants (voir ci-dessous).

ifld1, ifld2, ... -- angles d'azimut ou vélocités angulaires et durées correspondantes des phases du mouvement (voir ci-dessous).

## Exécution

asig -- signal audio à traiter.

vbap8move permet l'utilisation de sources virtuelles en mouvement. Si ifldnum est positif, les champs représentent les directions de la source virtuelle durant des intervalles de temps égaux, iazi1, [iele1,] iazi2, [iele2,], etc. La position de la source virtuelle est interpolée entre ces directions en partant de la première direction et en terminant à la dernière. Chaque intervalle est interpolé durant une fraction de la durée de l'évènement sonore égale à durée_totale / nombre_intervalles.

Si ifldnum est négatif, les champs représentent les vitesses angulaires à intervalles réguliers. Le premier champ est cependant la direction de départ, iazi1, [iele1,] iazi_vel1, [iele_vel1,] iazi_vel2, [iele_vel2,] ... Chaque vitesse est appliquée à la note qui occupe la fraction durée_totale / nombre_de_vitesses de la durée de l'évènement sonore. Si l'élévation de la source virtuelle dépasse 90 degrés ou devient inférieure à 0 degré, la polarité de la vitesse angulaire change. Ainsi l'élévation angulaire produit une source virtuelle qui monte et descend entre 0 et 90 degrés.

| Avertissement
Prière de noter que tous les opcodes de panoramique vbap nécessitent une initialisation du système vbap avec vbaplsinit.

## Exemples

Voici un exemple simple de l'opcode vbap8move. Il utilise le fichier vbap8move.csd.

Exemple 1144. Exemple de l'opcode vbap8move.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    ; Audio out   Audio in
    -odac           -iadc    ;;;RT audio I/O
    ; For Non-realtime ouput leave only the line below:
    ; -o vbap4move.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 48000
    ksmps = 10
    nchnls = 8

    ;Example by Hector Centeno 2007

    vbaplsinit    2, 8, 15, 65, 115, 165, 195, 245, 295, 345

        instr 1
    ifldnum = 9
    ispread = 30
    idur = p3

    ;; Generate a sound source
    kenv loopseg 10, 0, 0, 0, 0.5, 1, 10, 0
    a1 pinkish 3000*kenv

    ;; Move circling around once all the speakers
    aout1, aout2, aout3, aout4, aout5, aout6, aout7, aout8 vbap8move a1, idur, ispread, ifldnum, 15, 65, 115, 165, 195, 245, 295, 345, 15

    ;; Speaker mapping
    aFL = aout8 ; Front Left
    aFR = aout1 ; Front Right
    aMFL = aout7 ; Mid Front Left
    aMFR = aout2 ; Mid Front Right
    aMBL = aout6 ; Mid Back Left
    aMBR = aout3 ; Mid Back Right
    aBL = aout5 ; Back Left
    aBR = aout4 ; Back Right

    outo aFL, aFR, aMFL, aMFR, aMBL, aMBR, aBL, aBR

        endin

    </CsInstruments>
    <CsScore>
    i1 0 30
    e
    </CsScore>
    </CsoundSynthesizer>

## Référence

Ville Pulkki : « Virtual Sound Source Positioning Using Vector Base Amplitude Panning » Journal of the Audio Engineering Society, juin 1997, Vol. 45/6, p. 456.

## Voir aussi

vbap16, vbap16move, vbap4, vbap4move, vbap8, vbaplsinit, vbapz, vbapzmove

## Crédits

Auteur : Ville Pulkki
Sibelius Academy Computer Music Studio
Laboratoire d'Acoustique et de Traitement du Signal Audio
Helsinki, Université de Technologie
Helsinki, Finlande
Mai 2000

Nouveau dans la Version 4.07 de Csound.

Précédent | Niveau supérieur | Suivant
vbap8 | Sommaire | vbaplsinit