GEN41
Précédent | Instructions de partition et routines GEN | Suivant

## GEN41

GEN41 — Génère une liste aléatoire de paires numériques.

## Description

Génère une fonction de distribution aléatoire discrète en donnant une liste de paires numériques.

## Syntaxe

    f # date taille -41 valeur1 prob1 valeur2 prob2 valeur3 prob3 ... valeurN probN

## Exécution

Le premier nombre de chaque paire est une valeur, et le second est la probabilité que cette valeur soit choisie par un algorithme aléatoire. Même si n'importe quel nombre peut être assigné à l'élément probabilité de chaque paire, il vaut mieux lui donner une valeur en pourcentage, afin de rendre les choses plus claires pour l'utilisateur.

Ce sous-programme est prévu pour être utilisé avec les opcodes duserrnd et urd (voir duserrnd pour plus d'information).

## Exemples

Voici un exemple de l'opcode GEN41. Il utilise le fichier gen41.csd.

Exemple 1299. Exemple de l'opcode GEN41.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if RT audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o GEN41.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1

    k1   duserrnd 1
         printk 0, k1
    asig poscil .5, 220*k1, 2
         outs asig, asig

    endin
    </CsInstruments>
    <CsScore>
    f1 0 -20 -41  2 .1 8 .9	;choose 2 at 10% probability, 8 at 90%

    f2 0 8192 10 1

    i1 0 2
    e
    </CsScore>
    </CsoundSynthesizer>

Sa sortie contiendra des lignes comme celles-ci :

    i   1 time     0.00067:     8.00000
    i   1 time     0.00133:     8.00000
    i   1 time     0.00200:     8.00000
    i   1 time     0.00267:     8.00000
    i   1 time     0.00333:     2.00000
    i   1 time     0.00400:     8.00000
    i   1 time     0.00533:     8.00000
    i   1 time     0.00600:     8.00000
    ..........

Voici le diagramme de la forme d'onde de la routine GEN41 utilisée dans l'exemple :

f 1 0 -20 -41 2 .1 8 .9

## Crédits

Auteur : Gabriel Maldonado

Précédent | Niveau supérieur | Suivant
GEN40 | Sommaire | GEN42