wguide2
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## wguide2

wguide2 — Un modèle de plaque frappée constitué de deux lignes à retard en parallèle et de deux filtres passe-bas du premier ordre.

## Description

Un modèle de plaque frappée constitué de deux lignes à retard en parallèle et de deux filtres passe-bas du premier ordre.

## Syntaxe

    ares wguide2 asig, xfreq1, xfreq2, kcutoff1, kcutoff2, \
          kfeedback1, kfeedback2

## Exécution

asig -- l'entrée du bruit d'excitation.

xfreq1, xfreq2 -- la fréquence (c-à-d l'inverse de la durée du retard). A été changé au taux-x dans la version 3.59 de Csound.

kcutoff1, kcutoff2 -- la fréquence de coupure du filtre en Hz.

kfeedback1, kfeedback2 -- le facteur de rétroaction.

wguide2 est un modèle de plaque frappée consistant en deux lignes à retard en parallèle et deux filtres passe-bas du premier ordre. Les deux lignes de rétroaction sont mélangées et réenvoyées au délai à chaque cycle.

L'implémentation des algorithmes de guide d'onde comme opcodes au lieu d'instruments d'un orchestre de Csound permet de fixer une valeur de kr différente de celle de sr, ce qui donne de meilleures performances particulièrement en .

wguide2.

| Note
De manière empirique, la somme des deux valeurs de rétroaction ne devrait pas dépasser 0.5 pour éviter de rendre wguide2 instable.

## Exemples

Voici un exemple de l'opcode wguide2. Il utilise le fichier wguide2.csd.

Exemple 1209. Exemple de l'opcode wguide2.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if RT audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o wguide2.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr	1

    aout diskin2 "beats.wav", 1, 0, 1				;in signal
    afreq1 line 100, p3, 2000
    afreq2 line 1200, p3, p4					;vary second frequency in the score
    kcutoff1   = 3000
    kcutoff2   = 1500
    kfeedback1 = 0.25						;the sum of the two feedback
    kfeedback2 = 0.25						;values should not exceed  0.5
    asig wguide2 aout, afreq1, afreq2, kcutoff1, kcutoff2, kfeedback1, kfeedback2
    asig dcblock2 asig						;get rid of DC
          outs asig, asig

    endin
    </CsInstruments>
    <CsScore>
    i 1 0 8 1200	;freqency of afreq2 remains the same
    i 1 9 8 100	;freqency of afreq2 gets lower
    e
    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

wguide1

## Crédits

Auteur : Gabriel Maldonado
Italie
Octobre 1998

Nouveau dans la version 3.49 de Csound.

Précédent | Niveau supérieur | Suivant
wguide1 | Sommaire | while