fluidInfo
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## fluidInfo

fluidInfo — Retrouve l'information de programme du SoundFont courant.

## Syntaxe

    SPrograms[] fluidInfo ienginenum

## Description

Opcode du greffon fluidOpcodes.

Parcourt le SoundFont courant pour en extraire l'information de programme. Cette information est retournée dans un tableau de chaînes de caractères.

## Initialisation

SPrograms[] -- Tableau de chaînes de caractères contenant l'information de programme.

ienginenum -- numéro du moteur affecté par fluidEngine.

## Exécution

fluidInfo ne fonctionne que durant l'initialisation.

## Exemples

Voici un exemple de l'opcode fluidInfo. Il utilise le fichier fluidInfo.csd and sf_GMbank.sf2.

Exemple 336. Exemple de l'opcode fluidInfo.

Voir les sections Audio en temps réel et Options de la ligne de commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac    ;;;realtime audio out and realtime midi in
    </CsOptions>
    <CsInstruments>
    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs = 1

    giengine fluidEngine
    isfnum	 fluidLoad "sf_GMbank.sf2", giengine, 1

    instr 1
    iCnt init 0
    SSoundFontPrograms[] fluidInfo giengine
    iNumberOfPrograms lenarray SSoundFontPrograms

    until iCnt>=iNumberOfPrograms do
    	printf_i "%s\n", 1, SSoundFontPrograms[iCnt]
    	iCnt = iCnt+1
    od
    endin

    </CsInstruments>
    <CsScore>
    i1 0 1
    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

fluidEngine, fluidLoad, fluidNote

Plus d'information sur soundfonts dans les Floss Manuals : https://flossmanual.csound.com/midi/reading-midi-files

D'autres informations sur soundfonts dans Wikipedia : http://en.wikipedia.org/wiki/Soundfont

## Crédits

Rory Walsh, basé sur l'opcode fluidLoad de Steven Yi.

Nouveau dans Csound 6.12

Précédent | Niveau supérieur | Suivant
fluidEngine | Sommaire | fluidLoad