trandom
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## trandom

trandom — Génère une suite contrôlée de nombres pseudo-aléatoires entre des valeurs minimale et maximale en fonction d'un déclencheur.

## Description

Génère au taux-k une suite contrôlée de nombres pseudo-aléatoires entre des valeurs minimale et maximale chaque fois que le paramètre de déclenchement est différent de 0.

## Syntaxe

    kout trandom ktrig, kmin, kmax

## Exécution

ktrig -- déclencheur (l'opcode produit un nouveau nombre aléatoire chaque fois que cette valeur est différente de 0.

kmin -- limite inférieure de l'intervalle

kmax -- limite supérieure de l'intervalle

trandom est presque identique à l'opcode random sauf que trandom ne renouvelle sa sortie avec une nouvelle valeur aléatoire que si l'argument ktrig est déclenché (c-à-d chaque fois qu'il est différent de zéro).

## Exemples

Voici un exemple de l'opcode trandom. Il utilise le fichier trandom.csd.

Exemple 1098. Exemple de l'opcode trandom.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o trandom.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    seed 0				; every run time different values

    instr 1

    kmin init 0			;random number between 0 and 220
    kmax init 220
    ktrig = p4
    k1   trandom ktrig, kmin, kmax
         printk2 k1			;print when k1 changes
    asig poscil .4, 220+k1, 1	;if triggered, add random values to frequency
         outs asig, asig

    endin
    </CsInstruments>
    <CsScore>
    f1 0 4096 10 1

    i 1 0 2 0	;not triggered
    i 1 + 2 1	;triggered
    e
    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

random

## Crédits

Ecrit par Gabriel Maldonado.

Nouveau dans Csound 5.06

Précédent | Niveau supérieur | Suivant
tonex | Sommaire | tradsyn