mpulse
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## mpulse

mpulse — Génère un train d'impulsions.

## Description

Génère un train d'impulsions d'amplitude kamp séparées par kintvl secondes (ou échantillons si kintvl est négatif). La première impulsion est générée après un délai de ioffset secondes.

## Syntaxe

    ares mpulse kamp, kintvl [, ioffset]

## Initialisation

ioffset (facultatif, par défaut 0) -- le délai avant la première impulsion. S'il est négatif, la valeur est interprétée comme le nombre d'échantillons, sinon il représente des secondes. La valeur par défaut est zéro.

## Exécution

kamp -- amplitude des impulsions générées

kintvl -- intervalle de temps en secondes (ou en nombre d'échantillons si kintvl est négatif) jusqu'à la prochaine impulsion.

Après le délai initial, une impulsion d'amplitude kamp est générée comme échantillon unique. Immédiatement après la génération de l'impulsion, la date de la suivante est déterminée par la valeur de kintvl à ce moment précis. Cela signifie que tous les changements de kintvl entre les impulsions sont ignorés. Si kintvl est nul, il y a un temps d'attente infini jusqu'à la prochaine impulsion. Si kintvl est négatif, l'intervalle est compté en nombre d'échantillons plutôt qu'en secondes.

## Exemples

Voici un exemple de l'opcode mpulse. Il utilise le fichier mpulse.csd.

Exemple 627. Exemple de l'opcode mpulse.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    ; Audio out   Audio in    No messages
    -odac           -iadc     -d     ;;;RT audio I/O
    ; For Non-realtime ouput leave only the line below:
    ; -o mpulse.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    ; Initialize the global variables.
    sr = 44100
    kr = 4410
    ksmps = 10
    nchnls = 1

    gkfreq init 0.1

    instr 1
      kamp = 10000

      a1 mpulse kamp, gkfreq
      out a1
    endin

    instr 2
    ; Assign the value of p4 to gkfreq
    gkfreq init p4
    endin
    </CsInstruments>
    <CsScore>

    ; Play Instrument #1 for one second.
    i 1 0 11
    i 2 2 1    0.05
    i 2 4 1    0.01
    i 2 6 1    0.005
    ; only last notes are audible
    i 2 8 1    0.003
    i 2 10 1    0.002

    e

    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

On peut trouver un autre exemple montrant comment utiliser mpulse ici : mode.

## Crédits

Ecrit par John ffitch.

Nouveau dans la version 4.08

Précédent | Niveau supérieur | Suivant
mp3scal | Sommaire | mrtmsg