expsegb
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## expsegb

expsegb — Trace une suite de segments d'exponentielle entre les points absolus spécifiés.

## Description

Trace une suite de segments d'exponentielle entre les points absolus spécifiés.

## Syntaxe

    ares expsegb ia, itim1, ib [, itim2] [, ic] [...]

    kres expsegb ia, itim1, ib [, itim2] [, ic] [...]

## Initialisation

ia -- valeur initiale. Zéro est interdit pour les exponentielles.

ib, ic, etc. -- valeurs à tim1 secondes, etc. Pour les exponentielles doivent être différentes de zéro et de même signe que ia.

itim1 -- date en secondes de la fin du premier segment.

itim2, itim3, etc. -- date en secondes de la fin des segments suivants.

## Exécution

Ces unités génèrent des signaux de contrôle ou audio dont les valeurs passent par 2 ou plus points spécifiés. La dernière valeur tim peut égaler ou non la durée d'exécution de l'instrument : avec une exécution plus courte, la courbe sera tronquée alors qu'avec une exécution plus longue, la dernière valeur sera répétée jusqu'à la fin de la note.

Noter que l'opcode expsegb n'opère pas correctement au taux audio s'il y a des segments inférieurs à une période-k. Dans ce cas, essayez plutôt l'opcode expsegba opcode instead.

## Exemples

Voici un exemple de l'opcode expsegb. Il utilise le fichier expsegb.csd.

Exemple 280. Exemple de l'opcode expsegb.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    ; Audio out   Audio in
    -odac           -iadc    ;;;RT audio I/O
    ; For Non-realtime ouput leave only the line below:
    ; -o expseg.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    ; Initialize the global variables.
    sr = 44100
    kr = 4410
    ksmps = 10
    nchnls = 1

    ; Instrument #1.
    instr 1
      ; p4 = frequency in pitch-class notation.
      kcps = cpspch(p4)

      ; Create an amplitude envelope.
      kenv expsegb 0.01, p3*0.25, 1, p3, 0.01
      kamp = kenv * 30000

      a1 oscil kamp, kcps, 1
      out a1
    endin

    </CsInstruments>
    <CsScore>

    ; Table #1, a sine wave.
    f 1 0 16384 10 1

    ; Play Instrument #1 for a half-second, p4=8.00
    i 1 0 0.5 8.00
    ; Play Instrument #1 for a half-second, p4=8.01
    i 1 1 0.5 8.01
    ; Play Instrument #1 for a half-second, p4=8.02
    i 1 2 0.5 8.02
    ; Play Instrument #1 for a half-second, p4=8.03
    i 1 3 0.5 8.03
    e

    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

expon, expseg, expsega, expsegr, line, linseg, linsegr transeg

## Crédits

Auteur : Victor Lazzarini
Juin 2011

Nouveau dans la version 5.14

Précédent | Niveau supérieur | Suivant
expsega | Sommaire | expsegba