zamod
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## zamod

zamod — Module un signal de taux-a par un autre.

## Description

Module un signal de taux-a par un autre.

## Syntaxe

    ares zamod asig, kzamod

## Exécution

asig -- Le signal d'entrée

kzamod -- Contrôle quelle variable za sera utilisée pour la modulation. Une valeur positive indique une modulation additive, une valeur négative indique une modulation multiplicative. Une valeur de 0 ne fait aucun changement à asig.

zamod Module un signal de taux-a par un autre, qui provient d'une variable za. La position de la variable modulante est contrôlée par la variable de taux-i ou de taux-k kzamod. Ceci est la version de taux-a de zkmod.

## Exemples

Voici un exemple de l'opcode zamod. Il utilise le fichier zamod.csd.

Exemple 1230. Exemple de l'opcode zamod.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    ; Audio out   Audio in    No messages
    -odac           -iadc     -d     ;;;RT audio I/O
    ; For Non-realtime ouput leave only the line below:
    ; -o zamod.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    ; Initialize the global variables.
    sr = 44100
    kr = 4410
    ksmps = 10
    nchnls = 1

    ; Initialize the ZAK space.
    ; Create 2 a-rate variables and 2 k-rate variables.
    zakinit 2, 2

    ; Instrument #1 -- a simple waveform.
    instr 1
      ; Vary an a-rate signal linearly from 20,000 to 0.
      asig line 20000, p3, 0

      ; Send the signal to za variable #1.
      zaw asig, 1
    endin

    ; Instrument #2 -- generates audio output.
    instr 2
      ; Generate a simple sine wave.
      asin oscil 1, 440, 1

      ; Modify the sine wave, multiply its amplitude by
      ; za variable #1.
      a1 zamod asin, -1

      ; Generate the audio output.
      out a1

      ; Clear the za variables, prepare them for
      ; another pass.
      zacl 0, 2
    endin

    </CsInstruments>
    <CsScore>

    ; Table #1, a sine wave.
    f 1 0 16384 10 1

    ; Play Instrument #1 for 2 seconds.
    i 1 0 2
    ; Play Instrument #2 for 2 seconds.
    i 2 0 2
    e

    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

zacl, ziw, ziwm

## Crédits

Auteur : Robin Whittle
Australie
Mai 1997

Nouveau dans la version 3.45

Exemple écrit par Kevin Conder.

Précédent | Niveau supérieur | Suivant
zakinit | Sommaire | zar