max_k
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## max_k

max_k — Maximum (ou minimum) local d'un signal entrant de taux-a.

## Description

max_k retourne le maximum (ou le minimum) local du signal entrant asig, mesuré dans l'intervalle de temps entre deux passages à true de ktrig.

## Syntaxe

    knumkout max_k asig, ktrig, itype

## Initialisation

itype - détermine le comportement de max_k (voir ci-dessous)

## Exécution

asig -- signal entrée

ktrig -- signal de déclenchement

max_k retourne le maximum (ou le minimum) local du signal entrant asig, mesuré dans l'intervalle de temps entre deux passages à true de ktrig. itype détermine le comportement de max_k :

1 - maximum absolu (les valeurs négatives sont changées en valeurs positives avant l'évaluation)

2 - maximum courant

3 - minimum courant

4 - calcule la valeur moyenne de asig dans l'intervalle de temps depuis le dernier déclenchement.

Cet opcode peut être utile dans plusieurs situations, par exemple pour implémenter un vu-mètre.

## Exemples

Voici un exemple de l'opcode max_k. Il utilise le fichier max_k.csd.

Exemple 567. Exemple de l'opcode max_k.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac  ;-Ma   ;;;realtime audio out and midi in (on all inputs)
    ;-iadc    ;;;uncomment -iadc if RT audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o max_k.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    ; by Stefano Cucchi 2020

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1

    anoise noise 0.1, 0.1 ; generate some noise
    arandom randomi 400, 12000, 4 ; generate random numbers from 400 to 1200

    ktrig metro 3 ; trigger signal

    kmin max_k arandom, ktrig, 3 ; minumum value
    kmax max_k arandom, ktrig, 2 ; maximum value

    printk 0.2, kmin
    printk 0.2, kmax

    anoisehp butterhp anoise, kmin ; hipass filter at kmin frequency
    anoiselp butterlp anoise, kmax*0.5 ; lopass filter at kmin/2 frequency

    acomp oscil 0.1, 440 ; comparator signal for consistent amplitude

    anoisehp balance anoisehp, acomp ; adjusting the volume
    anoiselp balance anoiselp, acomp ; adjusting the volume

    outs anoisehp, anoiselp

    endin

    </CsInstruments>
    <CsScore>

    i1 0 10
    e
    </CsScore>
    </CsoundSynthesizer>

## Crédits

Written by Gabriel Maldonado.

Nouveau dans Csound 5. (N'était disponible auparavant que dans CsoundAV)

Modifié pour être conforme à la documentation dans la version 5.15.

Précédent | Niveau supérieur | Suivant
maxalloc | Sommaire | maxarray