inq
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## inq

inq — Lit des données audio quadro depuis un périphérique externe ou un flot.

## Description

Lit des données audio quadro depuis un périphérique externe ou un flot.

| Avertissement
Cet opcode est prévu pour ne fonctionner qu'avec des orchestres qui ont nchnls_i=4. Avec des orchestres dont nchnls_i > 4, la sortie audio ne sera pas correcte.

## Syntaxe

    ar1, ar2,  ar3, a4 inq

## Exécution

Lit des données audio quadro depuis un périphérique externe ou un flot. Si l'option de ligne de commande -i est positionnée, le son est lu en continu depuis le flot audio en entrée (par exemple stdin ou un fichier son) dans un tampon interne. N'importe quel nombre de ces opcodes peuvent lire librement depuis ce tampon.

## Exemples

Voici un exemple de l'opcode inq. Il utilise le fichier inq.csd.

Exemple 465. Exemple de l'opcode inq.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac  -idac ;;;realtime audio I/O
    ; For Non-realtime ouput leave only the line below:
    ; inq.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr   = 44100
    ksmps   = 32
    nchnls   = 2	;2 channels out
    0dbfs    = 1
    nchnls_i = 4	;4 channels in

    instr 1 ;4 channels in, two channels out

    ain1, ain2, ain3, ain4 inq		;grab your mics and sing

    adel   linseg 0, p3*.5, 0.02, p3*.5, 0	  ;max delay time = 20ms
    adel2  linseg 0.02, p3*.5, 0, p3*.5, 0.02 ;max delay time = 20ms
    aoutl  flanger ain1, adel, .7
    aoutr  flanger ain2, adel*2, .8
    aoutla flanger ain3, adel2, .9
    aoutra flanger ain4, adel2*2, .5
    ;write to quad file, 16 bits with header
           fout "in_4.wav", 14, aoutl, aoutr, aoutla, aoutra
           outs (aoutl+aoutla)*.5, (aoutr+aoutra)*.5 ;stereo out

    endin
    </CsInstruments>
    <CsScore>

    i 1 0 10
    e
    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

diskin, in, inh, inh, ino, ins, soundin

## Crédits

Auteurs : Barry L. Vercoe, Matt Ingalls/Mike Berry
MIT, Mills College
1993-1997

Précédent | Niveau supérieur | Suivant
ino | Sommaire | inrg