strrindex
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## strrindex

strrindex — Retourne la position de la dernière occurence d'une chaîne de caractères dans une autre chaîne.

## Description

Retourne la position de la dernière occurence de S2 dans S1, ou -1 si elle n'est pas trouvée. Si S2est vide, la longueur de S1 est retournée. strrindex ne s'exécute que pendant l'initialisation.

## Syntaxe

    ipos strrindex S1, S2

## Exemples

Voici un exemple de l'opcode strrindex. Il utilise le fichier strrindex.csd.

Exemple 1035. Exemple de l'opcode strrindex.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -n    ;;;no sound output
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    </CsOptions>
    <CsInstruments>
    ;example by Joachim Heintz

      opcode FilNam, S, S
    ;returns the name of a file path
    Spath  xin
    ipos   strrindex Spath, "/"	;look for the rightmost '/'
    Snam   strsub    Spath, ipos+1	;extract the substring
           xout      Snam
      endop

    instr name
           prints    "Printing name:\n"
    Snam   FilNam    "/my/dir/my/file.WAV"
           puts      Snam, 1

    endin
    </CsInstruments>
    <CsScore>
    i "name" 0 0
    e
    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

strrindexk

## Crédits

Auteur : Istvan Varga
2006

Nouveau dans la version 5.02

Précédent | Niveau supérieur | Suivant
strlowerk | Sommaire | strrindexk