GEN02
Précédent | Instructions de partition et routines GEN | Suivant

## GEN02

GEN02 — Transfère les données des p-champs dans une table de fonction.

## Description

Ce sous-programme transfère les données des p-champs dans une table de fonction.

## Syntaxe

    f # date taille 2 v1 v2 v3 ...

## Initialisation

taille -- nombre de points dans la table. La taille de table maximale est de 16777216 (224) points. On peut donner une taille de zéro ; dans ce cas le nombre de valeurs fixe la longueur de la table.

v1, v2, v3, etc. -- valeurs à copier directement dans l'espace de la table. Les valeurs copiées peuvent comprendre le point de garde de la table ; les cellules de la table non remplies contiendront des zéros.

| Note
Si p4 (le numéro de la routine GEN) est positif, la table sera post-normalisée (reproportionnée avec une valeur absolue maximale de 1 après génération). Une valeur de p4 négative empêche cette opération. On utilisera habituellement la valeur -2 avec cette fonction GEN, afin que les valeurs ne soient pas normalisées.

## Exemples

Voici un exemple de la routine GEN02. Il utilise le fichier gen02.csd.

Exemple 1267. Exemple de la routine GEN02.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac      ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o gen02.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1

    ifn  = p4				;choose different tables of GEN02
    kcps init 1/p3				;index over the length of entire note
    kndx phasor kcps
    ixmode = 1				;normalize index data
    kamp tablei kndx, ifn, ixmode
    asig poscil kamp, 440, 1		;use GEN02 as envelope for amplitude
         outs asig, asig

    endin
    </CsInstruments>
    <CsScore>
    f 1 0 8192 10 1	;sine wave
    f 2 0 5 2 0 2 0
    f 3 0 5 2 0 2 10 0
    f 4 0 9 2 0 2 10 100 0

    i 1 0 2 2
    i 1 3 2 3
    i 1 6 2 4
    e
    </CsScore>
    </CsoundSynthesizer>

Voici les diagrammes des formes d'onde des routines GEN02 utilisées dans l'exemple :

f 2 0 5 2 0 2 0

f 3 0 5 2 0 2 10 0

f 4 0 9 2 0 2 10 100 0

## Voir aussi

GEN17

## Crédits

Décembre 2002. Merci à Rasmus Ekman, pour avoir corrigé la limite de la variable PMAX.

L'utilisation d'une taille nulle est nouvelle dans la version 6.12

Précédent | Niveau supérieur | Suivant
GEN01 | Sommaire | GEN03