gogobel
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## gogobel

gogobel — La sortie audio est un son tel que celui produit lorque l'on frappe une cloche à vache.

## Description

La sortie audio est un son tel que celui produit lorque l'on frappe une cloche à vache. Il s'agit d'un modèle physique développé par Perry Cook, mais recodé pour Csound.

## Syntaxe

    ares gogobel kamp, kfreq, ihrd, ipos, imp, kvibf, kvamp, ivfn

## Initialisation

ihrd -- la dureté de la baguette utilisée pour la frappe. On utilise un intervalle allant de 0 à 1. 0,5 est une valeur adéquate.

ipos -- le point d'impact sur le bloc, compris entre 0 et 1.

imp -- une table des impulsions de la frappe. Le fichier marmstk1.wav contient une fonction adéquate créée à partir de mesures et l'on peut le charger dans une table GEN01. Il est aussi disponible à ftp://ftp.cs.bath.ac.uk/pub/dream/documentation/sounds/modelling/.

ivfn -- forme du vibrato, habituellement une table sinus, créée par une fonction.

## Exécution

Une note est jouée sur une instrument de type cloche à vache, avec les arguments suivants.

kamp -- Amplitude de la note.

kfreq -- Fréquence de la note.

kvibf -- Fréquence du vibrato en Hertz. L'intervalle conseillé va de de 0 à 12.

kvamp -- Amplitude du vibrato.

## Exemples

Voici un exemple de l'opcode gogobel. Il utilise les fichiers gogobel.csd et marmstk1.wav

Exemple 419. Exemple de l'opcode gogobel.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o gogobel.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1

       kfreq = 200
       ihrd = 0.5
       ipos = p4
       kvibf = 6.0
       kvamp = 0.3

    asig gogobel .9, kfreq, ihrd, ipos, 1, 6.0, 0.3, 2
         outs asig, asig
    endin
    </CsInstruments>
    <CsScore>
    ;audio file
    f 1 0 256 1 "marmstk1.wav" 0 0 0
    ;sine wave for the vibrato
    f 2 0 128 10 1

    i 1 0.5 0.5 0.01
    i 1 + 0.5 0.561
    i 1 + 0.5 0.9
    e
    </CsScore>
    </CsoundSynthesizer>

## Crédits

Auteur : John ffitch (d'après Perry Cook)
Université de Bath, Codemist Ltd.
Bath, UK

Nouveau dans la version 3.47 de Csound

Précédent | Niveau supérieur | Suivant
getseed | Sommaire | goto