ntom
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## ntom

ntom — Conversion d'un nom de note en numéro de note MIDI.

## Description

Convertit un nom de note en numéro de note MIDI. Les noms de notes peuvent comprendre des microtons ou une déviation en cents.

## Syntaxe

    kmidi ntom Snote

    imidi ntom Snote

## Exécution

Snote -- Nom de note.

kmidi -- Numéro de note MIDI.

Exemple de noms de note :

            midi    nom de note
            -------------------
            60      4C
            60.4    4C+40
            60.5    4C+
            60.9    4Db-10
            61      4C#
            61.5    4D-

| Note
4C est le do central du piano.

## Exemples

Voici un exemple de l'opcode ntom. Il utilise le fichier mton-ntom.csd.

Exemple 656. Exemple de l'opcode ntom.

    <CsoundSynthesizer>
    <CsOptions>
    --nosound
    </CsOptions>
    <CsInstruments>

    instr 1
        S4 mton ntom("7D+63")
        puts S4, 1

        S1  mton 60
        printf_i "midi 60 = %s \n", 1, S1

        S2 mton ftom(442)
        printf_i "442 Hz = %s \n", 1, S2

        S3 = mton(48.25)
        printf_i "midi 48.25 = %s \n", 1, S3

        k1 = ntom("4C")
        printf_i "4C = midi %f \n", 1, k1

        i2  ntom "4E"
        printf_i "4E = %f \n", 1, i2

        S5 = mton(ntom("4G+"))
        printf_i "roundtrip 4G+: %s \n", 1, S5

        turnoff
    endin

    instr 2
        ; test i-time and k-time execution
        k1 = ntom("4Eb-31")
        printf "4Eb-31 = %f \n", 1, k1

        i0  ntom "4C+"
        printf_i "4C+ = %f \n", 1, i0

        i1 = ntom:i("4A")
        printf_i "4A = %f \n", 1, i1
        turnoff
    endin

    </CsInstruments>
    <CsScore>

    i 1 0 1
    i 2 0 1

    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

cpsmidinn, mtof, ftom, mton

## Crédits

Par : Eduardo Moguillansky 2017

Nouveau greffon dans la version 6.11

Précédent | Niveau supérieur | Suivant
ntof | Sommaire | nstrnum