tigoto
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## tigoto

tigoto — Tranfère le contrôle lors de la phase d'initialisation si la nouvelle note est liée à la précédente note tenue.

## Description

Semblable à igoto mais ne fonctionne que lors d'une phase d'initialisation concernant une nouvelle note « liée » à une note précédente tenue. (Voir l'instruction i). Ca ne fonctionne pas s'il n'y a pas de liaison. Permet à un instrument d'ignorer l'initialisation de ses unités si une liaison a été proposée avec succès. (Voir aussi tival).

## Syntaxe

    tigoto label

où label se trouve dans le même bloc d'instrument et n'est pas une expression.

## Exemples

Voici un exemple de l'opcode tigoto. Il utilise le fichier tigoto.csd.

Exemple 1086. Exemple de l'opcode tigoto.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac   ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o tigoto.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1

    idur  = abs(p3)				;make p3 positive even if p3 is negative in score
    itiv  tival
    i1    = -1				;assume this is tied note, so keep fase of oscili
          tigoto slur			;no reinitialisation on tied notes
    i1    = 0				;first note, so reset phase
    aatt  line p4, idur, 0			;primary envelope

    slur:
          if itiv==0 kgoto note		;no expression on first and second note
    aslur linseg 0, idur*.3, p4, idur*.7, 0	;envelope for slurred note
    aatt  = aatt + aslur

    note:
    asig  oscili aatt, p5, 1, i1
          outs   asig, asig

    endin
    </CsInstruments>
    <CsScore>
    f1 0 4096 10 1	;sine wave

    i1  0    -5  .8  451	;p3 = 5 seconds
    i1  1.5 -1.5 .1  512
    i1  3    2   .7  440	;3 notes together--> duration = 5 seconds

    e
    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

cigoto, goto, if, igoto, kgoto, timout

Plus d'information sur cet opcode : http://www.csoundjournal.com/2005fall/tiedNotes.html , écrit par Steven Yi.

Précédent | Niveau supérieur | Suivant
tempoval | Sommaire | timedseq