readk2
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## readk2

readk2 — Lit périodiquement les valeurs de deux signaux de contrôle de l'orchestre depuis un fichier externe.

## Description

Lit périodiquement les valeurs de deux signaux de contrôle de l'orchestre depuis un fichier externe.

## Syntaxe

    kr1, kr2 readk2 ifilname, iformat, iprd

## Initialisation

ifilname -- un entier N indiquant un fichier nommé "readk.N" ou une chaîne de caractères (entre guillemets, espaces autorisés) contenant le nom du fichier externe. Si c'est une chaîne de caractères, elle peut être un nom de chemin complet avec un répertoire spécifié ou bien un simple nom de fichier. Dans ce dernier cas, le fichier est d'abord cherché dans le répertoire courant, puis dans SSDIR et finalement dans SFDIR.

iformat -- spécifie le format des données d'entrée :

- 1 = entiers signés sur 8 bit (char)

- 4 = entiers courts sur 16 bit

- 5 = entiers longs sur 32 bit

- 6 = flottants sur 32 bit

- 7 = entiers longs en ASCII (plein texte)

- 8 = flottants en ASCII (plein texte)

Noter que les formats A-law et U-law ne sont pas disponibles, et que tous les formats sauf les deux derniers sont binaires. Le fichier d'entrée doit être un fichier de données brutes sans en-tête.

iprd -- le taux (période) en secondes, arrondi à la période de contrôle de l'orchestre la plus proche, auquel les signaux sont lus depuis le fichier. Une valeur de 0 implique une période de contrôle (le minimum imposé), qui lira les nouvelles valeurs au taux de contrôle de l'orchestre. Avec des périodes plus longues, les mêmes valeurs seront répétées pendant plus d'une période de contrôle.

## Exécution

kr1, kr2 -- les signaux lus depuis ifilname.

Cette opcode permet de lire les valeurs de deux signaux générés au taux de contrôle depuis un fichier externe nommé. Le fichier ne doit pas contenir d'en-tête d'information mais il doit contenir une suite temporelle de valeurs de contrôle échantillonnées régulièrement. Pour les formats binaires, les échantillons individuels de chaque signal sont alternés. Pour les formats de texte ASCII, les valeurs doivent être séparées par au moins un espace. Les deux "canaux" d'une trame peuvent se trouver sur la même ligne ou être séparés par un caractère de retour à la ligne. Il peut y avoir n'importe quel nombre d'opcodes readk2 dans un instrument ou dans un orchestre et il peuvent lire à partir du même ou depuis différents fichiers.

## Exemples

Voici un exemple de l'opcode readk2. Il utilise le fichier readk2.csd.

Exemple 872. Exemple de l'opcode readk2.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac      ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o readk2.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    giSine ftgen 0, 0, 2^10, 10, 1

    instr 1 ;writes two control signals to a file
    kfreq     randh     100, 1, 2, 1, 500 ;generates one random number between 400 and 600 per second
    kdb       randh     12, 1, 2, 1, -12 ;amplitudes in dB between -24 and 0
              dumpk2    kfreq, kdb, "dumpk2.txt", 8, 1 ;writes the control signals
              prints    "WRITING:\n"
              printks   "kfreq = %f, kdb = %f\n", 1, kfreq, kdb  ;prints them
    endin

    instr 2 ;reads the file written by instr 1
    kf,kdb    readk2    "dumpk2.txt", 8, 1
              prints    "READING:\n"
              printks   "kfreq = %f, kdb = %f\n", 1, kf, kdb  ;prints again
    kdb       lineto    kdb, .1 ;smoothing amp transition
    aout      poscil    ampdb(kdb), kf, giSine
              outs      aout, aout
    endin

    </CsInstruments>
    <CsScore>
    i 1 0 5
    i 2 5 5
    e
    </CsScore>
    </CsoundSynthesizer>

Sa sortie comprendra des lignes comme celles-ci :

    kfreq = 429.202551, kdb = -20.495694
    kfreq = 429.202551, kdb = -20.495694
    kfreq = 407.275258, kdb = -23.123776
    kfreq = 475.264472, kdb = -9.300846
    kfreq = 569.979181, kdb = -7.315527
    kfreq = 440.103457, kdb = -0.058331

    kfreq = 429.202600, kdb = -20.495700
    kfreq = 429.202600, kdb = -20.495700
    kfreq = 407.275300, kdb = -23.123800
    kfreq = 475.264500, kdb = -9.300800
    kfreq = 569.979200, kdb = -7.315500
    kfreq = 440.103500, kdb = -0.058300

## Voir aussi

dumpk, dumpk2, dumpk3, dumpk4, readk, readk3, readk4

## Crédits

Par : John ffitch and Barry L. Vercoe

1999 ou avant

Précédent | Niveau supérieur | Suivant
readk | Sommaire | readk3