linsegr
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## linsegr

linsegr — Trace une suite de segments de droite entre les points spécifiés avec un segment de relâchement.

## Description

Trace une suite de segments de droite entre les points spécifiés avec un segment de relâchement.

## Syntaxe

    ares linsegr ia, idur1, ib [, idur2] [, ic] [...], irel, iz

    kres linsegr ia, idur1, ib [, idur2] [, ic] [...], irel, iz

## Initialisation

ia -- valeur initiale.

ib, ic, etc. -- valeur après dur1 secondes, etc.

idur1 -- durée en secondes du premier segment. Avec une valeur nulle ou négative l'initialisation sera ignorée.

idur2, idur3, etc. -- durée en secondes des segments suivants. Une valeur nulle ou négative terminera la phase d'initialisation avec le point précédent, permettant au dernier segment défini de continuer durant toute l'exécution. La valeur par défaut est zéro.

irel, iz -- durée en secondes et valeur finale du segment de relâchement de la note.

Pour les versions de Csound antérieures à la 5.00, le temps de relâchement ne peut pas dépasser 32767/kr secondes. Cette limite a été étendue à (231-1)/kr.

## Exécution

Ces unités génèrent des signaux de contrôle ou audio dont les valeurs passent par 2 ou plus points spécifiés. La somme des valeurs dur peut égaler ou non la durée d'exécution de l'instrument : avec une exécution plus courte, la courbe sera tronquée alors qu'avec une exécution plus longue, le dernier segment défini continuera dans la même direction.

linsegr fait partie des unités « r » de Csound qui contiennent un détecteur de fin de note et une extension de durée pour le relâchement. Quand la fin d'un évènement ou MIDI noteoff est détectée, la durée d'exécution de l'instrument courant est immédiatement allongée de irel secondes, de façon à ce que la valeur iz soit atteinte à la fin de cette période (quelque soit le segment dans lequel se trouvait l'unité). Les unités « r » peuvent aussi être modifiées par les vélocités nulles provoquant un message MIDI noteoff. S'il y a plusieurs extensions de durée dans un instrument, c'est la plus longue qui sera choisie.

On peut utiliser d'autres enveloppes préfabriquées pour lancer un segment de relâchement à la réception d'un message note off, comme linenr et expsegr, ou bien l'on peut construire des enveloppes plus complexes au moyen de xtratim et de release. Noter que qu'il n'est pas nécessaire d'utiliser xtratim avec linsegr, car la durée est allongée automatiquement.

## Exemples

Voici un exemple de l'opcode linsegr. Il utilise le fichier linsegr.csd.

Exemple 511. Exemple de l'opcode linsegr.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac  -+rtmidi=virtual -M0   ;;;realtime audio out and realtime midi in
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o linsegr.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1

    icps	cpsmidi
    iamp	ampmidi	.3

    kenv	linsegr	1, .05, 0.5, 1, 0
    asig	pluck	kenv, icps, 200, 1, 1
    	outs	asig, asig

    endin
    </CsInstruments>
    <CsScore>
    f 1 0 4096 10 1	;sine wave

    f0 30	;runs 30 seconds
    e
    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

linenr, expsegr, envlpxr, mxadsr, madsr expon, expseg, expsega line, linseg, xtratim, transegr

## Crédits

Auteur : Barry L. Vercoe

Décembre 2002, Décembre 2006. Merci à Istvan Varga pour l'ajout de la documentation sur le temps de relâchement maximum.

Nouveau dans Csound 3.47

Précédent | Niveau supérieur | Suivant
linsegb | Sommaire | liveconv