schedwhen
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## schedwhen

schedwhen — Ajoute un nouvel évènement de partition.

## Description

Ajoute un nouvel évènement de partition.

## Syntaxe

    schedwhen ktrigger, kinsnum, kwhen, kdur [, ip4] [, ip5] [...]

    schedwhen ktrigger, "insname", kwhen, kdur [, ip4] [, ip5] [...]

## Initialisation

ip4, ip5, ... -- Equivalent à p4, p5, etc., dans une instruction i de partition.

## Exécution

kinsnum -- numéro d'un instrument. Equivalent à p1 dans une instruction i de partition.

« insname » -- une chaîne de caractères (entre guillemets) représentant un instrument nommé.

ktrigger -- valeur de déclenchement pour le nouvel évènement.

kwhen -- date de début du nouvel évènement. Equivalent à p2 dans une instruction i de partition.

kdur -- durée de l'évènement. Equivalent à p3 dans une instruction i de partition.

schedwhen ajoute un nouvel évènement de partition. L'évènement n'est programmé que lorsque la valeur de taux-k ktrigger prend une valeur non nulle. Les arguments, options incluses, sont les mêmes que dans une partition. Le temps kwhen (p2) est mesuré à partir de l'instant de cet évènement.

Si la durée est nulle ou négative, le nouvel évènement est de type MIDI, et il hérite le sous-évènement de relachement (release) de l'instruction schedwhen.

| Note
Noter que l'opcode schedwhen ne peut pas accepter de p-champs chaîne de caractère. Si vous devez passer des chaînes de caractère à l'instanciation d'un instrument, utilisez l'opcode scoreline ou scoreline_i.

## Exemples

Voici une exemple de l'opcode schedwhen. Il utilise le fichier schedwhen.csd.

Exemple 924. Exemple de l'opcode schedwhen.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o schedwhen.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1

    kmtr metro 100				;produce 100 triggers per second
         schedwhen kmtr, 2, 1, .3		;but schedwhen plays instr. 2 only once

    endin

    instr 2

    aenv linseg 0, p3*.1, 1, p3*.3, 1, p3*.6, 0 ;envelope
    a1   poscil .3*aenv, 1000, 1
         outs a1, a1

    endin
    </CsInstruments>
    <CsScore>
    f 1 0 16384 10 1	;sine

    i 1 0 3
    i 1 3 5
    e
    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

event, event_i, schedule, schedkwhen, schedkwhennamed, scoreline, scoreline_i

## Crédits

Auteur : John ffitch
Université de Bath/Codemist Ltd.
Bath, UK
Novembre 1998

Nouveau dans la version 3.491 de Csound

Basé sur un travail de Gabriel Maldonado

Précédent | Niveau supérieur | Suivant
schedulek | Sommaire | scoreline