mute
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## mute

mute — Rend muettes/sonores de nouvelles instances d'un instrument donné.

## Description

Rend muettes/sonores de nouvelles instances d'un instrument donné.

## Syntaxe

    mute insnum [, iswitch]

    mute "insname" [, iswitch]

## Initialisation

insnum -- numéro d'instrument. Equivalent à p1 dans une instruction i de partition.

« insname » -- Une chaîne de caractères (entre guillemets) représentant un instrument nommé.

iswitch (facultatif, 0 par défaut) -- représente un commutateur pour rendre muet/sonore un instrument. Une valeur de 0 rendra muettes de nouvelles instances de l'instrument, tandis que les autres valeurs les rendront sonores. La valeur par défaut est 0.

## Exécution

Toutes les nouvelles instances de l'instrument seront muettes (iswitch = 0) ou sonores (iswitch différent de 0). Il n'y a aucun problème à rendre muets des instruments muets ou à rendre sonores des instruments sonores. Le mécanisme est le même que celui qui est utilisé par l'instruction q. de partition. Par exemple, il est possible de rendre muet depuis la partition et de rendre ensuite sonore depuis un instrument.

L'état Muet/Sonore est indiqué par un message (en fonction du niveau des messages).

## Exemples

Voici en exemple de l'opcode mute. Il utilise le fichier mute.csd.

Exemple 632. Exemple de l'opcode mute.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac   ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o mute.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    ; Mute Instrument #2.
    mute 2
    ; Mute Instrument three.
    mute "three"

    instr 1

    a1 oscils 0.2, 440, 0
       outs a1, a1
    endin

    instr 2	; gets muted

    a1 oscils 0.2, 880, 0
       outs a1, a1
    endin

    instr three	; gets muted

    a1 oscils 0.2, 1000, 0
       outs a1, a1
    endin

    </CsInstruments>
    <CsScore>

    i 1 0 1
    i 2 0 1
    i "three" 0 1
    e

    </CsScore>
    </CsoundSynthesizer>

## Crédits

Nouveau dans la version 4.22

Précédent | Niveau supérieur | Suivant
multitap | Sommaire | mvchpf