ampdbfs
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## ampdbfs

ampdbfs — Retourne l'amplitude équivalente (sur une échelle d'entiers signés sur 16 bit) à la valeur x de l'amplitude maximale (dB FS).

## Description

Retourne l'amplitude équivalente à la valeur x de l'amplitude maximale (dB FS). Les valeurs logarithmiques de l'échelle en décibels sont converties en valeurs linéaires entières sur 16 bit allant de -32768 à +32767.

## Syntaxe

    ampdbfs(x)  (pas de restriction de taux)

## Exemples

Voici un exemple de l'opcode ampdbfs. Il utilise le fichier ampdbfs.csd.

Exemple 53. Exemple de l'opcode ampdbfs.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;RT audio out
    ;-iadc    ;;;uncomment -iadc if RT audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o ampdbfs.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2

    instr 1

    idb  =  p4
    iamp =  ampdbfs(idb)
    asig	oscil iamp, 220, 1
    	print iamp
    	outs  asig, asig
    endin

    </CsInstruments>
    <CsScore>
    ;sine wave.
    f 1 0 16384 10 1

    i 1 0 1 -1
    i 1 + 1 -5
    i 1 + 1 -6
    i 1 + 1 -20
    e

    </CsScore>
    </CsoundSynthesizer>

Sa sortie contiendra cette ligne :

    instr 1:  iamp = 29204.511
    instr 1:  iamp = 18426.801
    instr 1:  iamp = 16422.904
    instr 1:  iamp = 3276.800

## Voir aussi

ampdb, dbamp, dbfsamp, 0dbfs

Nouveau dans la version 4.10 de Csound.

Précédent | Niveau supérieur | Suivant
ampdb | Sommaire | ampmidi