readk3
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## readk3

readk3 — Lit périodiquement les valeurs de trois signaux de contrôle de l'orchestre depuis un fichier externe.

## Description

Lit périodiquement les valeurs de trois signaux de contrôle de l'orchestre depuis un fichier externe.

## Syntaxe

    kr1, kr2, kr3 readk3 ifilname, iformat, iprd

## Initialisation

ifilname -- un entier N indiquant un fichier nommé "readk.N" ou une chaîne de caractères (entre guillemets, espaces autorisés) contenant le nom du fichier externe. Si c'est une chaîne de caractères, elle peut être un nom de chemin complet avec un répertoire spécifié ou bien un simple nom de fichier. Dans ce dernier cas, le fichier est d'abord cherché dans le répertoire courant, puis dans SSDIR et finalement dans SFDIR.

iformat -- spécifie le format des données d'entrée :

- 1 = entiers signés sur 8 bit (char)

- 4 = entiers courts sur 16 bit

- 5 = entiers longs sur 32 bit

- 6 = flottants sur 32 bit

- 7 = entiers longs en ASCII (plein texte)

- 8 = flottants en ASCII (plein texte)

Noter que les formats A-law et U-law ne sont pas disponibles, et que tous les formats sauf les deux derniers sont binaires. Le fichier d'entrée doit être un fichier de données brutes sans en-tête.

iprd -- le taux (période) en secondes, arrondi à la période de contrôle de l'orchestre la plus proche, auquel les signaux sont lus depuis le fichier. Une valeur de 0 implique une période de contrôle (le minimum imposé), qui lira les nouvelles valeurs au taux de contrôle de l'orchestre. Avec des périodes plus longues, les mêmes valeurs seront répétées pendant plus d'une période de contrôle.

## Exécution

kr1, kr2, kr3 -- les signaux lus depuis ifilname.

Cette opcode permet de lire les valeurs de trois signaux générés au taux de contrôle depuis un fichier externe nommé. Le fichier ne doit pas contenir d'en-tête d'information mais il doit contenir une suite temporelle de valeurs de contrôle échantillonnées régulièrement. Pour les formats binaires, les échantillons individuels de chaque signal sont alternés. Pour les formats de texte ASCII, les valeurs doivent être séparées par au moins un espace. Les trois "canaux" d'une trame peuvent se trouver sur la même ligne ou être séparés par un caractère de retour à la ligne. Il peut y avoir n'importe quel nombre d'opcodes readk3 dans un instrument ou dans un orchestre et il peuvent lire à partir du même ou depuis différents fichiers.

## Exemples

Voici un exemple de l'opcode readk3. Il utilise le fichier readk3.csd.

Exemple 873. Exemple de l'opcode readk3.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac      ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o readk3.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    giSine ftgen 0, 0, 2^10, 10, 1

    instr 1 ;writes three control signals to a file
    kfreq     randh     100, 1, 2, 1, 500 ;generates one random number between 400 and 600 per second
    kdb       randh     12, 1, 2, 1, -12 ;amplitudes in dB between -24 and 0
    kpan      randh     .5, 1, 2, 1, .5 ;panning between 0 and 1
              dumpk3    kfreq, kdb, kpan, "dumpk3.txt", 8, 1 ;writes the control signals
              prints    "WRITING:\n"
              printks   "kfreq = %f, kdb = %f, kpan = %f\n", 1, kfreq, kdb, kpan  ;prints them
    endin

    instr 2 ;reads the file written by instr 1
    kf,kdb,kp readk3    "dumpk3.txt", 8, 1
              prints    "READING:\n"
              printks   "kfreq = %f, kdb = %f, kpan = %f\n", 1, kf, kdb, kp  ;prints again
    kdb       lineto    kdb, .1 ;smoothing amp transition
    kp        lineto    kp, .1 ;smoothing pan transition
    aout      poscil    ampdb(kdb), kf, giSine
    aL, aR    pan2      aout, kp
              outs      aL, aR
    endin

    </CsInstruments>
    <CsScore>
    i 1 0 5
    i 2 5 5
    e
    </CsScore>
    </CsoundSynthesizer>

Sa sortie comprendra des lignes comme celles-ci :

    WRITING:
    kfreq = 473.352855, kdb = -15.197657, kpan = 0.366764
    kfreq = 473.352855, kdb = -15.197657, kpan = 0.366764
    kfreq = 441.426368, kdb = -19.026206, kpan = 0.207327
    kfreq = 452.965140, kdb = -21.447486, kpan = 0.553270
    kfreq = 585.106328, kdb = -11.903852, kpan = 0.815665
    kfreq = 482.056760, kdb = -4.046744, kpan = 0.876537

    READING:
    kfreq = 473.352900, kdb = -15.197700, kpan = 0.366800
    kfreq = 473.352900, kdb = -15.197700, kpan = 0.366800
    kfreq = 441.426400, kdb = -19.026200, kpan = 0.207300
    kfreq = 452.965100, kdb = -21.447500, kpan = 0.553300
    kfreq = 585.106300, kdb = -11.903900, kpan = 0.815700
    kfreq = 482.056800, kdb = -4.046700, kpan = 0.876500

## Voir aussi

dumpk, dumpk2, dumpk3, dumpk4, readk, readk2, readk4

## Crédits

Par : John ffitch and Barry L. Vercoe

1999 ou avant

Précédent | Niveau supérieur | Suivant
readk2 | Sommaire | readk4