r2c
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## r2c

r2c — Conversion du format réel au format complexe.

## Description

Convertit un tableau de valeurs réelles en un tableau de valeurs complexes réelles-imaginaires entrelancées, en fixant la partie imaginaire à 0. La taille du tableau de sortie est le double de celle du tableau d'entrée. C'est une opération utilitaire pour faciliter les opérations à valeurs complexes sur des tableaux réels.

## Syntaxe

    kout[] r2c kin[]

## Exécution

kout[] -- tableau de sortie contenant les valeurs complexes réelles-imaginaires. Créé s'il n'existe pas.

kin[] -- tableau d'entrée contenant les valeurs réelles.

## Exemples

Voici un exemple de l'opcode r2c. Il utilise le fichier r2c.csd.

Exemple 859. Exemple de l'opcode r2c.

Voir les sections Audio en temps réel et Options de la ligne de commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    -d -o dac
    </CsOptions>
    <CsInstruments>
    ksmps = 64

    instr 1
    ifftsize = 1024
    kcnt init 0
    kIn[] init  ifftsize
    kOut[] init ifftsize

    a1 oscili 0dbfs/2, 440

    if kcnt >= ifftsize then
     kCmplx[] r2c kIn
     kSpec[] fft kCmplx
     kCmplx fftinv kSpec
     kOut c2r kCmplx
     kcnt = 0
    endif

    kIn[] shiftin a1
    a2 shiftout kOut
    kcnt += ksmps
       out a2
    endin
    </CsInstruments>
    <CsScore>
    i1 0 10
    </CsScore>
    </CsoundSynthesizer>

## Voir aussi

Opcodes vectoriels, Opcodes de tableaux.

## Crédits

Auteur : Victor Lazzarini
NUI Maynooth
2014

Nouveau dans la version 6.04

Précédent | Niveau supérieur | Suivant
qnan | Sommaire | rand