Instruction s
Précédent | Instructions de partition et routines GEN | Suivant

## Instruction s

s — Marque le fin d'une section.

## Description

L'instruction s marque le fin d'une section.

## Syntaxe

    s [temps]

## Initialisation

Le premier p-champ temps est facultatif et s'il est présent, il détermine la date de fin (en pulsations) de la section. Cette date doit être après la fin du dernier évènement de la section sinon elle n'aura pas d'effet. On peut l'utiliser pour créer une pause avant le début de la section suivante ou pour permettre aux instruments "actifs en permanence" tels que les effets de jouer seuls pendant une certaine durée.

## Exécution

Le tri des instructions i, des instructions f et des instructions a par date d'action est effectué section par section.

La modification temporelle par l'instruction t est faite section par section.

Toute les dates d'action à l'intérieur d'une section sont relatives à son début. Une instruction de section établit un nouveau temps relatif de 0, mais n'a pas d'autres effets de réinitialisation (par exemple les tables de fonction mémorisées sont préservées par delà les limites de section).

On considère qu'une section est complète lorsque toutes les dates d'action et toutes les durées finies ont été satisfaites. (C'est-à-dire que la "longueur" d'une section est déterminée par la dernière action apparue ou par l'arrêt du système). Une section peut être allongée par l'utilisation d'une instruction f0 ou en fournissant la valeur de p1facultative à l'instruction s.

A la fin d'une section, le système provoque automatiquement le nettoyage des instruments inactifs et de leur espace de données.

| Note
Puisque les instructions de partition sont traitées section par section, la quantité de mémoire requise dépend du nombre maximum d'instructions de partition dans une section. L'allocation de mémoire est dynamique, et l'utilisateur sera informé chaque fois que des blocs de mémoire supplémentaires sont demandés pendant le traitement de la partition. Pour la dernière section d'une partition, l'instruction s est facultative ; l'instruction e peut être utilisée à la place.

## Exemples

Voici un exemple de l'instruction s. Il utilise le fichier s.csd.

Exemple 1258. Exemple de l'instruction s.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if RT audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o s.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1

    aenv expseg .01, p3*0.25, 1, p3*0.75, 0.01
    asig poscil3 .8*aenv, p4, 1
         outs asig, asig

    endin
    </CsInstruments>
    <CsScore>
    f 1 0 16384 10 1;sine wave

    s		;first section
    i 1 0 2 110
    i 1 3 2 220
    i 1 6 2 440
    i 1 9 2 880

    s		;second section
    i 1 0 2 880
    i 1 3 2 440
    i 1 6 2 220
    i 1 9 2 110
    e
    </CsScore>
    </CsoundSynthesizer>

Précédent | Niveau supérieur | Suivant
Instruction r (instruction répéter) | Sommaire | Instruction t (instruction de tempo)