linseg
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## linseg

linseg — Trace une suite de segments de droite entre les points spécifiés.

## Description

Trace une suite de segments de droite entre les points spécifiés.

## Syntaxe

    ares linseg ia, idur1, ib [, idur2] [, ic] [...]

    kres linseg ia, idur1, ib [, idur2] [, ic] [...]

## Initialisation

ia -- valeur initiale.

ib, ic, etc. -- valeur après dur1 secondes, etc.

idur1 -- durée en secondes du premier segment. Avec une valeur nulle ou négative l'initialisation sera ignorée.

idur2, idur3, etc. -- durée en secondes des segments suivants. Une valeur nulle ou négative terminera la phase d'initialisation avec le point précédent, permettant au dernier segment défini de continuer durant toute l'exécution. La valeur par défaut est zéro.

## Exécution

Ces unités génèrent des signaux de contrôle ou audio dont les valeurs passent par 2 ou plus points spécifiés. La somme des valeurs dur peut égaler ou non la durée d'exécution de l'instrument : avec une exécution plus courte, la courbe sera tronquée alors qu'avec une exécution plus longue, la dernière valeur sera répétée jusqu'à la fin de la note.

## Exemples

Voici un exemple de l'opcode linseg. Il utilise le fichier linseg.csd.

Exemple 509. Exemple de l'opcode linseg.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac      ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ;-o linseg.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    giSine ftgen 0, 0, 2^10, 10, 1

    instr 1

    kcps = cpspch(p4)
    kenv linseg 0, 0.25, 1, 0.75, 0	; together = 1 sec
    asig poscil kenv, kcps, giSine
         outs asig, asig

    endin

    instr 2	; scaling to duration

    kcps = cpspch(p4)
    kenv linseg 0, p3*0.25, 1, p3*0.75, 0
    asig poscil kenv, kcps, giSine
         outs asig, asig

    endin

    instr 3	; with negative value

    kcps = cpspch(p4)
    aenv linseg 0, 0.1, 1, 0.5, -0.9, 0.4, 0
    asig poscil aenv, kcps, giSine
         outs asig, asig

    endin
    </CsInstruments>
    <CsScore>

    i 1 0 1   7.00	; = 1 sec, p3 fits exactly
    i 1 2 2   7.00	; = 2 sec, p3 truncated at 1 sec

    i 2 4 1   7.00	; scales to duration
    i 2 6 2   7.00	; of p3

    i 3 9 2   7.00
    e
    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

expon, expseg, expsegb, expsegr, cosseg, triglinseg, trigexpseg, line, linsegr, transeg, transegb

## Crédits

Auteur : Barry L. Vercoe

Précédent | Niveau supérieur | Suivant
linrand | Sommaire | linsegb