nchnls
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## nchnls

nchnls — Fixe le nombre de canaux de la sortie audio.

## Description

Ces instructions sont des affectations de valeurs globales réalisées au début d'un orchestre, avant que tout bloc d'instrument ne soit défini. Leur fonction est de fixer certaines variables dont le nom est un mot réservé et qui sont nécessaires à l'exécution. Une fois fixés, ces mots réservés peuvent être utilisés dans des expressions n'importe où dans l'orchestre.

## Syntaxe

    nchnls = iarg

## Initialisation

nchnls = (facultatif) -- fixe le nombre de canaux de la sortie audio à iarg. (1 = mono, 2 = stéréo, 4 = quadriphonique.) La valeur par défaut est 1 (mono).

De plus, toute variable globale peut être initialisée par une instruction de la période d'initialisation n'importe où avant la première instruction instr. Toutes les affectations ci-dessus sont exécutées dans l'instrument 0 (passe-i seulement) au début de l'exécution réelle.

## Exemples

Voici un exemple de l'opcode nchnls. Il utilise le fichier nchnls.csd.

Exemple 641. Exemple de l'opcode nchnls.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac   -idac   ;;;realtime audio I/O
    ; For Non-realtime ouput leave only the line below:
    ; nchnls.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2				;two channels out
    0dbfs  = 1

    instr 1

    ain1, ainr ins				;grab your mic and sing
    adel  linseg 0, p3*.5, 0.02, p3*.5, 0	;max delay time = 20ms
    aoutl flanger ain1, adel, .7
    aoutr flanger ain1, adel*2, .8
          fout "in_s.wav", 14, aoutl, aoutr ;write to stereo file,
          outs aoutl, aoutr			;16 bits with header

    endin
    </CsInstruments>
    <CsScore>

    i 1 0 10
    e
    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

kr, ksmps, sr

Précédent | Niveau supérieur | Suivant
mxadsr | Sommaire | nchnls_hw