duserrnd
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## duserrnd

duserrnd — Générateur de nombres aléatoires de distribution discrète définie par l'utilisateur.

## Description

Générateur de nombres aléatoires de distribution discrète définie par l'utilisateur.

## Syntaxe

    aout duserrnd ktableNum

    iout duserrnd itableNum

    kout duserrnd ktableNum

## Initialisation

itableNum -- numéro d'une table contenant la fonction de la distribution aléatoire. Cette table est générée par l'utilisateur. Voir GEN40, GEN41 et GEN42. La longueur de la table peut être différente d'une puissance de 2.

## Exécution

ktableNum -- numéro d'une table contenant la fonction de la distribution aléatoire. Cette table est générée par l'utilisateur. Voir GEN40, GEN41 et GEN42. La longueur de la table peut être différente d'une puissance de 2.

duserrnd (Discrete USER-defined-distribution RaNDom generator) génère des nombres aléatoires selon une distribution aléatoire discrète créée par l'utilisateur. L'utilisateur peut créer l'histogramme de la distribution discrète au moyen de GEN41. Afin de créer cette table, on doit définir une quantité arbitraire de couples de nombres, le premier nombre de chaque paire représentant une valeur et le second représentant sa probabilité (voir GEN41 pour plus de détails).

Lorsqu'on l'utilise comme une fonction, le taux de génération dépend du type du taux de la variable d'entrée XtableNum. Dans ce cas, on peut l'insérer dans n'importe quelle formule. Le numéro de table peut varier au taux-k, ce qui permet de changer l'histogramme de la distribution durant l'exécution d'une note. duserrnd est destiné à être utilisé pour la génération de musique algorithmique.

On peut aussi utiliser duserrnd pour générer des valeurs suivant un ensemble d'intervalles de probabilités au moyen de fonctions de distribution générées par GEN42 (voir GEN42 pour plus de détails). Dans ce cas, si l'on veut simuler des intervalles continus, la longueur de la table XtableNum doit être raisonnablement grande car duserrnd ne fait pas d'interpolation entre les éléments de la table.

Pour un tutoriel sur les histogrammes et les fonctions de distribution aléatoires consulter :

- D. Lorrain. "A panoply of stochastic cannons". In C. Roads, ed. 1989. Music machine. Cambridge, Massachusetts: MIT press, pp. 351 - 379.

## Exemples

Voici un exemple de l'opcode duserrnd. Il utilise le fichier duserrnd.csd.

Exemple 254. Exemple de l'opcode duserrnd.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if RT audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o duserrnd.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1

    k1   duserrnd 1
         printk 0, k1
    asig poscil .5, 220*k1, 2	;multiply frequency with random value
         outs asig, asig

    endin
    </CsInstruments>
    <CsScore>
    f1 0 -20 -41  2 .1 8 .9	;choose 2 at 10% probability, and 8 at 90%

    f2 0 8192 10 1

    i1 0 2
    e
    </CsScore>
    </CsoundSynthesizer>

Sa sortie contiendra des lignes comme celles-ci :

    i   1 time     0.00067:     8.00000
    i   1 time     0.00133:     8.00000
    i   1 time     0.00200:     8.00000
    i   1 time     0.00267:     8.00000
    i   1 time     0.00333:     2.00000
    i   1 time     0.00400:     8.00000
    i   1 time     0.00533:     8.00000
    i   1 time     0.00600:     8.00000
    ..........

## Voir aussi

cuserrnd, urd

## Crédits

Auteur : Gabriel Maldonado

Nouveau dans la version 4.16

Précédent | Niveau supérieur | Suivant
dumpk4 | Sommaire | dust