wterrain
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## wterrain

wterrain — Un opcode simple de synthèse par terrain d'onde.

## Description

Un opcode simple de synthèse par terrain d'onde.

## Syntaxe

    aout wterrain kamp, kpch, k_xcenter, k_ycenter, k_xradius, k_yradius, \
          itabx, itaby

## Initialisation

itabx, itaby -- Les deux tables qui définissent le terrain.

## Exécution

La sortie est le résultat du dessin d'une ellipse dont les axes k_xradius et k_yradius centrés en (k_xcenter, k_ycenter), et de sa traversée à la fréquence kpch.

## Exemples

Voici un exemple de l'opcode wterrain. Il utilise le fichier wterrain.csd.

Exemple 1215. Exemple de l'opcode wterrain.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    ; Audio out   No messages
    -odac           -d     ;;;RT audio I/O
    ; For Non-realtime ouput leave only the line below:
    ; -o wterrain.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    ; Initialize the global variables.
    sr = 44100
    kr = 4410
    ksmps = 10
    nchnls = 1

    instr 1
    kdclk   linseg  0, 0.01, 1, p3-0.02, 1, 0.01, 0
    kcx     line    0.1, p3, 1.9
    krx     linseg  0.1, p3/2, 0.5, p3/2, 0.1
    kpch    line    cpspch(p4), p3, p5 * cpspch(p4)
    a1      wterrain    10000, kpch, kcx, kcx, -krx, krx, p6, p7
    a1      dcblock a1
            out     a1*kdclk
    endin

    </CsInstruments>
    <CsScore>

    f1      0       8192    10      1 0 0.33 0 0.2 0 0.14 0 0.11
    f2      0       4096    10      1

    i1      0       4       7.00 1 1 1
    i1      4       4       6.07 1 1 2
    i1      8       8       6.00 1 2 2
    e

    </CsScore>
    </CsoundSynthesizer>

## Crédits

Auteur : Matthew Gillard
Nouveau dans la version 4.19

Précédent | Niveau supérieur | Suivant
writescratch | Sommaire | wterrain2