Instruction q
Précédent | Instructions de partition et routines GEN | Suivant

## Instruction q

q — Cette instruction peut être utilisée pour rendre un instrument silencieux.

## Description

Cette instruction peut être utilisée pour rendre un instrument silencieux.

## Syntaxe

    q p1  p2  p3

## Exécution

p1 -- Numéro de l'instrument à rendre muet/sonore.

p2 -- Date d'action en pulsations.

p3 -- Détermine si l'instrument doit être rendu silencieux ou sonore. La valeur 0 signifie silencieux, toute autre valeur signifie sonore.

Noter que ceci n'affecte pas les instruments déjà actifs à la date p2. Ça bloque toute tentative d'en démarrer un après cette date.

## Exemples

Voici un exemple de l'instruction q. Il utilise le fichier q.csd.

Exemple 1256. Exemple de l'instruction q.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if RT audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o q.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1

    aenv expseg .01, p3*0.25, 1, p3*0.75, 0.01
    asig poscil3 .8*aenv, p4, 1
         outs asig, asig

    endin
    </CsInstruments>
    <CsScore>
    f 1 0 16384 10 1;sine wave
    s
    q 1 6 0		;mute at 6 seconds in this section
    i 1 0 2 110
    i 1 3 2 220
    i 1 6 2 440
    i 1 9 2 880

    s
    q 1 6 1		;unmute again at 6 seconds in this section
    i 1 0 2 110
    i 1 3 2 220
    i 1 6 2 440
    i 1 9 2 880
    e
    </CsScore>
    </CsoundSynthesizer>

Précédent | Niveau supérieur | Suivant
Instruction n | Sommaire | Instruction r (instruction répéter)