atonek
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## atonek

atonek — Un filtre passe-haut dont les fonctions de transfert sont les complémentaires de celles de l'opcode tonek.

## Description

Un filtre passe-haut dont les fonctions de transfert sont les complémentaires de celles de l'opcode tonek.

## Syntaxe

    kres atonek ksig, khp [, iskip]

## Initialisation

iskip (facultatif, par défaut 0) -- état initial de l'espace de données interne. Comme le filtrage comprend une boucle de rétroaction sur la sortie précédente, l'état initial de l'espace de stockage utilisé est significatif. Une valeur nulle provoquera l'effacement de cet espace ; une valeur non nulle autorisera la persistance de l'information précédente. La valeur par défaut est 0.

## Exécution

kres -- le signal de sortie au taux de contrôle.

ksig -- le signal d'entrée au taux de contrôle.

khp -- le point à mi-puissance de la courbe de réponse, en Hertz. La mi-puissance est définie par puissance maximale / racine de 2.

atonek est un filtre dont les fonctions de transfert sont complémentaires de celles de tonek. Ainsi atonek est un filtre passe-haut dont les fonctions de transfert représentent les aspects « filtrés » de leurs compléments. Cependant, l'échelle de puissance n'est pas normalisée dans atonek mais reste le complément réel de l'unité correspondante.

## Exemples

Voici un exemple de l'opcode atonek. Il utilise le fichier atonek.csd.

Exemple 63. Exemple de l'opcode atonek.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;RT audio out
    ;-iadc    ;;;uncomment -iadc if RT audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o atonek.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>
    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs = 1

    gisin ftgen 0, 0, 2^10, 10, 1

    instr 1

    ksig	randomh	400, 1800, 150
    aout	poscil	.2, 1000+ksig, gisin
    	outs	aout, aout
    endin

    instr 2

    ksig	randomh	400, 1800, 150
    khp	line	1, p3, 400	;vary high-pass
    ksig	atonek	ksig, khp
    aout	poscil	.2, 1000+ksig, gisin
    	outs	aout, aout
    endin

    </CsInstruments>
    <CsScore>
    i 1 0 5
    i 2 5.5 5
    e
    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

areson, aresonk, atone, port, portk, reson, resonk, tone, tonek

## Crédits

Auteur : Robin Whittle
Australie
Mai 1997

Précédent | Niveau supérieur | Suivant
atone | Sommaire | atonex