trighold
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## trighold

trighold — Déclencheur mesuré, maintient une valeur pour une durée donnée.

## Description

Opcode du greffon scugens.

Déclencheur mesuré. Adapté de Trig de Supercollider. Quand une transition d'une valeur non-positive à une valeur positive a lieu en entrée, trighold restitue le niveau du signal déclencheur pendant la durée spécifiée, sinon la sortie vaut zéro.

## Syntaxe

    aout trighold ain, kdur

    kout trighold kin, kdur

## Initialisation

ain -- Déclencheur, pouvant être n'importe quel signal. Un déclenchement a lieu quand le signal passe d'une valeur non-positive à une valeur positive.

## Exécution

kdur -- Durée du déclenchement en secondes.

## Exemples

Voici un exemple de l'opcode trighold. Il utilise le fichier trighold.csd.

Exemple 934. Exemple de l'opcode trighold.

Voir les sections Audio en temps réel et Options de la ligne de commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 128
    nchnls = 2
    0dbfs = 1.0

    instr 1
      km = metro(1)
      kt timeinsts
      ktrig = trighold(km, 0.5)
      printks "t=%f  km=%f    ktrig=%f\n", 0.01, kt, km, ktrig
    endin

    instr 2
      am = upsamp(metro(1))
      aenv = trighold(am, 0.5)
      asig pinker
      outch 1, asig*aenv
      outch 2, asig
    endin

    </CsInstruments>
    <CsScore>
    i 1 0 10
    i 2 0 10

    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

lag, metro, mpulse trigger

## Crédits

Par : Eduardo Moguillansky 2017

Précédent | Niveau supérieur | Suivant
sc_trig | Sommaire | seed