ntrpol
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## ntrpol

ntrpol — Calcule la valeur de la moyenne pondérée de deux signaux d'entrée.

## Description

Calcule la valeur de la moyenne pondérée (c'est-à-dire l'interpolation linéaire) de deux signaux d'entrée.

## Syntaxe

    ares ntrpol asig1, asig2, kpoint [, imin] [, imax]

    ires ntrpol isig1, isig2, ipoint [, imin] [, imax]

    kres ntrpol ksig1, ksig2, kpoint [, imin] [, imax]

## Initialisation

imin -- valeur minimale pour xpoint (facultatif, 0 par défaut)

imax -- valeur maximale pour xpoint (facultatif, 1 par défaut)

## Exécution

xsig1, xsig2 -- signaux d'entrée

xpoint -- point d'interpolation entre les deux valeurs

L'opcode ntrpol produit l'interpolation linéaire entre deux valeurs d'entrée. xpoint est la distance entre le point d'évaluation et la première valeur. Avec les valeurs par défaut de imin et de imax (0 and 1), une valeur de zéro indique aucune distance depuis la première valeur et une distance maximale à la seconde valeur. Avec une valeur de 0.5, ntrpol produit la valeur moyenne des deux entrées, indiquant exactement le point médian entre xsig1 et xsig2. Une valeur de un indique la distance maximale de la première valeur et pas de distance avec la seconde valeur. La plage de valeurs de xpoint peut aussi être définie avec imin et imax pour rendre sa gestion plus facile.

Ces opcodes sont utiles pour réaliser un fondu-enchainé de deux signaux.

## Exemples

Voici un exemple de l'opcode ntrpol. Il utilise le fichier ntrpol.csd.

Exemple 659. Exemple de l'opcode ntrpol.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac    ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if real audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o ntrpol.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    giSin ftgen 1, 0, 1024, 10, 1

    instr 1

    avco vco2   .5, 110			;sawtootyh wave
    asin poscil .5, 220, giSin		;sine wave but octave higher
    kx   linseg 0, p3*.4, 1, p3*.6, 1	;crossfade between saw and sine
    asig ntrpol avco, asin, kx
         outs   asig, asig

    endin
    </CsInstruments>
    <CsScore>

    i 1 0 5
    e
    </CsScore>
    </CsoundSynthesizer>

## Crédits

Auteur : Gabriel Maldonado
Italie
Octobre 1998

Nouveau dans la version 3.49 de Csound.

Précédent | Niveau supérieur | Suivant
nstrstr | Sommaire | octave