Instruction a (ou instruction avancer)
Précédent | Instructions de partition et routines GEN | Suivant

## Instruction a (ou instruction avancer)

a — Avancer le temps de la partition de la quantité spécifiée.

## Description

Provoque l'avancement du temps de la partition de la quantité spécifiée sans produire d'échantillons sonores.

## Syntaxe

    a p1  p2  p3

## Exécution

p1 Non significatif. Habituellement zéro.
p2 Date en pulsations à laquelle l'avance doit commencer.
p3 Nombre de pulsations duquel il faut avancer sans produire de son.
p4 |
p5 | Non significatifs.
p6 |
.
.

### Considérations Spéciales

Cette instruction permet d'avancer le compteur de pulsations dans une partition sans générer les échantillons sonores correspondants. On peut l'utiliser quand une section de la partition est incomplète (le début ou le milieu sont manquants) et que l'on ne souhaite pas générer et écouter une longue période de silence.

p2, date d'activation, et p3, nombre de pulsations, sont traités comme dans l'instruction i,en tenant compte du tri et des modifications par les instructions t.

Une instruction a sera insérée temporairement dans la partition par la fonction Score Extract lorsque l'extrait commence après le début de la Section. Ceci afin de conserver le compte de pulsations de la partition originale pour les messages de pic d'amplitude qui sont rapportés sur la console de l'utilisateur.

A chaque exécution d'un orchestre lorsqu'une instruction a est rencontrée, sa présence et son effet son rapportés sur la console de l'utilisateur.

## Exemples

Voici un exemple de l'instruction a. Il utilise le fichier a.csd.

Exemple 1249. Exemple de l'instruction a.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if RT audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o a.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1

    aenv expseg .01, p3*0.25, 1, p3*0.75, 0.01
    asig poscil3 .8*aenv, p4
         outs asig, asig

    endin
    </CsInstruments>
    <CsScore>
    ;two sections
    s
    a 0 0 6		;advance score 6 seconds
    i 1 0 2 110	;these first 2 notes
    i 1 3 2 220	;will not sound
    i 1 6 2 440
    i 1 9 2 880
    s
    a 0 3 6		;advance score 6 seconds, but do this after 3 seconds
    i 1 0 2 110	;this will sound, because action time (p2) from a statement = 3
    i 1 3 2 220	;so these 2 notes
    i 1 6 2 440	;will not sound
    i 1 9 2 880	;and this one will
    e
    </CsScore>
    </CsoundSynthesizer>

Précédent | Niveau supérieur | Suivant
Instructions de partition et routines GEN | Sommaire | Instruction b