faustgen
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## faustgen

faustgen — Compile, instancie et exécute un programme Faust compilé.

## Description

Opcode du greffon faustcsound.

faustgen invoque le compilateur à la volée, instancie et exécute un programme Faust.

## Syntaxe

    ihandle, a1 [,a2, ...] faustgen SCode [,ain1, ...]

## Initialisation

« Scode » -- une chaîne de caractères contenant un programme Faust.

« ihandle » -- une référence à l'instance DSP de Faust que l'on peut utiliser pour accéder à ses contrôles avec faustctl.

## Exécution

« ain1, ... » -- signaux d'entrée

« a1, ... » -- signaux de sortie

## Exemples

Voici un exemple de l'opcode faustgen. Il utilise le fichier faustgen.csd.

Exemple 287. Exemple de l'opcode faustgen.

Voir les sections Audio en temps réel et Options de la ligne de commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    -odac
    </CsOptions>
    <CsInstruments>
    instr 1
     ain1 oscili 0dbfs/2, 440
     idsp,a1 faustgen {{
       gain = hslider("vol",1,0,1,0.01);
       process = (_ * gain);
      }}, ain1
     k1 line  0, p3, 1
     faustctl idsp, "vol", k1
       out a1
    endin
    </CsInstruments>
    <CsScore>
    i1 0 10
    </CsScore>
    </CsoundSynthesizer>

## Crédits

Auteur : Victor Lazzarini, 2013

Précédent | Niveau supérieur | Suivant
faustdsp | Sommaire | faustplay