# Lenguaje Aseba

Este documento también se encuentra disponible en el menú `Help->Language` de ASEBA. Te sugerimos revisar primero, los conceptos básicos definidos aquí, así como algunos términos técnicos que encuentras en esta página y que están directamente vinculados con el correspondiente artículo en Wikipedia. Esta página describe el lenguaje Aseba a partir de la versión 1.2; para versiones anteriores, por favor lee esta esta página.

El lenguaje de programación ASEBA permite implementar control distribuido entre nodos ASEBA.

Sintácticamente hablando, ASEBA se asemeja a MatLab u Octave; esta similitud le permite a los desarrolladores que tengan conocimientos previos en esos lenguajes, sentirse más cómodos con Aseba y reducir la curva de aprendizaje.

Semánticamente hablando, este es un lenguaje de programación imperativo con un solo tipo de valores (enteros de 16 bits con signo) y vectores. Esta simplicidad le permite a los desarrolladores programar comportamientos sin tener conocimientos previos en otros sistemas de tipos (como el hexadecimal). Los enteros nos resultan muy naturales, cómodos y adecuados para programar robots móviles basados en microcontroladores.

# Comentarios

Los comentarios te permiten incluir en tus programas, información que el compilador no considera. Los comentarios se utilizan con frecuencia para incluir notas aclaratorias que puedan ser interpretadas por humanos, o también para deshabilitar temporalmente algunas líneas del código. Los comentarios comienzan con # y terminan al final de la línea.

Ejemplo:

    # este es un comentario.
    var b # otro comentario

También es puedes introducir comentarios de más de una línea: comienzan con #* y terminan con *#.

Ejemplo:

    #*
    Este es un
    comentario con
    más de una línea.*#
    var b # este es un comentario sencillo

# Escalares

Los escalares se usan en Aseba para representar números. Se pueden utilizar en cualquier expresión, como en la inicialización de una variable, una fórmula matemática o una condición lógica.

## Notación

Los escalares pueden definirse utilizando diferentes bases. La base más natural es el sistema de numeración decimal, usando dígitos del 0 al 9. Los números negativos se declaran usando el signo `-` (menos) frente al número.

    i = 42
    i = 31415
    i = -7

Se puede usar tanto el sistema binario como el hexadecimal. Los números binarios estan precedidos por `0b`, mientras que los números hexadecimales usan el prefijo `0x`.

    # Notación binaria:
    i = 0b110         # i = 6
    i = 0b11111111    # i = 255

    # Notación hexadecimal
    i = 0x10    # i = 16
    i = 0xff    # i = 255

# Las variables

Las variables son espacios de memoria que pueden contener un escalar o un vector de escalares. Pueden tomar valores entre -32768 y 32767, que es el rango para los enteros de 16 bits con signo. Debes declarar todas las variables personales (definidas por el usuario), usando el comando `var`, al comienzo de tu script Aseba, incluso antes de ejecutar cualquier proceso.

El nombre de una variable se define siguiendo estas reglas:

- Solo puede contener caracteres alfabéticos en mayúscula o minúscula, '_' o '.'
- Debe comenzar con una carácter alfabético válido o '_'.
- Es case sensitive: la variable "foo" es diferente a la variable "Foo"
- No se permite usar nombres de comandos Aseba (ver nombres reservados)

Las variables se pueden inicializar cuando son declaradas,combinando el símbolo de asignación con una expresión matemática válida. Una variable no inicializada puede contener un valor aleatorio; no se puede asumir cómo cero.

Ejemplo:

    var a
    var b = 0
    var c = 2*a + b        # Atención: 'a' no fue inicializada.

## Nombres reservados

