oscilikt
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## oscilikt

oscilikt — Un oscillateur avec interpolation linéaire qui permet de changer le numéro de table au taux-k.

## Description

oscilikt ressemble beaucoup à oscili, mais il permet de changer le numéro de table au taux-k. Il est légèrement plus lent que oscili (spécialement avec des taux de contrôle élevés), mais en contrepartie il est plus précis car il utilise un accumulateur de phase sur 31 bit au lieu de celui sur 24 bit utilisé par oscili.

## Syntaxe

    ares oscilikt xamp, xcps, kfn [, iphs] [, istor]

    kres oscilikt kamp, kcps, kfn [, iphs] [, istor]

## Initialisation

iphs (facultatif, par défaut 0) -- phase initiale dans l'intervalle 0 à 1. Les autres valeurs sont ramenées cycliquement dans l'intervalle autorisé.

istor (facultatif, par défaut 0) -- ignorer l'initialisation.

## Exécution

kamp, xamp -- amplitude.

kcps, xcps -- fréquence en Hz. Zéro et les valeurs négatives sont permis. Cependant, la valeur absolue doit être inférieure à sr (et il est recommandé qu'elle soit inférieure à sr/2).

kfn -- numéro de la table de fonction. Peut varier au taux de contrôle (utile pour le « morphing » de formes d'onde, ou pour choisir parmi un ensemble de tables à bande de fréquence limitée générées par GEN30).

## Exemples

Voici un exemple de l'opcode oscilikt. Il utilise le fichier oscilikt.csd.

Exemple 675. Exemple de l'opcode oscilikt.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    ; Audio out   Audio in    No messages
    -odac           -iadc     -d     ;;;RT audio I/O
    ; For Non-realtime ouput leave only the line below:
    ; -o oscilikt.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    ; Initialize the global variables.
    sr = 44100
    kr = 4410
    ksmps = 10
    nchnls = 1

    ; Instrument #1.
    instr 1
      ; Generate a uni-polar (0-1) square wave.
      kamp1 init 1
      kcps1 init 2
      itype = 3
      ksquare lfo kamp1, kcps1, itype

      ; Use the square wave to switch between Tables #1 and #2.
      kamp2 init 20000
      kcps2 init 220
      kfn = ksquare + 1

      a1 oscilikt kamp2, kcps2, kfn
      out a1
    endin

    </CsInstruments>
    <CsScore>

    ; Table #1, a sine waveform.
    f 1 0 4096 10 0 1
    ; Table #2: a sawtooth wave
    f 2 0 3 -2 1 0 -1

    ; Play Instrument #1 for two seconds.
    i 1 0 2

    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

osciliktp et oscilikts.

## Crédits

Auteur : Istvan Varga

Exemple écrit par Kevin Conder.

Nouveau dans la version 4.22

Précédent | Niveau supérieur | Suivant
oscili | Sommaire | osciliktp