tonek
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## tonek

tonek — Un filtre passe-bas récursif du premier ordre avec une réponse en fréquence variable.

## Description

Un filtre passe-bas récursif du premier ordre avec une réponse en fréquence variable.

## Syntaxe

    kres tonek ksig, khp [, iskip]

## Initialisation

iskip (facultatif, par défaut 0) -- état initial de l'espace de données interne. Comme le filtrage comprend une boucle de rétroaction sur la sortie précédente, l'état initial de l'espace de stockage utilisé est significatif. Une valeur nulle provoquera l'effacement de cet espace ; une valeur non nulle autorisera la persistance de l'information précédente. La valeur par défaut est 0.

## Exécution

kres -- le signal de sortie au taux de contrôle.

ksig -- le signal d'entrée au taux de contrôle.

khp -- le point à mi-puissance de la courbe de réponse, en Hertz. La mi-puissance est définie par puissance maximale / racine de 2.

tonek est semblabe à tone à part le fait que sa sortie se fait au taux de contrôle plutôt qu'au taux audio.

## Exemples

Voici un exemple de l'opcode tonek. Il utilise le fichier tonek.csd.

Exemple 1096. Exemple de l'opcode tonek.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac      ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o tonek.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    gisin ftgen 0, 0, 2^10, 10, 1

    instr 1

    ksig	randomh	400, 1800, 150
    aout	poscil	.2, 100+ksig, gisin
    	outs	aout, aout
    endin

    instr 2

    ksig	randomh	400, 1800, 150
    khp	line	1, p3, 100	;vary high-pass
    ksig	tonek	ksig, khp
    aout	poscil	.2, 100+ksig, gisin
    	outs	aout, aout
    endin

    </CsInstruments>
    <CsScore>

    i 1 0 5
    i 2 5.5 5
    e
    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

areson, aresonk, atone, atonek, port, portk, reson, resonk, tone

## Crédits

Auteur : Robin Whittle
Australie
Mai 1997

Précédent | Niveau supérieur | Suivant
tone | Sommaire | tonex