delay1
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## delay1

delay1 — Retarde un signal d'entrée d'un échantillon.

## Description

Retarde un signal d'entrée d'un échantillon.

## Syntaxe

    ares delay1 asig [, iskip]

## Initialisation

iskip (facultatif, 0 par défaut) -- disposition initiale de l'espace des données de la boucle de retard (voir reson). La valeur par défaut est 0.

## Exécution

delay1 est une forme spéciale de délai qui sert à retarder le signal audio asig d'un seul échantillon. Il est ainsi fonctionnellement équivalent à l'opcode delay mais il est plus efficace à la fois en temps et en espace. Cette unité est particulièrement utile dans le fabrication de filtres non récursifs généralisés.

## Exemples

Voici un exemple des opcodes delay et delay1. Il utilise le fichier delay1.csd.

Exemple 212. Exemple de l'opcode delay1.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; For Non-realtime ouput leave only the line below:
    -o delay.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    ; Initialize the global variables.
    sr = 44100
    kr = 4410
    ksmps = 10
    nchnls = 2
    0dbfs  = 1

    instr 1
      ; Make white noise.
      a0    random -1, 1

      ; Simple Lowpass filter
      a1    delay1  a0
      aout  =       (a0+0.99*a1)/2

      ; output white and filtered
            outs    aout, a0
    endin

    </CsInstruments>
    <CsScore>
    ; Play Instrument #1.
    i 1 0.0 3

    e

    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

delay, delayr, delayw

## Crédits

Auteur : Barry Vercoe

Exemple écrit par John ffitch.

Précédent | Niveau supérieur | Suivant
delay | Sommaire | delayk