ftsamplebank
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## ftsamplebank

ftsamplebank — Lit les fichiers son d'un répertoire.

## Description

Opcode du greffon ftsamplebank.

Lit les fichiers son d'un répertoire et les charge dans une série de table de fonction GEN01.

## Syntaxe

    iNumberOfFile ftsamplebank SDirectory, iFirstTableNumber, iSkipTime, iFormat, iChannel,

    kNumberOfFile ftsamplebank SDirectory, kFirstTableNumber, kTrigger, kSkipTime, kFormat, kChannel,

## Initialisation

SDirectory -- une chaîne de caractères identifiant le répertoire à parcourir.

FirstTableNumber -- fixe le numéro de la première table dans laquelle un fichier son sera chargé.

kTrigger -- les tables sont mises à jour lorsqu'il vaut 1, ne s'applique qu'à la version de taux-k.

SkipTime -- la lecture commence à skiptime secondes dans le fichier.

Format -- indique le format des données du fichier audio :

1 - caractères signés sur 8 bit 4 - entiers courts sur 16 bit
2 - octets A-law 5 - entiers longs sur 32 bit
3 - octets U-law 6 - flottants sur 32 bit

Channel -- numéro du canal à lire. 0 signifie tous les canaux.

Si Format = 0 le format des échantillons est déduit de l'en-tête du fichier ou, par défaut, de l'option de ligne de commande -o de Csound.

## Exécution

iNumberOfFile -- le nombre de tables créées.

kNumberOfFile -- le nombre de tables créées.

| Note
Le chargement au taux-k d'un grand nombre de fichiers dans des tables de fonction peut causer des interruptions dans le flux audio.

## Exemple

Cet exemple montre ftsamplebank cherchant des échantillons à un endroit donné. Il charge tous les échantillons qu'il trouve dans des tables de fonction GEN01 et les joue ensuite en séquence, un par seconde. Il utilise le fichier ftsamplebank.csd.

Exemple 394. Exemple de l'opcode ftsamplebank.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;RT audio out
    ;-iadc    ;;;uncomment -iadc if RT audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o diskin.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>
    0dbfs = 1

    ;load all samples in a given directory into function tables and play them using instrument 1000
    instr 1
       iFirstTableNumber = 60;
       iFileCount init 1
       iNumberOfFiles ftsamplebank "../examples/", iFirstTableNumber, 0, 4, 1

       until iFileCount>=iNumberOfFiles do
    	event_i "i", 1000, iFileCount, 1, iFirstTableNumber+iFileCount
    	iFileCount = iFileCount+1
       enduntil

    endin

    instr 1000
       iTable = p4
       aOut loscil3 1, 1, iTable, 1, 0;
       outs aOut, aOut
    endin

    </CsInstruments>
    <CsScore>
    i1 0 20
    </CsScore>
    </CsoundSynthesizer>

## Crédits

Auteur : Rory Walsh
2015

Précédent | Niveau supérieur | Suivant
ftprint | Sommaire | ftsave