oscilikts
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## oscilikts

oscilikts — Un oscillateur avec interpolation linéaire et statut de synchronisation qui permet de changer le numéro de table au taux-k.

## Description

oscilikts est pareil à oscilikt. Sauf qu'il a une entrée de synchronisation que l'on peut utiliser pour réinitialiser l'oscillateur à une valeur de phase de taux-k. Il est plus lent que oscilikt et que osciliktp.

## Syntaxe

    ares oscilikts xamp, xcps, kfn, async, kphs [, istor]

## Initialisation

istor (facultatif, par défaut 0) -- ignorer l'initialisation.

## Exécution

xamp -- amplitude.

kcps, xcps -- fréquence en Hz. Zéro et les valeurs négatives sont permis. Cependant, la valeur absolue doit être inférieure à sr (et il est recommandé qu'elle soit inférieure à sr/2).

kfn -- numéro de la table de fonction. Peut varier au taux de contrôle (utile pour le « morphing » de formes d'onde, ou pour choisir parmi un ensemble de tables à bande de fréquence limitée générées par GEN30).

async -- n'importe quelle valeur positive réinitialise la valeur de la phase de oscilikts à kphs. Zero ou des valeurs négatives n'ont aucun effet.

kphs -- fixe la phase, initialement et lorsqu'elle est réinitialisée avec async.

## Exemples

Voici un exemple de l'opcode oscilikts. Il utilise le fichier oscilikts.csd.

Exemple 677. Exemple de l'opcode oscilikts.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    ; Audio out   Audio in    No messages
    -odac           -iadc     -d     ;;;RT audio I/O
    ; For Non-realtime ouput leave only the line below:
    ; -o oscilikts.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    ; Initialize the global variables.
    sr = 44100
    kr = 4410
    ksmps = 10
    nchnls = 1

    ; Instrument #1: oscilikts example.
    instr 1
      ; Frequency envelope.
      kfrq expon 400, p3, 1200
      ; Phase.
      kphs line 0.1, p3, 0.9

      ; Sync 1
      atmp1 phasor 100
      ; Sync 2
      atmp2 phasor 150
      async diff 1 - (atmp1 + atmp2)

      a1 oscilikts 14000, kfrq, 1, async, 0
      a2 oscilikts 14000, kfrq, 1, async, -kphs

      out a1 - a2
    endin

    </CsInstruments>
    <CsScore>

    ; Table #1: Sawtooth wave
    f 1 0 3 -2 1 0 -1

    ; Play Instrument #1 for four seconds.
    i 1 0 4
    e

    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

oscilikt et osciliktp.

## Crédits

Auteur : Istvan Varga

Nouveau dans la version 4.22

Précédent | Niveau supérieur | Suivant
osciliktp | Sommaire | osciln