delayw
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## delayw

delayw — Ecrit le signal audio dans une ligne à retard numérique.

## Description

Ecrit le signal audio dans une ligne à retard numérique.

## Syntaxe

    delayw asig

## Exécution

delayw écrit asig dans l'espace du délai établi par l'unité delayr précédente. Cette paire d'unités permet la formation de boucles de rétroaction modifiées, etc. Cependant, il y a une limite inférieure à idlt, qui doit valoir au moins une période de contrôle (ou 1/kr).

## Exemples

Voici un exemple de l'opcode delayw. Il utilise le fichier delayw.csd.

Exemple 215. Exemple de l'opcode delayw.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;RT audio out
    ;-iadc    ;;;uncomment -iadc if RT audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o delayw.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs = 1

    gasig  init 0
    gidel  = 1		;delay time in seconds

    instr 1

    ain  pluck .7, 440, 1000, 0, 1
         outs ain, ain

    vincr gasig, ain	;send to global delay
    endin

    instr 2

    ifeedback = p4

    abuf2	delayr	gidel
    adelL 	deltap	.4		;first tap (on left channel)
    adelM 	deltap	1		;second tap (on middle channel)
    	delayw	gasig + (adelL * ifeedback)

    abuf3	delayr	gidel
    kdel	line    1, p3, .01	;vary delay time
    adelR 	deltap  .65 * kdel	;one pitch changing tap (on the right chn.)
    	delayw	gasig + (adelR * ifeedback)
    ;make a mix of all deayed signals
    	outs	adelL + adelM, adelR + adelM

    clear	gasig
    endin

    </CsInstruments>
    <CsScore>

    i 1 0 1
    i 1 3 1
    i 2 0 3  0	;no feedback
    i 2 3 8 .8	;lots of feedback
    e
    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

delay, delay1, delayr

Précédent | Niveau supérieur | Suivant
delayr | Sommaire | deltap