platerev
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## platerev

platerev — Modélise la réverbération d'une plaque métallique.

## Description

Modélise la réverbération d'une plaque métallique rectangulaire avec des caractéristiques physiques ajustables lorsqu'elle est excitée par des signaux audios.

## Syntaxe

    a1[, a2, ...] platerev itabexcite. itabouts, kbndry, iaspect, istiff, idecay, iloss, aexcite1[, aexcite2, ...]

## Initialisation

itabexcite -- numéro d'une table contenant un triplet pour chaque signal d'excitation (fréquence, rayon, phase initiale en radians). Le rayon doit être inférieur à 1. Ceux-ci contrôlent l'endroit où l'excitation se produit. Les valeurs dans la table pour la fréquence et le rayon peuvent être changée durant l'exécution avec le risque de clics si les changements sont trop importants.

itabouts -- numéro d'une table contenant un triplet pour chaque signal de sortie (fréquence, rayon, phase initiale en radians). Voir la description de itabexcite.

kbndry -- conditions aux limites de la plaque ; 0 = libre, 1 = fixée, 2 = pivotante. Les autres valeurs sont indéfinies. Ce paramètre peut être changé au taux-k, au risque de l'apparition de clics.

iaspect -- rapport d'aspect de la plaque qui doit être inférieur ou égal à 1.

istiff -- paramètre de raideur de la plaque (fixé autour de 1 ou à une valeur inférieure pour une réverbération de plaque).

idecay -- temps de décroissance à 30 db.

iloss -- paramètre de perte des hautes fréquences (une valeur d'environ 0.001 est recommandée).

## Exécution

Une plaque métallique est excitée par un signal stéréo et la réverbération résultante est prélevée.

aexciten -- signaux d'excitation à injecter dans la plaque.

## Exemples

Voici un exemple de l'opcode platerev. Il utilise le fichier plate.csd.

Exemple 753. Exemple de l'opcode platerev.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    ;-odac    ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
     -o plate.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>
    ; Note: this example is heavy on CPU
    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1

    ab    diskin2  "beats.wav", 1
    al,ar platerev 1, 2, p4, 0.73, 1.0, 5.0, 0.001, ab,ab
          outs      al*.25,ar*.25

    endin
    </CsInstruments>
    <CsScore>
    f1 0 8 -2   0.3   0.3875    0.39274  0.32   0.85714 0.78548
    f2 0 8 -2   0.2   0.666667  1.57097  0.24   0.75    0.78548
    i1 0 4 1
    i1 + 4 2
    e

    </CsScore>
    </CsoundSynthesizer>

## Crédits

Auteur : Stefan Bilbao
Université d'Edimbourg, UK
Auteur : John ffitch
Université de Bath, Codemist Ltd.
Bath, UK

Nouveau dans la version 5.17.12 de Csound.

Précédent | Niveau supérieur | Suivant
planet | Sommaire | plltrack