STKBandedWG
Précédent | Opcodes et opérateurs de l'orchestre | Suivant

## STKBandedWG

STKBandedWG — STKBandedWG utilise des techniques de guide d'onde à bandes pour modéliser une variété de sons.

## Description

Opcode du greffon stkopd.

Cette opcode utilise des techniques de guide d'onde à bandes pour modéliser une variété de sons, comprenant des barres frottées, des verres et des bols.

## Syntaxe

    asignal STKBandedWG ifrequency, iamplitude, [kpress, kv1[, kmot, kv2[, klfo, kv3[, klfodepth, kv4[, kvel, kv5[, kstrk, kv6[, kinstr, kv7]]]]]]]

## Initialisation

ifrequency -- Fréquence de la note jouée, en Hz.

iamplitude -- Amplitude de la note jouée (entre 0 et 1).

## Exécution

kpress -- contrôleur 2, pression de l'archet. kv1 compris entre 0 et 127.

kmot -- contrôleur 4, mouvement de l'archet. kv2 compris entre 0 et 127.

klfo -- contrôleur 11, vitesse de l'oscillateur basse-fréquence. kv3 compris entre 0 et 127.

klfodepth -- contrôleur 1, intensité de l'oscillateur basse-fréquence. kv4 compris entre 0 et 127.

kvel -- contrôleur 128, vélocité de l'archet. kv5 compris entre 0 et 127.

kstrk -- contrôleur 64, frappe de l'archet. kv6 compris entre 0 et 127.

kinstr -- contrôleur 16, préréglages de l'instrument (0 = barre uniforme, 1 = barre accordée, 2 = harmonica de verre, 3 = bol tibétain). kv7 compris entre 0 et 3.

| Notes
Le code pour cet opcode vient directement de la classe BandedWG du Synthesis Toolkit en C++ par Perry R. Cook et Gary P. Scavone. On peut en savoir plus sur les classes STK ici : https://ccrma.stanford.edu/software/stk/classes.html kc1, kv1, kc2, kv2, kc3, kv3, kc4, kv4, kc5, kv5, kc6, kv6, kc7, kv7, kc8, kv8 -- Jusqu'à 8 paires de contrôle facultatives au taux-k pour les opcodes STK. Chaque paire de contrôle est constituée d'un numéro de contrôleur (kc) suivi d'une valeur de contrôleur (kv). Le numéro de contrôleur ainsi que la valeur associée sont des variables de taux-k. Cependant, durant l'exécution, les numéros de contrôleur sont habituellement constants tandis que les valeurs correspondantes peuvent changer à tout moment. L'ordre des paires de contrôle est arbitraire mais elles doivent apparaître après iamplitude. Il n'est pas non plus nécessaire d'utiliser toutes les paires.

## Exemples

Voici un exemple de l'opcode STKBandedWG. Il utilise le fichier STKBandedWG.csd

Exemple 998. Exemple de l'opcode STKBandedWG.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if RT audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o STKBandedWG.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1

    ifrq =    p4
    kv1  line p5, p3, p6					;pressure of bow
    kenv line 1, p3, 0

    asig STKBandedWG cpspch(ifrq), 1, 2, kv1, 4, 100, 11, 0, 1, 0, 64, 100, 128, 120, 16, 2
    asig = asig * kenv					;simple envelope
         outs asig, asig
    endin

    </CsInstruments>
    <CsScore>

    i 1 0 10 5.00 100 0
    i 1 10 8 6.03 10 .
    i 1 20 5 7.05 50 127

    e
    </CsScore>
    </CsoundSynthesizer>

## Crédits

Auteur : Michael Gogins (d'après Georg Essl)
Irreducible Productions
New York, NY

Nouveau dans la version 5.11 de Csound.

Précédent | Niveau supérieur | Suivant
stix | Sommaire | STKBeeThree