int
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## int

int — Extrait la partie entière d'un nombre décimal.

## Description

Retourne la partie entière de x.

## Syntaxe

    int(x)  (taux-i ou taux-k ; fonctionne aussi au taux-a dans Csound5)

où l'argument entre parenthèses peut être une expression. Les convertisseurs de valeur effectuent une transformation arithmétique d'unités d'une sorte en unités d'une autre sorte. Le résultat peut devenir ensuite un terme dans une autre expression.

## Exemples

Voici un exemple de l'opcode int. Il utilise le fichier int.csd.

Exemple 469. Exemple de l'opcode int.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac   ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o int.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1

    icount init 0
    loop:
      inum = icount / 3
      inm  = int(inum)
      prints "integer (%f/3) = %f\\n", icount, inm
    loop_lt icount, 1, 10, loop

    endin
    </CsInstruments>
    <CsScore>

    i 1 0 0
    e
    </CsScore>
    </CsoundSynthesizer>

Sa sortie contiendra des lignes comme :

    integer (0.000000/3) = 0.000000
    integer (1.000000/3) = 0.000000
    integer (2.000000/3) = 0.000000
    integer (3.000000/3) = 1.000000
    integer (4.000000/3) = 1.000000
    integer (5.000000/3) = 1.000000
    integer (6.000000/3) = 2.000000
    integer (7.000000/3) = 2.000000
    integer (8.000000/3) = 2.000000
    integer (9.000000/3) = 3.000000

Voici un exemple de groupe d'arrondis, comparant les différents opcodes d'arrondis. Il utilise le fichier rounding-group.csd.

Exemple 470. Exemple de groupe d'arrondis.

    <CsoundSynthesizer>
    <CsOptions>
    -odac       ;
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32

    ; by tgrey 2020
    instr 1

    iLoopStart = p4
    iLoopEnd   = p5
    iOffset    = p6

    iCount init iLoopStart

    if(iLoopStart<iLoopEnd) then		; loop going up
    	while iCount <= iLoopEnd do
    		iVal = iCount+iOffset
    		iRound = round(iVal)
    		iInt = int(iVal)
    		iFloor = floor(iVal)
    		iCeil = ceil(iVal)
    		print iVal, iRound, iInt, iFloor, iCeil
    		iCount = iCount + 1
    	od

    elseif(iLoopEnd<iLoopStart) then	; loop going down
    	while iCount >= iLoopEnd do
    		iVal = iCount+iOffset
    		iRound = round(iVal)
    		iInt = int(iVal)
    		iFloor = floor(iVal)
    		iCeil = ceil(iVal)
    		print iVal, iRound, iInt, iFloor, iCeil
    		iCount = iCount - 1
    	od
    endif
    endin
    </CsInstruments>
    <CsScore>
    i1 0 .1 0 10 .5
    i1 .2 .1 0 -10 .5
    e
    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

abs, exp, frac, log, log10, i, sqrt

## Crédits

Précédent | Niveau supérieur | Suivant
instr | Sommaire | integ