foscili
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## foscili

foscili — Oscillateur élémentaire modulé en fréquence avec interpolation linéaire.

## Description

Oscillateur élémentaire modulé en fréquence avec interpolation linéaire.

## Syntaxe

    ares foscili xamp, kcps, xcar, xmod, kndx, ifn [, iphs]

## Initialisation

ifn -- numéro de la table de fonction. Nécessite un point de garde de lecture cyclique.

iphs (faculatif, par défaut 0) -- phase initiale de la forme d'onde dans la table ifn, exprimée comme une fraction d'une période (0 à 1). Avec une valeur négative, l'initialisation de la phase sera ignorée. La valeur par défaut est 0.

## Exécution

xamp -- l'amplitude du signal de sortie.

kcps -- un dénominateur commun, en cycles par seconde, pour les fréquences porteuse et modulante.

xcar -- un facteur qui, lorsqu'il est multiplié par le paramètre kcps, donne la fréquence de la porteuse.

xmod -- un facteur qui, lorsqu'il est multiplié par le paramètre kcps, donne la fréquence de la modulante.

kndx -- l'indice de modulation.

foscili diffère de foscil en ce que la procédure standard d'utilisation d'une phase tronquée comme index de lecture des échantillons est remplacée ici par une interpolation entre deux lectures successives. Les générateurs avec interpolation produiront un signal de sortie nettement plus propre, mais ils peuvent prendre jusqu'à deux fois plus de temps de calcul. On peut obtenir également ce type de précision sans le surcoût du calcul de l'interpolation en utilisant de grandes tables de fonction stockées de 2K, 4K ou 8K points, si l'on dispose de cet espace mémoire.

## Exemples

Voici un exemple de l'opcode foscili. Il utilise le fichier foscili.csd.

Exemple 365. Exemple de l'opcode foscili.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac      ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o foscili.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1

    kcps = 440
    kcar = 1
    kmod = p4
    kndx line 0, p3, 20	;intensivy sidebands

    asig foscili .5, kcps, kcar, kmod, kndx, 1
         outs asig, asig

    endin
    </CsInstruments>
    <CsScore>
    ; sine
    f 1 0 16384 10 1

    i 1 0  9 .01	;vibrato
    i 1 10 .  1
    i 1 20 . 1.414	;gong-ish
    i 1 30 5 2.05	;with "beat"
    e
    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

Plus d'information au sujet de la modulation de fréquence sur Wikipedia : http://en.wikipedia.org/wiki/Frequency_modulation_synthesis

## Crédits

Exemple écrit par Kevin Conder.

Précédent | Niveau supérieur | Suivant
foscil | Sommaire | fout