tonex
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## tonex

tonex — Emule une série de filtres utilisant l'opcode tone.

## Description

tonex est équivalent à un filtre constitué de plusieurs couches de filtres tone avec les mêmes arguments, connectés en série. L'utilisation d'une série d'un nombre important de filtres permet une pente de coupure plus raide. Ils sont plus rapides que l'équivalent obtenu à partir du même nombre d'instances d'opcodes classiques dans un orchestre Csound, car il n'y aura qu'un cycle d'initialisation et une seule passe de k cycles de contrôle à la fois et la boucle audio sera entièrement contenue dans la mémoire cache du processeur.

## Syntaxe

    ares tonex  asig, khp [, inumlayer] [, iskip]

    ares tonex  asig, ahp [, inumlayer] [, iskip]

## Initialisation

inumlayer (facultatif) -- nombre d'éléments dans la série de filtre. La valeur par défaut est 4.

iskip (facultatif, par défaut 0) -- état initial de l'espace de données interne. Comme le filtrage comprend une boucle de rétroaction sur la sortie précédente, l'état initial de l'espace de stockage utilisé est significatif. Une valeur nulle provoquera l'effacement de cet espace ; une valeur non nulle autorisera la persistance de l'information précédente. La valeur par défaut est 0.

## Exécution

asig -- signal d'entrée

khp/ahp -- le point à mi-puissance de la courbe de réponse. La mi-puissance est définie par puissance maximale / racine de 2.

## Exemples

Voici un exemple de l'opcode tonex. Il utilise le fichier tonex.csd.

Exemple 1097. Exemple de l'opcode tonex.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o tonex.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    0dbfs  = 1
    nchnls = 2

    instr 1

    asig diskin2 "beats.wav", 1
         outs asig, asig
    endin

    instr 2

    kton line 10000, p3, 0		;all the way down to 0 Hz
    asig diskin2 "beats.wav", 1
    asig tonex asig, kton, 8	;8 filters
         outs asig, asig
    endin
    </CsInstruments>
    <CsScore>

    i 1 0 2
    i 2 3 2

    e
    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

atonex, resonx

## Crédits

Auteur : Gabriel Maldonado (adapté par John ffitch)
Italie

Nouveau dans la version 3.49 de Csound

Paramètres de taux audio introduits dans la version 6.02

Octobre 2013.

Précédent | Niveau supérieur | Suivant
tonek | Sommaire | trandom