cntCreate
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## cntCreate

cntCreate — Crée un objet compteur.

## Description

Opcode du greffon counter.

Crée un objet compteur.

## Syntaxe

    icnt cntCreate [imax, imin, inc]

## Initialisation

imax -- valeur maximale facultative pour le compteur, vaut 1 par défaut.

imin -- valeur minimale facultative pour le compteur, vaut 0 par défaut.

inc -- incrément facultatif pour de compteur, vaut 1 par défaut.

icnt -- un identifiant pour le compteur.

## Exécution

Crée un objet compteur qui boucle entre imin et imax par pas de inc. Lorsqu'il est utilisé sans argument, les valeurs par défaut créent une bascule.

## Examples

Voici un exemple de l'opcode cndCreate. Il utilise le fichier counter.csd.

Exemple 167. Exemple de l'opcode cndCreate.

Voir les sections Audio en temps réel et Options de la ligne de commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    -odac -Mhw:1,0,0
    </CsOptions>

    <CsInstruments>
     gicnt cntCreate 1     ; a toggle
     gicntNote cntCreate 1 ; ignore note-off message to turn MIDI notes into toggles

    instr 1

    kkey sensekey

    inote notnum

    if (kkey == 97) then
     k1 count gicnt
     if k1==0 then
      event "i", 2, 0, -1
     else
      event "d", 2, 0, -1
     endif
    endif

    print  inote
    if (inote == 60) then
     i2 count_i gicntNote
     print i2
     if i2==0 then
      event_i "i", 3, 0, -1
     else
      event_i "d", 3, 0, -1
     endif
    endif
    endin

    instr 2
    asig oscil 10000, 440
    out asig
    endin

    instr 3
    asig oscil 5000, 880
    out asig
    endin

    </CsInstruments>

    <CsScore>
    i1 0 z
    e

    </CsScore>

    </CsoundSynthesizer>

`

## Voir aussi

count count_i cntCycles cntRead cntReset cntState

## Crédits

Par : John ffitch juin 2020

Nouveau dans la version 6.15

Précédent | Niveau supérieur | Suivant
cntState | Sommaire | cntDelete