vbaplsinit
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## vbaplsinit

vbaplsinit — Configure la sortie VBAP selon les paramètres de haut-parleur.

## Description

Configure la sortie VBAP selon les paramètres de haut-parleur.

## Syntaxe

    vbaplsinit idim, ilsnum [, idir1] [, idir2] [...] [, idir32]

    vbaplsinit idim, ilsnum, ilsarray

## Initialisation

idim -- dimension de l'espace de haut-parleurs. 2 ou 3. Si la dimension a une partie fractionnaire, celle-ci représente l'indice de la disposition créée (utilisé seulement dans vbap, vbapz et vbapg). La partie fractionnaire doit être comprise entre .00 et .99.

ilsnum -- nombre de haut-parleurs. En deux dimensions, il peut varier entre 2 et 64. En trois dimensions, il peut varier entre 3 et 64.

idir1, idir2, ..., idir32 -- directions des haut-paleurs. Le nombre de directions doit être inférieur ou égal à 16. Dans une répartition des haut-parleurs en deux dimensions, idirn représente l'angle d'azimut du nième canal. Dans une répartition des haut-parleurs en trois dimensions, les champs représentent les angles d'azimut et d'élévation de chaque haut-parleur (azi1, ele1, azi2, ele2, etc.).

ilsarray -- tableau unidimensionnel de données comme celles décrites ci-dessus.

| Note
A deux dimensions, l'angle entre deux haut-parleurs adjacents doit être inférieur à 179 degrés (170 degrés dans les versions précédentes). C'est une restriction de l'algorithme.

## Exécution

VBAP distribue le signal en tenant compte des données de haut-parleurs configurées avec vbaplsinit. Le signal est appliqué au plus à deux haut-parleurs dans les configurations 2D et à trois haut-parleurs dans les configurations 3D. Si la source sonore est distribuée en dehors de la région couverte par les haut-parleurs, les haut-parleurs les plus proches sont utilisés dans le panoramique.

## Exemples

Voici un exemple de l'opcode vbaplsinit. Il utilise le fichier vbaplsinit.csd.

Exemple 1145. Exemple de l'opcode vbaplsinit.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac  ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o vbaplsinit.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 8
    0dbfs  = 1

    vbaplsinit 2, 8, 0, 45, 90, 180, 270, 0, 0, 0		;5 speakers for 5.1 amps

    instr 1

    asig diskin2 "beats.wav", 1, 0, 1			;loop beats.wav
    kazim line 1, p3, 355
    a1,a2,a3,a4,a5,a6,a7,a8 vbap8  asig, kazim, 0, 1	;change azimuth of soundsource
    ; Speaker mapping
    aFL = a1 						; Front Left
    aMF = a5 						; Mid Front
    aFR = a2 						; Front Right
    aBL = a3 						; Back Left
    aBR = a4 						; Back Right
        outo aFL,aFR,aBL,aBR,aMF,a6,a7,a8			;a6, a7 and a8 are dummies

    endin
    </CsInstruments>
    <CsScore>

    i 1 0 5

    e
    </CsScore>
    </CsoundSynthesizer>

Voir les différentes entrées des opcodes vbap pour d'autres exemples.

## Référence

Ville Pulkki : « Virtual Sound Source Positioning Using Vector Base Amplitude Panning » Journal of the Audio Engineering Society, juin 1997, Vol. 45/6, p. 456.

## Voir aussi

vbap, vbapg, vbap4, vbap4move, vbap8, vbap8move, vbap16, vbap16move, vbapz, vbapzmove

## Crédits

Auteur : Ville Pulkki
Sibelius Academy Computer Music Studio
Laboratoire d'Acoustique et de Traitement du Signal Audio
Helsinki, Université de Technologie
Helsinki, Finlande
Mai 2000

Nouveau dans la Version 4.07 de Csound.

Les dispositions multiples sont nouvelles dans la version 5.17.14

Précédent | Niveau supérieur | Suivant
vbap8move | Sommaire | vbapz