STKFlute
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## STKFlute

STKFlute — STKFlute utilise un simple modèle physique de flûte.

## Description

Opcode du greffon stkopd.

STKFlute utilise un simple modèle physique de flûte. Le modèle du jet utilise un polynôme, à la Cook.

## Syntaxe

    asignal STKFlute ifrequency, iamplitude, [kjet, kv1[, knoise, kv2[, klfo, kv3[, klfodepth, kv4[, kbreath, kv5]]]]]

## Initialisation

ifrequency -- Fréquence de la note jouée, en Hz.

iamplitude -- Amplitude de la note jouée (entre 0 et 1).

## Exécution

kjet -- contrôleur 2, délai du jet. kv1 compris entre 0 et 127.

knoise -- contrôleur 4, gain du bruit. kv2 compris entre 0 et 127.

klfo -- contrôleur 11, vitesse de l'oscillateur basse-fréquence. kv3 compris entre 0 et 127.

klfodepth -- contrôleur 1, intensité de l'oscillateur basse-fréquence. kv4 compris entre 0 et 127.

kbreath -- contrôleur 128, pression du souffle. kv5 compris entre 0 et 127.

| Notes
Le code pour cet opcode vient directement de la classe Flute du Synthesis Toolkit en C++ par Perry R. Cook et Gary P. Scavone. On peut en savoir plus sur les classes STK ici : https://ccrma.stanford.edu/software/stk/classes.html kc1, kv1, kc2, kv2, kc3, kv3, kc4, kv4, kc5, kv5, kc6, kv6, kc7, kv7, kc8, kv8 -- Jusqu'à 8 paires de contrôle facultatives au taux-k pour les opcodes STK. Chaque paire de contrôle est constituée d'un numéro de contrôleur (kc) suivi d'une valeur de contrôleur (kv). Le numéro de contrôleur ainsi que la valeur associée sont des variables de taux-k. Cependant, durant l'exécution, les numéros de contrôleur sont habituellement constants tandis que les valeurs correspondantes peuvent changer à tout moment. L'ordre des paires de contrôle est arbitraire mais elles doivent apparaître après iamplitude. Il n'est pas non plus nécessaire d'utiliser toutes les paires.

## Exemples

Voici un exemple de l'opcode STKFlute. Il utilise le fichier STKFlute.csd.

Exemple 1006. Exemple de l'opcode STKFlute.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if RT audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o STKFlute.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1

    ifrq	=	p4
    kv1	line	p5, p3, p6				;jet delay
    kv4	line	0, p3, 100				;vibrato depth

    asig	STKFlute cpspch(ifrq), 1, 2, kv1, 4, 100, 11, 100, 1, kv4, 128, 100
    	outs asig, asig
    endin

    </CsInstruments>
    <CsScore>
    i 1 0 5 8.00 0 0
    i 1 7 3 9.00 20 120
    e
    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

STKClarinet.

## Crédits

Auteur : Michael Gogins (d'après Perry Cook)
Irreducible Productions
New York, NY

Nouveau dans la version 5.11 de Csound.

Précédent | Niveau supérieur | Suivant
STKDrummer | Sommaire | STKFMVoices