nchnls_i
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## nchnls_i

nchnls_i — Fixe le nombre de canaux de l'entrée audio.

## Description

Ces instructions sont des affectations de valeurs globales réalisées au début d'un orchestre, avant que tout bloc d'instrument ne soit défini. Leur fonction est de fixer certaines variables dont le nom est un mot réservé et qui sont nécessaires à l'exécution. Une fois fixés, ces mots réservés peuvent être utilisés dans des expressions n'importe où dans l'orchestre.

## Syntaxe

    nchnls_i = iarg

## Initialisation

nchnls_i = (facultatif) -- fixe le nombre de canaux de l'entrée audio à iarg. (1 = mono, 2 = stéréo, 4 = quadriphonique.) La valeur par défaut est celle de nchnls.

De plus, toute variable globale peut être initialisée par une instruction de la période d'initialisation n'importe où avant la première instruction instr. Toutes les affectations ci-dessus sont exécutées dans l'instrument 0 (passe-i seulement) au début de l'exécution réelle.

## Exemples

Voici un exemple de l'opcode nchnls_i. Il utilise le fichier nchnls_i.csd.

Exemple 642. Exemple de l'opcode nchnls_i.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac  -idac ;;;realtime audio I/O
    ; For Non-realtime ouput leave only the line below:
    ; nchnls_i.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr   = 44100
    ksmps   = 32
    nchnls   = 2	;2 channels out
    0dbfs    = 1
    nchnls_i = 4	;4 channels in

    instr 1 ;4 channels in, two channels out

    ain1, ain2, ain3, ain4 inq		;grab your mics and sing

    adel   linseg 0, p3*.5, 0.02, p3*.5, 0	  ;max delay time = 20ms
    adel2  linseg 0.02, p3*.5, 0, p3*.5, 0.02 ;max delay time = 20ms
    aoutl  flanger ain1, adel, .7
    aoutr  flanger ain2, adel*2, .8
    aoutla flanger ain3, adel2, .9
    aoutra flanger ain4, adel2*2, .5
    ;write to quad file, 16 bits with header
           fout "in_4.wav", 14, aoutl, aoutr, aoutla, aoutra
           outs (aoutl+aoutla)*.5, (aoutr+aoutra)*.5 ;stereo out

    endin
    </CsInstruments>
    <CsScore>

    i 1 0 10
    e
    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

kr, ksmps, nchnls, sr

Précédent | Niveau supérieur | Suivant
nchnls_hw | Sommaire | nestedap