ftprint
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## ftprint

ftprint — Affiche le contenu d'une table de fonction (pour débogage).

## Description

Opcode du greffon emugens.

Affiche le contenu d'une table de fonction (pour débogage). Fonctionne au taux-k, un déclencheur contrôlant quand afficher (utiliser ktrig=1, qui est la valeur par défaut, pour n'afficher qu'à l'initialisation).

## Syntaxe

    ftprint ifn [, ktrig, kstart, kend, kstep, inumcols ]

## Initialisation

ifn -- La table à afficher.

inumcols -- Le nombre d'éléments à afficher dans une colonne (10 par défaut).

## Exécution

ktrig -- La table sera affichée chaque fois que cette valeur change de 0 à un nombre positif. On peut l'utiliser avec metro pour afficher à intervalle donné. Une valeur de -1 indique d'afficher à chaque cycle-k (vaut 1 par défaut).

kstart -- La première position à afficher (0 par défaut).

kend -- La dernière postion à afficher (non incluse). (Par défaut = la longueur de la table).

kstep -- Le nombre d'élements à ignorer (1 par défaut)

## Exemples

Voici un exemple de l'opcode ftprint. Il utilise le fichier ftprint.csd.

Exemple 393. Exemple de l'opcode ftprint.

    <CsoundSynthesizer>
    <CsOptions>

    --nosound

    </CsOptions>
    <CsInstruments>

    ; This is the example file for ftprint

    /*

      ftprint

      Print the contents of an f-table
      (mostly for debuggin purposes)

      ftprint ifn, ktrig=1, kstart=0, kend=0, kstep=1, inumcols=0

      ifn: the table to print
      ktrig: table will be printed whenever this changes
             from non-positive to positive
      kstart: start index
      kend: end index (non inclusive)
      kstep: number of elements to skip
      inumcols: number of elements to print per line

      See also: printarray

    */

    instr 1
      ifn   ftgentmp 0, 0, -13, -2,  0, 1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11, 12

      ; print all elements
      ftprint ifn

      ; print all elements in columns of 4 elements
      ftprint ifn, 1, 0, 0, 1, 4

      ; assume that a table holds a 2D matrix, print the matrix
      imatrix  ftgentmp 0, 0, 0, -2, \
          00, 01, 02, 03, 04,  \
          10, 11, 12, 13, 14,  \
          20, 21, 22, 23, 24,  \
          30, 31, 32, 33, 34

      ; print the whole matrix, 5 columns per line
      ftprint imatrix, 1, 0, 0, 1, 5

      ; print one row
      irow = 2
      inumcols = 5
      ftprint imatrix, 1, 2*inumcols, 3*inumcols

      ; print one column
      ftprint imatrix, 1, 3, 0, inumcols, 1

      turnoff
    endin

    </CsInstruments>

    <CsScore>
    i 1 0 0.01
    </CsScore>

    </CsoundSynthesizer>

## Voir aussi

printarray, printf

## Crédits

Auteur : Eduardo Moguillansky 2018

Nouveau greffon dans la version 6.12

Précédent | Niveau supérieur | Suivant
ftom | Sommaire | ftsamplebank