notnum
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## notnum

notnum — Donne un numéro de note à partir d'un évènement MIDI.

## Description

Donne un numéro de note à partir d'un évènement MIDI.

## Syntaxe

    ival notnum

## Exécution

Donne la valeur de l'octet MIDI (0 - 127) représentant le numéro de note de l'évènement courant.

## Exemples

Voici un exemple de l'opcode notnum. Il utilise le fichier notnum.csd.

Exemple 649. Exemple de l'opcode notnum.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac  -M0 -+rtmidi=virtual ;;;realtime audio out with virtual MIDI in
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    massign 1, 1	; set MIDI channel 1 to play instr 1

    instr   1

    iNum notnum
         print iNum
    ; Convert MIDI note number to Hz
    iHz  = (440.0*exp(log(2.0)*((iNum)-69.0)/12.0))
    aosc oscil 0.6, iHz, 1
         outs  aosc, aosc

    endin
    </CsInstruments>
    <CsScore>
    f 1 0  16384 10 1	;sine wave

    f 0 60			;play 60 seconds

    e
    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

aftouch, ampmidi, cpsmidi, cpsmidib, midictrl, octmidi, octmidib, pchbend, pchmidi, pchmidib, veloc

## Crédits

Auteur : Barry L. Vercoe - Mike Berry
MIT - Mills
Mai 1997

Exemple écrit par David Akbari.

Précédent | Niveau supérieur | Suivant
noteondur | Sommaire | nreverb