FLvalue
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## FLvalue

FLvalue — Montre la valeur courante d'un valuateur FLTK.

## Description

FLvalue montre la valeur courante d'un valuateur dans un champ texte.

## Syntaxe

    ihandle FLvalue "label", iwidth, iheight, ix, iy

## Initialisation

ihandle -- un identifiant (un nombre entier) qui référence de manière univoque le valuateur correspondant. Il peut être utilisé comme argument idisp d'un valuateur.

« label » -- une chaîne entre guillemets contenant un texte fourni par l'utilisateur placé à côté du widget.

iwidth -- largeur du widget.

iheight -- hauteur du widget.

ix -- position horizontale du coin supérieur gauche du valuateur, relative au coin supérieur gauche de la fenêtre correspondante (exprimée en pixels).

iy -- position verticale du coin supérieur gauche du valuateur, relative au coin supérieur gauche de la fenêtre correspondante (exprimée en pixels).

## Exécution

FLvalue montre la valeur courante d'un valuateur dans un champ texte. Il retourne ihandle qui peut être utilisé comme argument idisp d'un valuateur (voir la section Valuateurs FLTK). De cette manière, les valeurs de ce valuateur seront montrées dynamiquement dans un champ texte.

| Note
Noter que FLvalue n'est pas un valuateur et que sa valeur ne peut pas être modifiée. La valeur d'un widget FLvalue ne doit être fixée que par d'autres widgets, et PAS depuis FLsetVal ou FLsetVal_i car cela pourrait planter Csound.

## Exemples

Voici un exemple de l'opcode FLvalue. Il utilise le fichier FLvalue.csd.

Exemple 341. Exemple de l'opcode FLvalue.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    ; Audio out   Audio in    No messages
    -odac           -iadc     -d     ;;;RT audio I/O
    ; For Non-realtime ouput leave only the line below:
    ; -o FLvalue.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    ; Using the opcode flvalue to display the output of a slider
    sr = 44100
    kr = 441
    ksmps = 100
    nchnls = 1

    FLpanel "Value Display Box", 900, 200, 50, 50
        ; Width of the value display box in pixels
        iwidth = 50
        ; Height of the value display box in pixels
        iheight = 20
        ; Distance of the left edge of the value display
        ; box from the left edge of the panel
        ix = 65
        ; Distance of the top edge of the value display
        ; box from the top edge of the panel
        iy = 55

        idisp FLvalue "Hertz", iwidth, iheight, ix, iy
        gkfreq, ihandle FLslider "Frequency", 200, 5000, -1, 5, idisp, 750, 30, 125, 50
        FLsetVal_i 500, ihandle
    ; End of panel contents
    FLpanelEnd
    ; Run the widget thread!
    FLrun

    instr 1
        iamp = 15000
        ifn = 1
        asig oscili iamp, gkfreq, ifn
        out asig
    endin

    </CsInstruments>
    <CsScore>

    ; Function table that defines a single cycle
    ; of a sine wave.
    f 1 0 1024 10 1

    ; Instrument 1 will play a note for 1 hour.
    i 1 0 3600
    e

    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

FLbox, FLbutBank, FLbutton, FLprintk, FLprintk2

## Crédits

Auteur : Gabriel Maldonado

Nouveau dans la version 4.22

Exemple écrit par Iain McCurdy, édité par Kevin Conder.

Précédent | Niveau supérieur | Suivant
fluidSetInterpMethod | Sommaire | FLvkeybd