filelen
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## filelen

filelen — Retourne la longueur d'un fichier son.

## Description

Retourne la longueur d'un fichier son.

## Syntaxe

    ir filelen ifilcod, [iallowraw]

## Initialisation

ifilcod -- fichier son à interroger

iallowraw -- (facultatif) permet des fichiers son bruts (vaut 1 par défaut)

## Exécution

filelen retourne la longueur du fichier son ifilcod en secondes. filelen peut retourner la longueur des fichiers de type convolve et PVOC si le paramètre iallowraw est différent de zéro (il est non nul par défaut).

## Exemples

Voici un exemple de l'opcode filelen. Il utilise les fichiers filelen.csd, fox.wav et kickroll.wav.

Exemple 292. Exemple de l'opcode filelen.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    ;-odac     ;;;realtime audio out
    -iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ;-o filelen.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs = 1

    instr 1 ; choose between mono or stereo file

    ilen   filelen p4	;calculate length of soundfile
    print  ilen
    ichn filenchnls  p4	;check number of channels
    ;print  ichn

    if (ichn == 1) then
    ;mono signal
    asig diskin2 p4, 1
         outs    asig, asig

    else
    ;stereo signal
    aL, aR diskin2 p4, .5, 0, 1
           outs    aL, aR

    endif

    endin
    </CsInstruments>
    <CsScore>

    i 1 0 3 "fox.wav"	;mono signal
    i 1 5 2 "kickroll.wav"	;stereo signal

    e
    </CsScore>
    </CsoundSynthesizer>

Le fichier audio mono « fox.wav » dure 2.8 secondes et le fichier stéréo « kickroll.wav » dure 0.9 secondes. Ainsi la sortie de filelen contiendra une ligne pour le fichier mono et pour le fichier stéréo comme ceci :

    instr 1:  ilen = 2.757
    instr 1:  ilen = 0.857

## Voir aussi

filebit, filenchnls, filepeak, filesr

## Crédits

Auteur : Matt Ingalls
Juillet 1999

Nouveau dans la version 3.57 de Csound

Précédent | Niveau supérieur | Suivant
filebit | Sommaire | filenchnls