pan2
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## pan2

pan2 — Distribue un signal audio sur deux canaux.

## Description

Distribue un signal audio sur deux canaux avec choix de la méthode.

## Syntaxe

    a1, a2 pan2 asig, xp [, imode]

## Initialisation

imode (facultatif) -- mode de l'algorithme de positionnement stéréophonique. 0 pour un panoramique à puissance égale (harmonique), 1 pour la méthode de la racine carrée, 2 pour un panoramique simplement linéaire et 3 pour un autre panoramique à puissance égale (basé sur un UDO). La valeur par défaut est 0.

## Exécution

pan2 prend en entrée le signal asig et le distribue sur ses deux sorties (essentiellement des haut-parleurs stéréo) en fonction du contrôle xp qui peut être de taux-k ou de taux-a. Une valeur de zéro pour xp indique complètement à gauche et 1 indique complètement à droite.

## Exemples

Voici un exemple de l'opcode pan2. Il utilise le fichier pan2.csd.

Exemple 712. Exemple de l'opcode pan2.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if real audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o pan2.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    giSine ftgen 0, 0, 2^10, 10, 1

    instr 1

    kline	line	0, p3, 1     ; straight line
    ain	oscili	.6, 440, giSine ; audio signal..
    aL,aR	pan2	ain, kline   ; sent across image
    	outs	aL, aR

    endin
    </CsInstruments>
    <CsScore>
    i1 0 5
    e
    </CsScore>
    </CsoundSynthesizer>

## Crédits

Auteur : John ffitch
Université de Bath, Codemist Ltd.
Bath, UK
Septembre 2007

Nouveau dans la version 5.07

Précédent | Niveau supérieur | Suivant
p | Sommaire | pan