port
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## port

port — Applique un portamento à un signal de contrôle en escalier.

## Description

Applique un portamento à un signal de contrôle en escalier.

## Syntaxe

    kres port ksig, ihtim [, isig]

## Initialisation

ihtim -- durée à mi-parcours de la fonction, en secondes.

isig (facultatif, par défaut 0) -- valeur initiale (c-à-d. précédente) pour la rétroaction interne. La valeur par défaut est 0. Avec une valeur négative l'initialisation sera ignorée et la dernière valeur de l'instance précédente sera la valeur initiale de la note.

## Exécution

kres -- le signal de sortie au taux de contrôle.

ksig -- le signal d'entrée au taux de contrôle.

port applique un portamento à un signal de contrôle en escalier. A chaque nouveau palier, ksig est filtré par un filtre passe-bas pour que la transition vers cette valeur se fasse au taux déterminé par ihtim. ihtim est la durée à « mi-parcours » de la fonction (en secondes), au cours de laquelle la courbe parcourera la moitié de la distance la séparant de la nouvelle valeur, puis la moitié de la moitié, etc., n'atteignant théoriquement jamais son asymptote. Avec portk, la durée à mi-parcours peut être variée au taux de contrôle.

## Exemples

Voici un exemple de l'opcode port. Il utilise le fichier port.csd.

Exemple 760. Exemple de l'opcode port.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac   ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o port.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    0dbfs  = 1
    nchnls = 2

    instr 1

    aout  diskin2 "fox.wav",1, 0, 1
    kf,ka ptrack aout, 512	; pitch track with winsize=1024
    kcps  port kf, 0.01	; smooth freq
    kamp  port ka, 0.01	; smooth amp
    ; drive an oscillator
    asig  poscil ampdb(kamp)*0dbfs, kcps, 1
          outs  asig, asig

    endin
    </CsInstruments>
    <CsScore>
    ; simple sine wave
    f 1 0 4096 10 1

    i 1 0  5
    e
    </CsScore>
    </CsoundSynthesizer>

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

## Voir aussi

areson, aresonk, atone, atonek, portk, reson, resonk, tone, tonek

Précédent | Niveau supérieur | Suivant
polynomial | Sommaire | portk