initc7
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## initc7

initc7 — Initialise le contrôleur utilisé pour créer une valeur MIDI sur 7 bit.

## Description

Initialise le contrôleur MIDI ictlno avec ivalue

## Syntaxe

    initc7 ichan, ictlno, ivalue

## Initialisation

ichan -- canal MIDI (1-16)

ictlno -- numéro du contrôleur (0-127)

ivalue -- valeur décimale (doit être entre 0 et 1)

## Exécution

initc7 peut être utilisé conjointement avec les opcodes midic7 et ctrl7 pour initialiser la première valeur du contrôleur. L'argument ivalue doit être un nombre entre 0 et 1. Une erreur aura lieu si ce n'est pas le cas. Utiliser cette formule afin d'ajuster ivalue selon les limites min et max de l'intervalle de midic7 et de ctrl7:

ivalue = (valeur_initiale - min) / (max - min)

## Exemples

Voici un exemple de l'opcode initc7. Il utilise le fichier initc7.csd.

Exemple 462. Exemple de l'opcode initc7.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac   -M0  ;;;realtime audio I/O with MIDI in
    ;-iadc    ;;;uncomment -iadc if RT audio input is needed too
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs = 1

    instr 1	; expects MIDI controller input on channel 1
    ; run and move your midi controller to see result

    imax = 1
    imin = 0
    ichan = 1
    ictlno = 7

    	initc7	1, 7, 1			; start at max. volume
    kamp	ctrl7	ichan, ictlno, imin, imax	; controller 7
    	printk2	kamp
    asig	oscil	kamp, 220, 1
    	outs	asig, asig

    endin

    </CsInstruments>
    <CsScore>
    f 1 0 4096 10 1

    i1 0 20

    e
    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

ctrl7, ctrl14, ctrl21, ctrlinit, initc14, initc21, midic7, midic14, midic21

## Crédits

Auteur : Gabriel Maldonado
Italie

Nouveau dans la version 3.47 de Csound

Merci à Rasmus Ekman pour avoir indiqué les bons intervalles pour le canal MIDI et le numéro de contrôleur.

Précédent | Niveau supérieur | Suivant
initc21 | Sommaire | inleta