moogvcf2
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## moogvcf2

moogvcf2 — Une simulation numérique de la configuration du filtre en échelle à diode de Moog.

## Description

Une simulation numérique de la configuration du filtre en échelle à diode de Moog.

## Syntaxe

    ares moogvcf2 asig, xfco, xres [,iscale, iskip]

## Initialisation

iscale (facultatif, 0dBfs par défaut) -- facteur de pondération interne, car les opérations du code nécessitent que le signal soit dans l'intervalle +/-1. L'entrée est d'abord divisée par iscale, puis la sortie est multipliée par iscale.

iskip (facultatif, 0 par défaut) -- s'il est non nul, l'initialisation du filtre est ignorée.

## Exécution

asig -- signal d'entrée

xfco -- fréquence de coupure du filtre en Hz. Peut-être de taux-i, de taux-k ou de taux-a.

xres -- quantité de résonance. Il y a des auto-oscillations lorsque xres est proche de 1. Peut-être de taux-i, de taux-k ou de taux-a.

moogvcf2 est une simulation numérique de la configuration du filtre en échelle à diode de Moog. Cette émulation est librement basée sur le papier « Analyzing the Moog VCF with Considerations for Digital Implementation » par Stilson et Smith (CCRMA). Cette version fut codée dans Csound à l'origine par Josep Comajuncosas. Quelques modifications et conversions en C ont été apportées par Hans Mikelson et ensuite ajustées.

moogvcf2 est identique à moogvcf, sauf que le paramètre iscale vaut par défaut 0dbfs au lieu de 0, ce qui garantit que l'amplitude sera normalement correcte.

## Exemples

Voici un exemple de l'opcode moogvcf2. Il utilise le fichier moogvcf2.csd.

Exemple 622. Exemple de l'opcode moogvcf2.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac   ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o moogvcf2.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1

    aout diskin2 "beats.wav", 1, 0, 1
    kfco line 100, p3, 10000		;filter-cutoff
    krez init p4
    asig moogvcf2 aout, kfco, krez
         outs asig, asig

    endin
    </CsInstruments>
    <CsScore>

    i 1 0 4 .1
    i 1 + 4 .6
    i 1 + 4 .9
    e
    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

moogvcf, biquad, rezzy

## Crédits

Auteur : Hans Mikelson et John ffitch
Octobre 1998 / Juillet 2006

Nouveau dans la version 5.03 de Csound.

Précédent | Niveau supérieur | Suivant
moogvcf | Sommaire | moscil