oscil
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## oscil

oscil — Un oscillateur simple.

## Description

oscil lit la table ifn séquentiellement et de manière répétive à la fréquence xcps. L'amplitude est pondérée par xamp.

## Syntaxe

    ares oscil xamp, xcps [, ifn, iphs]

    kres oscil kamp, kcps [, ifn, iphs]

## Initialisation

ifn (facultatif) -- numéro de la table de fonction. Nécessite un point de garde pour la lecture cyclique. Vaut -1 par défaut ce qui indique une onde sinus.

iphs (facultatif, par défaut 0) -- phase initiale de la lecture, exprimée comme une fraction d'une période (0 à 1). Avec une valeur négative l'initialisation de la phase sera ignorée. La valeur par défaut est 0.

## Exécution

kamp, xamp -- amplitude

kcps, xcps -- fréquence en cycles par seconde.

L'opcode oscil génère des signaux de contrôle (ou audio) constitués de la valeur de kamp (xamp) fois la valeur de la lecture au taux de contrôle (ou au taux audio) d'une table de fonction stockée. La phase interne est simultanément incrémentée selon la valeur en entrée de kcps ou de xcps.

La table ifn est parcourue par incrément modulo la longueur de la table et la valeur obtenue est multipliée par amp.

Si vous désirez changer la table de l'oscillateur avec un signal de taux-k, vous pouvez utiliser oscilikt.

## Exemples

Voici un exemple de l'opcode oscil. Il utilise le fichier oscil.csd.

Exemple 673. Exemple de l'opcode oscil.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o oscil.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1

    kamp = .6
    kcps = 440
    ifn  = p4

    asig oscil kamp, kcps, ifn
         outs asig,asig

    endin
    </CsInstruments>
    <CsScore>
    f1 0 16384 10 1                                          ; Sine
    f2 0 16384 10 1 0.5 0.3 0.25 0.2 0.167 0.14 0.125 .111   ; Sawtooth
    f3 0 16384 10 1 0   0.3 0    0.2 0     0.14 0     .111   ; Square
    f4 0 16384 10 1 1   1   1    0.7 0.5   0.3  0.1          ; Pulse

    i 1 0 2 1
    i 1 3 2 2
    i 1 6 2 3
    i 1 9 2 4

    e
    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

oscili, oscilikt, oscil3, poscil, poscil3

Précédent | Niveau supérieur | Suivant
oscil3 | Sommaire | oscili