cpumeter
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## cpumeter

cpumeter — Retourne le taux d'utilisation cpu soit globalement soit par coeur.

## Description

Retourne le taux d'utilisation de l'unité centrale soit globalement soit par coeur, pour contrôler à quel point le traitement se rapproche des capacités maximales.

A noter que cet opcode n'est actuellement disponible que sous GNU/Linux.

## Syntaxe

    ktot[,kcpu1, kcpu2,...]cpumeter ifreq

## Initialisation

ifreq est le temps de rafraichissement de la mesure en secondes. S'il est trop court, alors on verra principalement les valeurs zéro ou cent. Une valeur de 0.1 semble acceptable.

## Exécution

cpumeter lit la durée totale du temps de repos lors des dernières ifreq secondes et retourne le pourcentage d'utilisation. Si le résultat ktot n'est pas suffisant, on peut récupérer le même type de résultat pour chaque coeur.

## Exemples

Voici un exemple de l'opcode cpumeter. Il utilise le fichier cpumeter.csd.

Exemple 183. Exemple de l'opcode cpumeter.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o cpumeter.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 1
    0dbfs  = 1

    instr 1 ;cpu metering; stop when too large
    k0   cpumeter   0.1
         printk2 k0
         if k0>70 then
           event "i", 3, 0.1, 1
         endif
    endin

    instr 2
         event_i    "i", 2, 1, 1000
         asig oscil 0.2, 440, 1
         out asig
    endin

    instr 3
         exitnow
    endin
    </CsInstruments>
    <CsScore>
    f 1 0 32768 10 1	; sine wave

    i 1 0 1000
    i 2 0 1000
    e
    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

maxalloc, prealloc, cpuprc

## Crédits

Auteur : John ffitch
Mai 2011

Nouveau dans la version 5.14 de Csound, seulement pour Linux/Unix et OSX.

Précédent | Niveau supérieur | Suivant
cpsxpch | Sommaire | cpuprc