phasor
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## phasor

phasor — Produit une valeur de phase mobile normalisée.

## Description

Produit une valeur de phase mobile normalisée.

## Syntaxe

    ares phasor xcps [, iphs]

    kres phasor kcps [, iphs]

## Initialisation

iphs (facultatif) -- phase initiale, exprimée comme une fraction d'une période (0 à 1). Avec une valeur négative, l'initialisation de la phase sera ignorée. La valeur par défaut est zéro.

## Exécution

Une phase interne est augmentée successivement selon la fréquence de kcps ou de xcps pour produire une valeur de phase mobile, normalisée pour se trouver dans l'intervalle 0 <= phs < 1.

Lorsqu'elle est utilisée comme indice dans une table, cette phase (multipliée par la longueur de la table de fonction) permettra de l'utiliser comme un oscillateur.

Noter que phasor est une sorte d'intégrateur, accumulant les incréments de phase qui représent les réglages de fréquence.

## Exemples

Voici un exemple de l'opcode phasor. Il utilise le fichier phasor.csd.

Exemple 743. Exemple de l'opcode phasor.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if real audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o phasor.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1

    ifn = 1			;read table 1 with our index
    ixmode = 1
    kndx phasor p4
    kfrq table kndx, ifn, ixmode
    asig poscil .6, kfrq, 2	;re-synthesize with sine
         outs asig, asig

    endin
    </CsInstruments>
    <CsScore>
    f 1 0 1025 -7 200 1024 2000 ;a line from 200 to 2,000
    f 2 0 16384 10 1;sine wave

    i 1 0 1 1	;once per second
    i 1 2 2 .5	;once per 2 seconds
    i 1 5 1 2	;twice per second
    e
    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

Les opcodes d'Accès aux Tables comme : table, tablei, table3 et tab.

Aussi : phasorbnk.

Précédent | Niveau supérieur | Suivant
phaser2 | Sommaire | phasorbnk