olabuffer
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## olabuffer

olabuffer — Additionne les trames audio tuilées dans des tableaux de taux-k et retourne un signal audio.

## Description

Opcode du greffon framebuffer.

olabuffer prend des tableaux unidimensionnels de taux-k qui contiennent des trames audio séquentielles et les additionne sur la base d'un facteur de superposition, produisant un signal audio en sortie. C'est utile pour un traitement audio basé sur des trames comme l'analyse/resynthèse spectrale.

## Syntaxe

    aout olabuffer kin, ioverlap

## Initialisation

ioverlap -- Le facteur de superposition par taille d'échantillons de trame dans le tableau de taux-k en entrée. Par exemple pour une taille de fenêtre de 1024 en entrée et une taille de saut de 256, le facteur de superposition vaut 4. Le facteur de superposition doit être supérieur ou égal à ksmps et doit aussi être un multiple entier du nombre d'échantillons dans le tableau de taux-k en entrée.

## Exécution

aout -- Le signal audio résultant de l'addition des trames en entrée. kin -- Un tableau de taux-k contenant les trames audio séquentielles.

## Exemples

Voici un exemple simple de l'opcode olabuffer. Il utilise le fichier framebuffer.csd.

Exemple 666. Exemple de l'opcode olabuffer.

Voir les sections Audio en temps réel et Options de la ligne de commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    -odac
    </CsOptions>
    <CsInstruments>
    nchnls = 2
    0dbfs = 1
    ksmps = 128
    sr = 44100

    instr 1
        isize init 1024
        ioverlaps init 4

        asig diskin2 "fox.wav", 1, 0, 1
        kframe[] framebuffer asig, isize
        kwindowedFrame[] window kframe, isize

        aout olabuffer kwindowedFrame, ioverlaps
        aout = aout / 2

        outs aout, aout
    endin

    </CsInstruments>
    <CsScore>
    i 1 0 400
    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

olabuffer shiftin shiftout

## Crédits

Auteur : Edward Costello;
NUIM, 2015

Nouveau dans la version 6.06

Précédent | Niveau supérieur | Suivant
octpch | Sommaire | opcode