tone
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## tone

tone — Un filtre passe-bas récursif du premier ordre avec une réponse en fréquence variable.

## Description

Un filtre passe-bas récursif du premier ordre avec une réponse en fréquence variable.

tone est filtre RII à un terme. Sa formule est :

yn = c1 * xn + c2 * yn-1

où

- b = 2 - cos(2 π hp/sr);

- c2 = b - sqrt(b2 - 1.0)

- c1 = 1 - c2

## Syntaxe

    ares tone asig, khp [, iskip]

## Initialisation

iskip (facultatif, par défaut 0) -- état initial de l'espace de données interne. Comme le filtrage comprend une boucle de rétroaction sur la sortie précédente, l'état initial de l'espace de stockage utilisé est significatif. Une valeur nulle provoquera l'effacement de cet espace ; une valeur non nulle autorisera la persistance de l'information précédente. La valeur par défaut est 0.

## Exécution

ares -- le signal audio de sortie.

asig -- le signal audio en entrée.

khp -- le point à mi-puissance de la courbe de réponse, en Hertz. La mi-puissance est définie par puissance maximale / racine de 2.

tone implémente un filtre passe-bas récursif du premier ordre dans lequel la variable khp (en Hz) détermine le point à mi-puissance de la courbe de réponse. La mi-puissance est définie par puissance maximale / racine de 2.

## Exemples

Voici un exemple de l'opcode tone. Il utilise le fichier tone.csd.

Exemple 1095. Exemple de l'opcode tone.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o tone.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    0dbfs  = 1
    nchnls = 2

    instr 1

    asig diskin2 "beats.wav", 1
         outs asig, asig
    endin

    instr 2

    kton line 10000, p3, 0		;all the way down to 0 Hz
    asig diskin2 "beats.wav", 1
    asig tone asig, kton		;half-power point at 500 Hz
         outs asig, asig
    endin

    </CsInstruments>
    <CsScore>

    i 1 0 2
    i 2 2 2

    e

    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

areson, aresonk, atone, atonek, port, portk, reson, resonk, tonek

Précédent | Niveau supérieur | Suivant
tlineto | Sommaire | tonek