dssiaudio
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## dssiaudio

dssiaudio — Traitement audio au moyen d'un greffon LADSPA ou DSSI.

| Note
Greffon : nécessite le greffon dssi4cs

## Syntaxe

    [aout1, aout2, ..., aout9] dssiaudio ihandle, [ain1, ain2, ..., ain9]

## Description

Opcode du greffon dssi4cs.

dssiaudio génère des données audio en traitant un signal d'entrée dans un greffon LADSPA ou DSSI.

## Initialisation

ihandle - le numéro qui identifie le greffon, généré par dssiinit.

## Exécution

aout1, aout2, etc - sortie audio générée par le greffon.

ain1, ain2, etc - entrée audio fournie au greffon pour traitement.

dssiaudio exécute un greffon sur la source audio et produit une sortie audio. Actuellement il peut y avoir jusqu'à quatre entrées et sorties. Il faut fournir un signal à toutes les entrées audio du greffon, sinon le résultat peut être imprévisible. Si le greffon n'a pas d'entrée (par exemple un générateur de bruit), il faut quand même fournir au moins une variable d'entrée qui sera ignorée avec un message.

Il ne faut exécuter qu'un seul dssiaudio à la fois par greffon, sinon des résultats étranges peuvent survenir.

## Exemples

Voici un exemple de l'opcode dssiaudio. Il utilise le fichier dssiaudio.csd.

Exemple 245. Exemple de l'opcode dssiaudio.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;RT audio out
    ;-iadc    ;;;uncomment -iadc if RT audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o DSSIplay_mono.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2

    gihandle dssiinit "caps.so", 19, 1	; = mono phaser and
    gaout    init  0			; verbose about all ports

    instr 1	; activate DSSI

    dssiactivate gihandle, 1
    endin

    instr 2
    ain1	diskin2 "beats.wav", 1,0,1	; loop

    gaout = gaout+(ain1*.5)
    endin

    instr 3

    dssictls gihandle, 0, .8, 1		; range -1 to 1
    dssictls gihandle, 1, .05, 1		; rate 0 to 10
    dssictls gihandle, 2, .8, 1		; depth 0 to 1
    dssictls gihandle, 3, 2, 1		; spread 0 to 3.14
    dssictls gihandle, 4, .7, 1		; feedback 0 to 0.999

    endin

    instr 4

    aout1 dssiaudio gihandle, gaout	;get beats.wav, mono out
          outs aout1,aout1

    gaout = 0

    endin
    </CsInstruments>
    <CsScore>
    i 1 0 20
    i 2 1 20
    i 3 1 20
    i 4 0 20

    e
    </CsScore>
    </CsoundSynthesizer>

## Crédits

2005

Par Andrés Cabrera

Utilise du code provenant du sdk de LADSPA par Richard Furse.

Précédent | Niveau supérieur | Suivant
dssiactivate | Sommaire | dssictls