tlineto
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## tlineto

tlineto — Génère des glissandi déclenchés par un signal de contrôle.

## Description

Génère des glissandi déclenchés par un signal de contrôle.

## Syntaxe

    kres tlineto ksig, ktime, ktrig

## Exécution

kres -- Signal de sortie.

ksig -- Signal d'entrée.

ktime -- Durée du glissando en secondes.

ktrig -- Signal de déclenchement.

tlineto est semblable à lineto mais on peut l'appliquer à n'importe quelle sorte de signal (pas seulement des signaux en escalier) sans produire de discontinuités. La dernière valeur de chaque segment est échantillonnée et bloquée à partir du signal d'entrée chaque fois que la valeur de ktrig est différente de zéro. Normalement le signal ktrig est constitué d'une suite de zéros (voir l'opcode trigger).

L'effet de glissando est assez différent de celui de port. En effet, ici, les lignes sont droites. De plus, le contexte d'utilisation est différent.

## Exemples

Voici un exemple de l'opcode tlineto. Il utilise le fichier tlineto.csd.

Exemple 1094. Exemple de l'opcode tlineto.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac      ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o tlineto.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    giSine ftgen 0, 0, 2^10, 10, 1

    instr 1

    kmtr lfo 1, .5, 1			;produce trigger signal
    ktr  trigger kmtr, .5, 0		;with triangle wave

    ktime = p4
    kfreq randh 1000, 3, .2, 0, 500		;generate random values
    kfreq tlineto kfreq, ktime, ktr		;different glissando times
    aout  poscil .4, kfreq, giSine
          outs aout, aout

    endin
    </CsInstruments>
    <CsScore>

    i 1 0 10 .2	;short glissando
    i 1 11 10 .8	;longer glissande
    e
    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

lineto

## Crédits

Auteur : Gabriel Maldonado

Nouveau dans la version 4.13

Précédent | Niveau supérieur | Suivant
tival | Sommaire | tone