[[#nombres-reservados]]

Las siguientes palabras no pueden ser usadas como nombres de variables porque ya son usadas en el lenguaje Aseba:

Palabras
abs | call | callsub | do
else | elseif | emit | end
for | if | in | onevent
return | step | sub | then
var | when | while |

## Constantes

Las constantes se pueden definir, en Aseba Studio, usando el panel de "Constantes", pero no se pueden definir directamente en el código. Una constante representa un valor numérico en cualquier parte que se requiera un número, pero a diferencia de las variables, una constante no se puede modificar durante la ejecución. Las constantes resultan útiles cuando se desea cambiar fácilmente el comportamiento entre diferentes ejecuciones, como cuando se adapta un umbral, para un alcance de varios nodos Aseba. Una constante no puede tener el mismo nombre que una variable, de otro modo, se producirá un error.

    # asumir una constante nombrada UMBRAL
    var i = 600

    if i > UMBRAL then
        i = UMBRAL - 1
    end

## Vectores

Los vectores representan un espacio continuo en la memoria, direccionado como una sola entidad lógica. El tamaño de un vector es fijo y se debe especificar cuando se declara. Los vectores se pueden declarar usando el operador corchetes `[]`. El número entre corchetes especifica la cantidad de elementos asignados al vector, por eso hace referencia a su tamaño. Puede ser cualquier expresión constante, incluyendo operaciones matemáticas con escalares y constantes. Una alternativa consiste en usar el constructor de vectores (descrito más abajo); en ese caso no se especifica el tamaño del vector.

Ejemplo:

    var a[10]                   # vector de 10 elementos
    var b[3] = [2, 3, 4]        # inicialización
    var c[] = [3, 1, 4, 1, 5]   # tamaño implícito: 5 elementos
    var d[3*FOO-1]              # tamaño declarado usando una expresión constante (FOO declarada como constante)

El contenido de un vector se puede acceder de diferentes maneras:

- Para acceder a un sólo elemento se usa una expresión constante que indique su posición y encerrada en corchetes. Las posiciones (índices) comienzan con cero. Cualquier expresión se puede usar como índice, incluyendo expresiones matemáticas con otras variables.
- Para acceder un rango de elementos se usan dos expresiones contantes, separadas por ':' y encerradas por corchetes.
- Si se omiten los corchetes, se accede a la totalidad del vector.

Ejemplo:

    var foo[5] = [1,2,3,4,5]
    var i = 1
    var a
    var b[3]
    var c[5]
    var d[5]

    a = foo[0]       # copia el primer elemento de 'foo' en 'a'
    a = foo[2*i-2]       # lo mismo
    b = foo[1:3]       # copia el 2°, 3° y 4° elemento de 'foo' en 'b'
    b = foo[1:2*2-1]   # lo mismo
    c = foo           # copia los 5 elementos del vector 'foo' al vector 'c'
    d = c * foo       # multiplica los vectores 'foo' y 'c', elemento por elemento, y copia el resultado en 'd'

## Constructores de vectores

Los constructores de vectores son un método para construir vectores a partir de variables, otros vectores, escalares o incluso expresiones complejas. Reesultan útiles en varias situaciones; por ejemplo, para inicializar otro vector, o como operando en expresiones, funciones y eventos. Un constructor de vectores consiste en una serie de expresiones separadas por `,` (comas) y encerradas en corchetes. El tamaño del vector será la suma de los tamaños individuales de sus elementos y debe coincidir con el tamaño del vector que almacenará el resultado.

Ejemplo:

    var a[5] = [1,2,3,4,5]    # constructor de vectores para inicializar un vector
    var b[3] = [a[1:2],0]    # b se inicializa con [2,3,0]
    a = a + [1,1,1,1,1]    # suma 1 a cada elemento del vector a
    a = [b[1]+2,a[0:3]]    # es igual a [5,2,3,4,5]

# Expresiones y asignaciones

Las expresiones permiten ejecutar operaciones matemáticas utilizando la convencional notación de infijo convencional.

Las asignaciones se usan para vincular el resultado de un cómputo o de una expresión a una variable escalar o a un elemento de un vector o un vector completo. Para asignar un valor a una variable se utiliza el operador `=`. Puedes usar paréntesis para agrupar subexpresiones y evaluar expresiones en un orden determinado.

ASEBA dispone de los siguientes operadores:

Precedencia | Operador | Descripción | Asociatividad | Aridad
--- | --- | --- | --- | ---
1 | () | Agrupar subexpresiones |  | unario
2 | * / | Multiplicación, división |  | binario
| % | Módulo |  | binario
3 | + - | Suma, resta |  | binario
4 | << >> | desplazamiento a izquierda, desplazamiento a derecha |  | binario
5 | | | ó binario (or) | asociativo a izquierda | binario
6 | ^ | ó exclusivo (xor) | asociativo a izquierda | binario
7 | & | y binario (and) | asociativo a izquierda | binario
8 | - | menos unario |  | unario
9 | ~ | no binario (not) |  | unario
10 | abs | Valor absoluto |  | unario
11 | = | Asignación |  | binario
| |= ^= &= | Asignación or, xor, and |  | binario
| ~= | Asignación not |  | binario
| *= /= | Asignación producto y cociente |  | binario
| %= | Asignación módulo |  | binario
| += -= | Asignación suma y resta |  | binario
| <<= >>= | Asignación desplazamiento derecha / izquierda |  | binario
| ++ -- | Incremento y decremento unario |  | unario

Las asignaciones con operadores binarios funcionan aplicando el operador a una variable y almacenando el resultado en ella misma. Por ejemplo, `A *= 2` es lo mismo que `A = A * 2`. Estos operadores buscan hacer el código más legible.

Ejemplo:

    a = 1 + 1
    # Resulta: a = 2
    a *= 3
    # Resulta: a = 6
    a++
    # Resulta: a = 7

    b = b + d[0]
    b = (a - 7) % 5
    c[a] = d[a]
    c[0:1] = d[2:3] * [3,2]

## Utilización

Las expresiones matemáticas son una herramienta general. Como tal, pueden ser usadas en muchos casos, por ejemplo:

- Al lado derecho de una asignación.
- Cómo índice para acceder a los elementos de un vector.
- Dentro de los llamados a funciones.
- Cómo argumento al emitir un evento.

# Control de flujo

## Condicionales

Aseba incluye dos tipos de condicionales: `if` y `when`. Ambos constan de la evaluación de una condición (sentencia) y de un bloque de código. La evaluación es normalmente una comparación utilizando los operadores `and` (conjunción lógica), `or` (disyunción lógica), y `not` (negación lógica), y paréntesis.

Una comparación consta de un operador y dos operandos; el resultado puede ser verdadero o falso. Los operandos pueden ser expresiones arbitrarias.

La siguiente es una lista con los operadores de comparación:

Operador | Valor de verdad
--- | ---
`==` | verdadero si los operandos son iguales
`!=` | verdadero si los operandos son diferentes
`>` | verdadero si el primer operando es estrictamente mayor que el segundo
`>=` | verdadero si el primer operando es mayor o igual que el segundo
`<` | verdadero si el primer operando es estrictamente menor que el segundo
`<=` | verdadero si el primer operando es menor o igual que el segundo

Las estructuras condicionales `if` y `when` ejecutan un bloque de código específico si se cumple o no una determinada condición (verdadero/falso):

- `if` ejecuta un primer bloque de código si se cumple la condición (`verdadero`). un segundo bloque de código puede ser ejecutado en caso de no cumplirse la condición (`falso`); basta con incluir la instrucción `else`. Además, otras condiciones pueden ser tenidas en cuenta utilizando la instrucción `elseif`.
- `when` solo ejecuta las instrucciones correspondientes cuando ocurre un cambio en el estado de la condición. Es decir, el conjunto de instrucciones asociadas al cumplimiento de la condición (verdadero) so lo se ejecuta si la última vez que se evaluó fue `falso`.

Ejemplo:

    if a - b > c[0] then
        c[0] = a
    elseif a > 0 then
        b = a
    else
        b = 0
    end

    if a < 2 and a > 2 then
        b = 1
    else
        b = 0
    end

    when a > b do
        leds[0] = 1
    end

En el código anterior, la instrucción correspondiente al `when` se ejecuta solo cuando `a` se vuelve mayor que `b`.

## Ciclos (bucles)

Dos estructuras permiten crear ciclos iterativos: `while` y `for`.

Un ciclo `while` ejecuta una conjunto de instrucciones, repetidamente, siempre y cuando se cumpla una determinada condición.Las condiciones se pueden construir de igual manera que para los condicionales `if` y `when`. El siguiente ejemplo, ejecuta las instrucciones asociadas al ciclo `while` mientras que el valor que tome i sea menor que 10.

    while i < 10 do
        v = v + i * i
        i = i + 1
    end

Un ciclo `for` le permite a una variable tomar diferentes valores enteros dentro de un rango establecido y con un incremento determinado. En el primer ciclo `for` del siguiente ejemplo, la variable i toma valores desde 1 hasta 10 incrementándose en 1 para cada iteració; es decir, para la primera iteración i=1, para la segunda i=2 y así sucesivamente, hasta la última iteración en donde i=10. En el segundo ciclo, la variable toma el valor de 30 para la primera iteración y va disminuyendo de 3 en 3 hasta llegar a 1; es decir, i=27 para la segunda iteración, i=24 para la tercera y así sucesivamente.

    for i in 1:10 do
        v = v + i * i
    end
    for i in 30:1 step -3 do
        v = v - i * i
    end

# Bloques

## Subrutinas

Cuando quieras utilizar una secuencia de instrucciones en dos o más lugares de tu código, puedes escribir una subrutina con la secuencia de instrucciones y luego llamarla donde la la necesites. Para definir una subrutina debes usar la instrucción `sub` seguida por el nombre de la subrutina. Para llamarla, utilizas la instrucción `callsub`, seguida por el nombre de la subrutina. Debes escribir las subrutinas antes de llamarlas. Las subrutinas tienen acceso a todas la variables, pero no pueden tener argumentos, ni pueden ser recursivas (llamarse a si mismas), directa o indirectamente. Este es un ejemplo:

    var v = 0

    sub toto
    v = 1

    onevent test
    callsub toto

# Eventos

La arquitectura de Aseba se basa en eventos. Esto quiere decir que los eventos pueden hacer que el código se ejecute asincrónicamente.

Los eventos pueden ser:

- externos, como por ejemplo los eventos definidos por el usuario que provienen de otro nodo Aseba; ó
- internos, como aquellos generados por un sensor.

La realización de un evento ejecuta el bloque de código que se encuentra después de la instrucción `onevent` seguido por el nombre del evento; el código que se encuentra antes de esa instrucción solo se ejecuta una vez al comienzo o cada vez que hay un reset. El script también puede generar un evento usando la instrucción `emit`, seguida por el nombre del evento y el nombre de la variable a enviar, si es el caso. Si se suministra el nombre de una variable, el tamaño del evento debe coincidir con el tamaño del argumento que se emite. Los eventos le permite a los scripts, ejecutar códigos en otros nodos o comunicarse con un programa externo.

Para permitir que los códigos relacionados con otros eventos puedan ser ejecutados, los scripts no se pueden bloquear ni tener ciclos infinitos. En el contexto de la robótica, los programas tradicionales para controlar los robots realizaban procesos dentro de ciclos infinitos; un script de Aseba realiza los procesos dentro de eventos relacionados con los sensores.

Este es un ejemplo:

    var run = 0

    onevent start
    run = 1

    onevent stop
    run = 0

    onevent ir_sensors
    if run == 1 then
        emit sensors_values proximity_sensors_values
    end

## Declaración de retorno (return)

Es posible interrumpir la ejecución de una subrutina o de un evento utilizando el comando `return`.

Ejemplo:

    var v = 0

    sub toto
    if v == 0 then
        return
    end
    v = 1

    onevent test
    callsub toto
    return
    v = 2

# Funciones nativas

Aseba está concebido para ser tan simple que permite un rápido aprendizaje por parte de los desarrolladores (incluso novatos) y la implementación de la máquina virtual en un micro-controlador de manera eficiente. Las funciones nativas se encargan de los procesos complejos o que requieren de muchos recursos. Ellas están escritas en lenguaje de máquina para mejorar la eficiencia. Además son seguras. Ellas especifican y verifican el tamaño de sus argumentos, los cuales pueden ser constantes, variables o elementos de vectores. Para el último caso, puedes extraer todos los elementos de un vector, un solo elemento o una porción. Las funciones nativas asignan sus argumentos por referencia y pueden modificar sus contenidos pero no devuelven ningún valor. Puedes usar funciones nativas usando la instrucción `call`. Por ejemplo:

    var a[3] = 1, 2, 3
    var b[3] = 2, 3, 4
    var c[5] = 5, 10, 15
    var d
    call math.dot(d, a, b, 3)
    call math.dot(d, a, c[0:2], 3)
    call math.dot(a[0], c[0:2], 3)

# Qué más puedo leer ahora?

Con seguridad te interesará consultar:

- Descripción de la librería estándar de funciones nativas