FLtext
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## FLtext

FLtext — Un opcode de widget FLTK qui crée une boîte de texte.

## Description

FLtext permet à l'utilisateur de modifier la valeur d'un paramètre en la tapant directement dans un champ de texte.

## Syntaxe

    kout, ihandle FLtext "label", imin, imax, istep, itype, iwidth, \
          iheight, ix, iy

## Initialisation

ihandle -- un identifiant (un nombre entier) qui référence de manière univoque le widget correspondant. Il est utilisé par d'autres opcodes qui modifient les propriété du widget (voir Modifier l'Apparence des Widgets FLTK). Il est automatiquement retourné par FLtext et ne doit pas être fixé par l'étiquette de l'utilisateur. (L'étiquette de l'utilisateur est une chaîne entre guillemets contenant un texte fourni par l'utilisateur placé à côté du widget.)

« label » -- une chaîne entre guillemets contenant un texte fourni par l'utilisateur placé à côté du widget.

imin -- valeur minimale de l'intervalle de sortie.

imax -- valeur maximale de l'intervalle de sortie.

istep -- un nombre en virgule flottante indiquant le pas d'incrémentation du valuateur correspondant au glissé de souris. L'argument istep permet de ralentir le glissé autorisant une précision arbitraire.

itype -- un nombre entier indiquant l'apparence du valuateur.

L'argument itype accepte les valeurs suivantes :

- 1 - comportement normal

- 2 - l'opération du glissé de souris est suppimée, deux boutons fléchés la remplacent. Un clic de souris sur un de ces boutons peut accroitre/diminuer la valeur en sortie.

- 3 - l'édition du texte est supprimée, seul le glissé de souris modifie la valeur en sortie.

iwidth -- largeur du widget.

iheight -- hauteur du widget.

ix -- position horizontale du coin supérieur gauche du valuateur, relative au coin supérieur gauche de la fenêtre correspondante (exprimée en pixels).

iy -- position verticale du coin supérieur gauche du valuateur, relative au coin supérieur gauche de la fenêtre correspondante (exprimée en pixels).

## Exécution

kout -- valeur en sortie.

FLtext permet à l'utilisateur de modifier la valeur d'un paramètre en la tapant directement dans un champ de texte.

FLtext.

On peut aussi modifier sa valeur en le cliquant et en glissant la souris horizontalement. L'argument istep permet à l'utilisateur de fixer arbitrairement la réponse au glissé de souris.

## Exemples

Voici un exemple de l'opcode FLtext. Il utilise le fichier FLtext.csd.

Exemple 335. Exemple de l'opcode FLtext.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    ; Audio out   Audio in    No messages
    -odac           -iadc     -d     ;;;RT audio I/O
    ; For Non-realtime ouput leave only the line below:
    ; -o FLtext.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    ; A sine with oscillator with fltext box controlled
    ; frequency either click and drag or double click and
    ; type to change frequency value
    sr = 44100
    kr = 441
    ksmps = 100
    nchnls = 1

    FLpanel "Frequency Text Box", 270, 600, 50, 50
        ; Minimum value output by the text box
        imin = 200
        ; Maximum value output by the text box
        imax = 5000
        ; Step size
        istep = 1
        ; Text box graphic type
        itype = 1
        ; Width of the text box in pixels
        iwidth = 70
        ; Height of the text box in pixels
        iheight = 30
        ; Distance of the left edge of the text box
        ; from the left edge of the panel
        ix = 100
        ; Distance of the top edge of the text box
        ; from the top edge of the panel
        iy = 300

        gkfreq,ihandle FLtext "Enter the frequency", imin, imax, istep, itype, iwidth, iheight, ix, iy
    ; End of panel contents
    FLpanelEnd
    ; Run the widget thread!
    FLrun

    instr 1
        iamp = 15000
        ifn = 1
        asig oscili iamp, gkfreq, ifn
        out asig
    endin

    </CsInstruments>
    <CsScore>

    ; Function table that defines a single cycle
    ; of a sine wave.
    f 1 0 1024 10 1

    ; Instrument 1 will play a note for 1 hour.
    i 1 0 3600
    e

    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

FLcount, FLjoy, FLknob, FLroller, FLslider

## Crédits

Auteur : Gabriel Maldonado

Nouveau dans la version 4.22

Exemple écrit par Iain McCurdy, édité par Kevin Conder.

Précédent | Niveau supérieur | Suivant
FLtabs_end | Sommaire | FLupdate