STKBlowBotl
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## STKBlowBotl

STKBlowBotl — STKBlowBotl utilise un résonateur de Helmholtz (filtre biquadratique) avec une excitation par jet polynomial.

## Description

Opcode du greffon stkopd.

Cet opcode implémente un résonateur de Helmholtz (filtre biquadratique) avec une excitation par jet polynomial (à la Cook).

## Syntaxe

    asignal STKBlowBotl ifrequency, iamplitude, [knoise, kv1[, klfo, kv2[, klfodepth, kv3[, kvol, kv4]]]]

## Initialisation

ifrequency -- Fréquence de la note jouée, en Hz.

iamplitude -- Amplitude de la note jouée (entre 0 et 1).

## Exécution

knoise -- contrôleur 4, gain du bruit. kv1 compris entre 0 et 127.

klfo -- contrôleur 11, vitesse de l'oscillateur basse-fréquence. kv2 compris entre 0 et 127.

klfodepth -- contrôleurr 1, intensité de l'oscillateur basse-fréquence. kv3 compris entre 0 et 127.

kvol -- contrôleur 128, volume. kv4 compris entre 0 et 127.

| Notes
Le code pour cet opcode vient directement de la classe BlowBotl du Synthesis Toolkit en C++ par Perry R. Cook et Gary P. Scavone. On peut en savoir plus sur les classes STK ici : https://ccrma.stanford.edu/software/stk/classes.html kc1, kv1, kc2, kv2, kc3, kv3, kc4, kv4, kc5, kv5, kc6, kv6, kc7, kv7, kc8, kv8 -- Jusqu'à 8 paires de contrôle facultatives au taux-k pour les opcodes STK. Chaque paire de contrôle est constituée d'un numéro de contrôleur (kc) suivi d'une valeur de contrôleur (kv). Le numéro de contrôleur ainsi que la valeur associée sont des variables de taux-k. Cependant, durant l'exécution, les numéros de contrôleur sont habituellement constants tandis que les valeurs correspondantes peuvent changer à tout moment. L'ordre des paires de contrôle est arbitraire mais elles doivent apparaître après iamplitude. Il n'est pas non plus nécessaire d'utiliser toutes les paires.

## Exemples

Voici un exemple de l'opcode STKBlowBotl. Il utilise le fichier STKBlowBotl.csd.

Exemple 1000. Exemple de l'opcode STKBlowBotl.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if RT audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o STKBlowBotl.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1

    ipch	= p4
    kv1	line p5, p3, p6					;gain of noise
    kv4	line	100, p3, 70				;volume

    asig	STKBlowBotl cpspch(ipch), 1, 4, kv1, 11, 10, 1, 50, 128, kv4
    asig	=	asig * .5				;too loud
    	outs	asig, asig
    endin

    </CsInstruments>
    <CsScore>

    i 1 0 2 9.00 20 100
    i 1 + 5 8.03 120 0
    e
    </CsScore>
    </CsoundSynthesizer>

## Crédits

Auteur : Michael Gogins (d'après Perry Cook)
Irreducible Productions
New York, NY

Nouveau dans la version 5.11 de Csound.

Précédent | Niveau supérieur | Suivant
STKBeeThree | Sommaire | STKBlowHole