rireturn
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## rireturn

rireturn — Termine une phase de réinitialisation.

## Description

Termine une phase de réinitialisation (reinit) (c'est-à-dire qu'il n'opère pas pendant l'initialisation standard). Cette instruction, ou un endin, provoquera la reprise de l'exécution normale.

## Syntaxe

                rireturn

## Exemples

Les instructions suivantes génèrent un signal de contrôle exponentiel dont les valeurs vont de 440 à 880 exactement dix fois pendant la durée p3. Elles utilisent le fichier reinit.csd.

Exemple 898. Exemple de l'opcode rireturn.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    ; Audio out   Audio in
    -odac           -iadc    ;;;RT audio I/O
    ; For Non-realtime ouput leave only the line below:
    ; -o reinit.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    kr = 44100
    ksmps = 1
    nchnls = 1

    instr 1

    reset:
            timout 0, p3/10, contin
            reinit reset

    contin:
            kLine expon 440, p3/10, 880
            aSig oscil 10000, kLine, 1
            out aSig
            rireturn

    endin

    </CsInstruments>
    <CsScore>

    f1 0 4096 10 1

    i1 0 10
    e

    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

reinit, rigoto

Précédent | Niveau supérieur | Suivant
rigoto | Sommaire | rms