sc_lag
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## sc_lag

sc_lag — Lag exponentiel (obsolète).

## Description

Opcode du greffon scugens.

Lag exponentiel avec durée de latence à 60 dB. Obsolète (renommé en lag).

## Syntaxe

    aout sc_lag ain, klagtime [, initialvalue]

    kout sc_lag kin, klagtime [, initialvalue]

## Initialisation

initialvalue -- Si elle est fournie, fixe l'état interne. Vaut par défaut la première valeur passée.

## Exécution

ain -- Signal en entrée.

klagtime -- Durée de latence à 60 dB en secondes.

kladown -- Durée de latence à 60 dB en secondes pour le signal atténué.

C'est essentiellement un filtre à un pôle sauf qu'au lieu de fournir le coefficient directement, celui-ci est calculé en fonction d'un temps de latence à 60 dB. C'est le temps nécessaire pour que le filtre converge à 0.01% d'une valeur. Utile pour lisser un signal de contrôle.

## Exemples

Voici un exemple de l'opcode sc_lag. Il utilise le fichier sc_lag.csd.

Exemple 927. Exemple de l'opcode sc_lag.

Voir les sections Audio en temps réel et Options de la ligne de commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 128
    nchnls = 2
    0dbfs = 1.0

    instr 1
      ; smooth a krate signal
      kx = floor(line(0, p3, 10))
      kx2 = sc_lag(kx, 0.1)
      printk2 kx2
    endin

    instr 2
      ; smooth an audio signal
      kmidi = floor(line(60, p3, 72)/2)*2
      afreq = upsamp(mtof(kmidi))
      afreqsmooth = sc_lag(afreq, 1)
      a1 = oscili(1, afreq)
      a2 = oscili(1, afreqsmooth)
      outch 1, a1
      outch 2, a2
    endin

    </CsInstruments>
    <CsScore>
    i 1 0 5
    i 2 0 10

    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

sc_lagud, lag, lagud, port, portk

## Crédits

Par : Eduardo Moguillansky 2017

Précédent | Niveau supérieur | Suivant
scoreline_i | Sommaire | lag