kgoto
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## kgoto

kgoto — Transfère le contrôle lors des phases d'exécution.

## Description

Transfère le contrôle sans condition vers l'instruction étiquetée par label, lors des phases d'exécution seulement.

## Syntaxe

    kgoto label

où label se trouve dans le même bloc d'instrument et n'est pas une expression.

## Exemples

Voici un exemple de l'opcode kgoto. Il utilise le fichier kgoto.csd.

Exemple 486. Exemple de l'opcode kgoto.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    ; Audio out   Audio in
    -odac           -iadc    ;;;RT audio I/O
    ; For Non-realtime ouput leave only the line below:
    ; -o kgoto.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    ; Initialize the global variables.
    sr = 44100
    kr = 4410
    ksmps = 10
    nchnls = 1

    ; Instrument #1.
    instr 1
      ; Change kval linearly from 0 to 2 over
      ; the period set by the third p-field.
      kval line 0, p3, 2

      ; If kval is greater than or equal to 1 then play the high note.
      ; If not then play the low note.
      if (kval >= 1) kgoto highnote
        kgoto lownote

    highnote:
      kfreq = 880
      goto playit

    lownote:
      kfreq = 440
      goto playit

    playit:
      ; Print the values of kval and kfreq.
      printks "kval = %f, kfreq = %f\\n", 1, kval, kfreq

      a1 oscil 10000, kfreq, 1
      out a1
    endin

    </CsInstruments>
    <CsScore>

    ; Table #1: a simple sine wave.
    f 1 0 32768 10 1

    ; Play Instrument #1 for two seconds.
    i 1 0 2
    e

    </CsScore>
    </CsoundSynthesizer>

Sa sortie contiendra des lignes comme celles-ci :

    kval = 0.000000, kfreq = 440.000000
    kval = 0.999732, kfreq = 440.000000
    kval = 1.999639, kfreq = 880.000000

## Voir aussi

cggoto, cigoto, ckgoto, goto, if, igoto, tigoto, timout

## Crédits

Exemple écrit by Kevin Conder.

Précédent | Niveau supérieur | Suivant
K35_lpf | Sommaire | kr