minabs
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## minabs

minabs — Produit un signal qui est le minimum des valeurs absolues de n'importe quel nombre de signaux d'entrée.

## Description

L'opcode minabs prend en entrée n'importe quel nombre de signaux de taux-a ou de taux-k (tous du même taux), et retourne un signal au même taux qui est le minimum de toutes les entrées. Il est identique à l'opcode min sauf qu'il prend la valeur absolue de chaque entrée avant de les comparer. Ainsi, la sortie est toujours non-négative. Pour les signaux de taux-a, les entrées sont comparées échantillon par échantillon (c-à-d que minabs n'examine pas une période ksmps entière du signal pour trouver son minimum local comme l'opcode max_k le fait).

## Syntaxe

    amin minabs ain1, ain2 [, ain3] [, ain4] [...]

    kmin minabs kin1, kin2 [, kin3] [, kin4] [...]

## Exécution

ain1, ain2, ... -- signaux de taux-a à comparer.

kin1, kin2, ... -- signaux de taux-k à comparer.

## Exemples

Voici un exemple de l'opcode minabs. Il utilise le fichier minabs.csd.

Exemple 604. Exemple de l'opcode minabs.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac   ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o minabs.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1

    k1   oscili 1, 10.0, 1			;combine 3 sinusses
    k2   oscili 1, 1.0, 1			;at different rates
    k3   oscili 1, 3.0, 1
    kmin minabs   k1, k2, k3
    kmin = kmin*250				;scale kmin
    printk2 kmin				;check the values

    aout vco2 .5, 220, 6			;sawtooth
    asig moogvcf2 aout, 600+kmin, .5 	;change filter above 600 Hz
         outs asig, asig

    endin

    </CsInstruments>
    <CsScore>
    f1 0 32768 10 1

    i1 0 5
    e
    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

maxabs, max, min, maxaccum, minaccum, maxabsaccum, minabsaccum, max_k

## Crédits

Auteur : Anthony Kozar
Mars 2006

Nouveau dans la version 5.01 de Csound.

Précédent | Niveau supérieur | Suivant
min | Sommaire | minabsaccum