zkw
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## zkw

zkw — Ecrit dans une variable zk au taux-k sans mixage.

## Description

Ecrit dans une variable zk au taux-k sans mixage.

## Syntaxe

    zkw kval, kndx

## Exécution

kval -- valeur à écrire dans la position zk.

kndx -- pointe sur la position zk vers laquelle écrire.

zkw écrit kval dans la variable zk spécifiée par kndx.

## Exemples

Voici un exemple de l'opcode zkw. Il utilise le fichier zkw.csd.

Exemple 1247. Exemple de l'opcode zkw.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    ; Audio out   Audio in    No messages
    -odac           -iadc     -d     ;;;RT audio I/O
    ; For Non-realtime ouput leave only the line below:
    ; -o zkw.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    ; Initialize the global variables.
    sr = 44100
    kr = 4410
    ksmps = 10
    nchnls = 1

    ; Initialize the ZAK space.
    ; Create 1 a-rate variable and 1 k-rate variable.
    zakinit 1, 1

    ; Instrument #1 -- a simple waveform.
    instr 1
      ; Linearly vary a k-rate signal from 100 to 1,000.
      kline line 100, p3, 1000

      ; Add the linear signal to zk variable #1.
      zkw kline, 1
    endin

    ; Instrument #2 -- generates audio output.
    instr 2
      ; Read zk variable #1.
      kfreq zkr 1

      ; Use the value of zk variable #1 to vary
      ; the frequency of a sine waveform.
      a1 oscil 20000, kfreq, 1

      ; Generate the audio output.
      out a1

      ; Clear the zk variables, get them ready for
      ; another pass.
      zkcl 0, 1
    endin

    </CsInstruments>
    <CsScore>

    ; Table #1, a sine wave.
    f 1 0 16384 10 1

    ; Play Instrument #1 for two seconds.
    i 1 0 2
    ; Play Instrument #2 for two seconds.
    i 2 0 2
    e

    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

zaw, zawm, ziw, ziwm, zkr, zkwm

## Crédits

Auteur : Robin Whittle
Australie
Mai 1997

Nouveau dans la version 3.45

Exemple écrit par Kevin Conder.

Précédent | Niveau supérieur | Suivant
zkr | Sommaire | zkwm