sfload
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## sfload

sfload — Charge en mémoire un fichier d'échantillons SoundFont2 (SF2) en entier.

## Description

Charge en mémoire un fichier d'échantillons SoundFont2 (SF2) en entier. Ces opcodes permettent la gestion de la structure d'échantillon des fichiers SF2. Afin de comprendre l'utilisation de ces opcodes, il faut connaître le format SF2 dont on peut trouver une brève description dans la section format de fichier SoundFont2.

sfload doit être placé dans le section d'en-tête d'un orchestre de Csound.

## Syntaxe

    ir sfload "filename"

## Initialisation

ir -- valeur de retour à utiliser par les autres opcodes SF2. Pour sfload, ir est le ifilhandle.

« filename » -- nom du fichier SF2, avec son chemin complet. C'est une chaîne de caractères entre guillements avec le « / » comme séparateur de répertoires (ceci s'applique également à DOS et à Windows, où l'utilisation d'un antislash générera une erreur), ou bien un entier qui a été lié à une chaîne de caractères par strset.

## Exécution

sfload charge en mémoire un fichier SF2 en entier. Il retourne un identificateur de fichier à utiliser par les autres opcodes. On peut placer plusieurs instances de sfload dans la section d'en-tête d'un orchestre, ce qui permet d'utiliser plusieurs fichiers SF2 dans un seul orchestre.

Si l'on tente de charger deux fois le même fichier, le fichier déjà chargé est utilisé accompagné d'un message d'avertissement (à partir de la version 6.14).

Ces opcodes ne supportent que la structure d'échantillon des fichiers SF2. La structure de modulateur du format SoundFormat2 n'est pas supportée dans Csound. Tout traitement ou modulation des données échantillonnées est à la charge de l'utilisateur de Csound, ce qui permet de s'affranchir de toutes les restrictions imposées par le standard SF2.

Il faut noter qu'avant la version 5.12 on pouvait charger au maximum dix soundfonts. Cette restriction est maintenant levée.

## Exemples

Voici un exemple de l'opcode sfload. Il utilise le fichier sfload.csd.

Exemple 953. Exemple de l'opcode sfload.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac ;;;realtime audio out, virtual midi in
    ;-iadc    ;;;uncomment -iadc if RT audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o sfload.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    ; By  Menno Knevel - 2020

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    ; load in two soundfonts
    isf	sfload	"sf_GMbank.sf2"
    ir	sfload	"07AcousticGuitar.sf2"
    	sfplist isf
    	sfplist ir
    ; first sf_GMbank.sf2 is loaded and assigned to start at 0 and counting up to 328
    ; as there are 329 presets in sf_GMbank.sf2 (0-328).
    ; then 07AcousticGuitar.sf2 is loaded and assigned to replace the 10th preset of already loaded sf_GMbank.sf2
    	sfpassign	0, isf
    	sfpassign	10, ir

    instr 1 ; play French Horn, bank 0 program 60

    inum	=	p4
    ivel	=	p5
    kamp	linsegr	1, 1, 1, .1, 0
    kamp	= kamp/500000						;scale amplitude
    kfreq	=	1						;do not change freq from sf
    a1,a2	sfplay3	ivel, inum, kamp*ivel, kfreq, 60			;preset index = 60
    	outs	a1, a2
    endin

    instr 2	; play Guitar replaces sf_GMbank.sf2 at preset index 10

    inum	=	p4
    ivel	=	p5
    kamp	linsegr	1, 1, 1, .1, 0
    kamp	= kamp/700000						;scale amplitude
    kfreq	=	1						;do not change freq from sf
    a1,a2	sfplay3	ivel, inum, kamp*ivel, kfreq, 10			;preset index = 10
    	outs	a1, a2
    endin

    </CsInstruments>
    <CsScore>

    i1 0 1 60 100
    i1 + 1 62 <
    i1 + 1 65 <
    i1 + 1 69 10

    i2 5 1 60 100
    i2 + 1 62 <
    i2 7 1 65 <
    i2 7 1 69 10

    e
    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

sfilist, sfinstr, sfinstrm, sfpassign, sfplay, sfplaym, sfplist, sfpreset

## Crédits

Auteur : Gabriel Maldonado
Italie
Mai 2000

Nouveau dans la version 4.07 de Csound

Précédent | Niveau supérieur | Suivant
sfinstrm | Sommaire | sflooper