STKMoog
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## STKMoog

STKMoog — STKMoog produit des sons de filtre à balayage comme sur un moog.

## Description

Opcode du greffon stkopd.

STKMoog produit des sons de filtre à balayage comme sur un moog, en utilisant une onde pour l'attaque, une onde pour la boucle et une enveloppe ADSR, et en ajoutant deux filtres à balayage de formant.

## Syntaxe

    asignal STKMoog ifrequency, iamplitude, [kq, kv1[, krate, kv2[, klfo, kv3[, klfodepth, kv4[, kvol, kv5]]]]]

## Initialisation

ifrequency -- Fréquence de la note jouée, en Hz.

iamplitude -- Amplitude de la note jouée (entre 0 et 1).

## Exécution

kq -- contrôleur 2, Q du filtre. kv1 compris entre 0 et 127.

krate -- contrôleur 4, taux de balayage du filtre. kv2 compris entre 0 et 127.

klfo -- contrôleur 11, vitesse de l'oscillateur basse-fréquence. kv3 compris entre 0 et 127.

klfodepth -- contrôleur 1, intensité de l'oscillateur basse-fréquence. kv4 compris entre 0 et 127.

kvol -- contrôleur 128, volume. kv5 compris entre 0 et 127.

| Notes
Le code pour cet opcode vient directement de la classe Moog du Synthesis Toolkit en C++ par Perry R. Cook et Gary P. Scavone. On peut en savoir plus sur les classes STK ici : https://ccrma.stanford.edu/software/stk/classes.html kc1, kv1, kc2, kv2, kc3, kv3, kc4, kv4, kc5, kv5, kc6, kv6, kc7, kv7, kc8, kv8 -- Jusqu'à 8 paires de contrôle facultatives au taux-k pour les opcodes STK. Chaque paire de contrôle est constituée d'un numéro de contrôleur (kc) suivi d'une valeur de contrôleur (kv). Le numéro de contrôleur ainsi que la valeur associée sont des variables de taux-k. Cependant, durant l'exécution, les numéros de contrôleur sont habituellement constants tandis que les valeurs correspondantes peuvent changer à tout moment. L'ordre des paires de contrôle est arbitraire mais elles doivent apparaître après iamplitude. Il n'est pas non plus nécessaire d'utiliser toutes les paires.

## Exemples

Voici un exemple de l'opcode STKMoog. Il utilise le fichier STKMoog.csd.

Exemple 1011. Exemple de l'opcode STKMoog.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if RT audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o STKMoog.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1

    ifrq	=	p4
    kv1	line	p5, p3, p6				;filter Q

    asig	STKMoog cpspch(ifrq), 1, 2,kv1, 4, 120, 11, 40, 1, 1, 128, 120
    asig	=	asig * .3				;too loud
    	outs asig, asig
    endin

    </CsInstruments>
    <CsScore>

    i 1 0 .5 6.00 100 0
    i 1 + .  5.05 10 127
    i 1 + .  7.06 100 0
    i 1 + 3  7.00 10 10
    e
    </CsScore>
    </CsoundSynthesizer>

## Crédits

Auteur : Michael Gogins (d'après Perry Cook)
Irreducible Productions
New York, NY

Nouveau dans la version 5.11 de Csound.

Précédent | Niveau supérieur | Suivant
STKModalBar | Sommaire | STKPercFlut