rezzy
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## rezzy

rezzy — Un filtre passe-bas à résonance.

## Description

Un filtre passe-bas à résonance.

## Syntaxe

    ares rezzy asig, xfco, xres [, imode, iskip]

## Initialisation

imode (facultatif, 0 par défaut) -- mode passe-haut ou passe-bas. S'il vaut zéro, rezzy est passe-bas. S'il est différent de zéro, rezzy est passe-haut. La valeur par défaut est 0. (Nouveau dans la version 3.50 de Csound.)

iskip (facultatif, 0 par défaut) -- s'il est différent de zéro, l'initialisation du filtre est ignorée. (Nouveau dans les versions 4.23f13 et 5.0 de Csound.)

## Exécution

asig -- signal d'entrée

xfco -- fréquence de coupure du filtre en Hz. Depuis la version 3.50, peut-être de taux-i, de taux-k ou de taux-a.

xres -- quantité de résonance. Des valeurs entre 1 et 100 sont typiques. La résonance doit valoir un ou plus. Depuis la version 3.50, peut-être de taux-i, de taux-k ou de taux-a.

rezzy est un filtre passe-bas à résonance créé empiriquement par Hans Mikelson.

## Exemples

Voici un exemple de l'opcode rezzy. Il utilise le fichier rezzy.csd.

Exemple 895. Exemple de l'opcode rezzy.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac   ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o rezzy.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    0dbfs  = 1
    nchnls = 2

    instr 1

    asaw vco2 .3, 110	;sawtooth
    kcf  line 1760, p3, 220	;vary cut-off frequency from 220 to 1280 Hz
    kres = p4		;vary resonance too
    ares rezzy asaw, kcf, kres
    asig balance ares, asaw
         outs asig, asig

    endin
    </CsInstruments>
    <CsScore>

    i 1 0 4 10
    i 1 + 4 30
    i 1 + 4 120	;lots of resonance
    e
    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

biquad, moogvcf

## Crédits

Auteur : Hans Mikelson
Octobre 1998

Nouveau dans la version 3.49 de Csound.

Précédent | Niveau supérieur | Suivant
rewindscore | Sommaire | rfft